Was ist die richtige Backupstrategie für den ambitionierten Heimadmin -server?

'================================================================  
'=	Skript zum Sichern eines Übergebenen Pfades Robocopy		=  
'=	29.03.2012 / Dirk Lenzing (wdlzd)	 						=  
'=	Verison: 1.1	 											=  
'=	 															=  
'= Robocopy muß im System vorhanden sein!!!				 		=  
'================================================================  

option explicit

'Debugmodus  
const debugmode = false

dim objSHELL
dim objFSO
dim objNET
dim objDRIVES
dim objLINK
dim ini
dim mydrive, rtw, startzeit, ZEIT, ZIEL, myargument, LOG, LOGFILE, hddserial, backup_basispfad, drive, sendtofile
dim inifile
set objSHELL = createobject("wscript.shell")  
set objFSO = createobject("scripting.filesystemobject")  
set objNET = createobject("wscript.network")  
set objDRIVES = objFSO.drives
inifile = "C:\Users\" & objnet.username & "\" & replace(wscript.scriptname,"vbs","ini")  
sendtofile = "C:\Users\" & objnet.username & "\AppData\Roaming\Microsoft\Windows\SendTo\Backup this!.lnk"  

'ggf. Installation!  
if objfso.fileexists(inifile) = false then
	if objshell.regread("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\CurrentVersion") <> "6.1" then  
		msgbox "Dieses Tool wurde extra für Windows 7 geschrieben, tut mir leid...",vbokonly+vbcritical,"Lenzing's Backup"  
		wscript.quit
	end if
	rtw = ""  
	rtw = msgbox("Für den reibungslosen Betrieb muss diese Datei an einem stets für alle zugänglichen Ort liegen." & vbcr & "Zudem muss das Backup-Laufwerk verfügbar sein!" & vbcr & vbcr & "Ist beides der Fall?",vbyesno+vbquestion,"Installationsanweisungen")  
	if rtw = vbno then wscript.quit
	for each drive in objDRIVES
		'Backup-Laufwerk einstellen  
		if drive.isready = true then
			rtw = ""  
			rtw = msgbox("Ist dies das gewünschte Backup-Laufwerk?" & vbcr & drive.driveletter & ":\  -> " & drive.volumename & " (" & get_dtype(drive.drivetype) & ")",vbyesno+vbquestion,"Lenzing's Backup / Einrichtung")	  
			if rtw = vbyes then
				do 
					backup_basispfad = inputbox("Bitte Unterverzeichnis ohne führendes Laufwerk angeben!" & vbcr & "z.B.: BackUp nicht C:\BackUp!","Unterverzeichnis angeben")  
					if backup_basispfad = false then wscript.quit
					rtw = ""  
					rtw = msgbox("Backups werden somit hierher gesichert:" & vbcr & drive.driveletter & ":\" & backup_basispfad & vbcr & vbcr & "Ist das korrekt?",vbyesno+vbquestion,"Lenzing's Backup / Frage")  
				loop until rtw = vbyes
			
			'Konfiguration speichern	  
				set ini = objfso.opentextfile(inifile,2,true,-2)
				ini.writeline drive.serialnumber
				ini.writeline backup_basispfad
				ini.close
				set ini = nothing
			
			'Verknüpfung erstellen  
				set objLINK = objSHELL.createshortcut(sendtofile)
				objLINK.workingdirectory = replace(wscript.scriptfullname,wscript.scriptname,"")  
				objLINK.targetpath = wscript.scriptfullname
				objLINK.IconLocation = "shell32.dll,249"  
				objLINK.Description = "Lenzing's Backup für Ordner unter Windows 7 ausführen"  
				objLINK.save
				set objLINK = nothing
			
			'Fertig!  
				msgbox "Die Installation für User " & objnet.username & " ist nun abgeschlossen." & vbcr & "Sollen auch andere User dieses Tool nutzen können so müssen sie diese Installation ebenfalls ausführen." & vbcr & vbcr & "Um ein BackUp von einem Ordner zu machen einfach: Rechts-Klick -> Senden an -> Backup this!",vbokonly+vbinformation,"Lenzing's Backup"  
				rtw = true
				exit for
			end if
		end if		
	next
	if rtw <> true then
		msgbox "Es wurde kein Laufwerk ausgewählt!",vbokonly+vbcritical,"Lenzing's Backup / Abbruch!"  
	end if	
	wscript.quit
end if
	
'Daten einlesen!  
set ini = objfso.opentextfile(inifile,1)
hddserial = ini.readline()
backup_basispfad = ":\" & ini.readline() & "\"  
ini.close
set ini = nothing

'Prüfungen  
if objshell.regread("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\CurrentVersion") <> "6.1" then  
	msgbox "Dieses Tool wurde extra für Windows 7 geschrieben, tut mir leid...",vbokonly+vbcritical,"Lenzing's Backup"  
	wscript.quit
end if

if wscript.arguments.count = 0 then
	rtw = ""  
	rtw = msgbox("Lenzing's Backup deinstalieren?",vbyesno+vbquestion,"Lenzing's Backup")  
	if rtw = vbyes then 
		objfso.deletefile sendtofile
		if objfso.fileexists(sendtofile) then msgbox "Datei konnte nicht gelöscht werden:" & vbcr & sendtofile,vbokonly+vbexclamation,"Lenzing's Backup"  
		objfso.deletefile inifile
		if objfso.fileexists(inifile) then msgbox "Datei konnte nicht gelöscht werden:" & vbcr & inifile,vbokonly+vbexclamation,"Lenzing's Backup"  
	end if
	wscript.quit
end if

mydrive = ""  
for each drive in objDRIVES
	if drive.isready = true then
		if debugmode = true then msgbox "Letter: " & drive.driveletter & " -> " & drive.serialnumber & " / " & hddserial,,"Lenzing's Backup / Livetracking"  
		if cstr(drive.serialnumber) = cstr(hddserial) then 
			if debugmode = true then msgbox "Letter: " & drive.driveletter,,"Lenzing's Backup / Auswahl!"  
			mydrive = drive.driveletter
			exit for
		end if
	end if
next
if mydrive = "" then  
	msgbox "Das Backuplaufwerk wurde nicht gefunden! Bitte schließe das Laufwerk mit der Seriennummer: " & hddserial & " an und versuche es erneut!",vbokonly+vbexclamation,"Lenzing's Backup / Fehler"  
	wscript.quit
end if

if wscript.arguments.count > 1 then
	rtw = msgbox ("Bitte nur einen Ordner auswählen!" & vbcr & vbcr & "Backup fortsetzen mit:" & vbcr & wscript.arguments(0),vbyesno+vbquestion,"Lenzing's Backup / Frage")  
	if rtw = vbno then wscript.quit
end if

if objfso.folderexists(wscript.arguments(0)) = false then
	msgbox "Das übergebene Objekt ist KEIN Ordner!",vbokonly+vbexclamation,"Lenzing's Backup / Abbruch"  
	wscript.quit
end if

'Vorbereitungen  
myargument = replace(wscript.arguments(0),":","")  
ZIEL = mydrive & backup_basispfad & myargument
LOG = "Backup___" & replace(replace(myargument,"\","+")," ","_") & "___(" & replace(replace(replace(now,":",""),".","")," ","") & ").log"  
LOGFILE = mydrive & backup_basispfad & "Logfiles\" & LOG   

'Sicherheitsabfrage:  
rtw = ""  
rtw = msgbox("Sind diese Angaben korrekt?" & vbcr & vbcr & "Quelle: " & wscript.arguments(0) & vbcr & "Ziel:   " & mydrive & backup_basispfad & "...",vbyesno+vbquestion,"Lenzing's Backup / Frage")  
if rtw = vbno then wscript.quit

'Backup!   
startzeit = now
mkdir ZIEL
mkdir mydrive & backup_basispfad & "Logfiles"  
rtw = objSHELL.run("robocopy.exe" & " " & """" & wscript.arguments(0) & """" & " " & """" & ZIEL & """" & " /E /r:0 /w:0  /NP /TEE /ETA /LOG:" & LOGFILE,1,true)  
if objfso.fileexists(LOGFILE) = false then
	msgbox "Da ist etwas schief gelaufen!!!" & vbcr & "Antwort von Robocopy: " & robocopy_rtc(rtw),vbokonly+vbcritical,"Lenzing's Backup / Fehler!"  
	wscript.quit
end if
objfso.movefile LOGFILE, mydrive & backup_basispfad & "Logfiles\" & LOG   
ZEIT = datediff("s",startzeit,now)  

'Meldung  
msgbox "Sicherung von " & wscript.arguments(0) & " nach " & ZIEL & " abgeschlossen..." & vbcr & "Backup-Zeit: " & ZEIT & " Sekunden...",vbokonly+vbinformation,"Lenzing's Backup / Fertig"  

Sub mkdir (byval Pfad) '----- Verzeichnisbaum anlegenen --------------------------------------------------------------------------------------------------------------  
	dim counter	'Position im Pfad  
	dim string
	if right(pfad,1) <> "\" then pfad = pfad & "\"  
	counter = 4
	while instr(counter,pfad,"\") >0  
		string = left(pfad,instr(counter,pfad,"\")-1)  
		counter = instr(counter,pfad,"\")+1  
		if not objfso.folderexists(string) then
			objfso.createfolder(string)
		end if
	wend
	set counter = nothing
	set string = nothing
End Sub

function robocopy_rtc(byval rtc) '----- Robocopy Rückgabewerte -------------------------------------------------------------------------------------------------------  
    Select Case (rtc)
        Case 0  '--no change--  
            robocopy_rtc = "no change"  
        Case 1  'copy  
            robocopy_rtc = "copy"  
        Case 2  'xtra  
            robocopy_rtc = "xtra"  
        Case 3  'xtra & copy  
            robocopy_rtc = "xtra & copy"  
        Case 4  'mism  
            robocopy_rtc = "mism"  
        Case 5  'mism & copy  
            robocopy_rtc = "mism & copy"  
        Case 6  'mism & xtra  
            robocopy_rtc = "mism & xtra"  
        Case 7  'mism & xtra & copy  
            robocopy_rtc = "mism & xtra & copy"  
        Case 8  'fail  
            robocopy_rtc = "fail"  
        Case 9  'fail & copy  
            robocopy_rtc = "fail & copy"  
        Case 10 'fail & xtra  
            robocopy_rtc = "fail & xtra"  
        Case 11 'fail & xtra & copy  
            robocopy_rtc = "fail & xtra & copy"  
        Case 12 'fail & mism  
            robocopy_rtc = "fail & mism"  
        Case 13 'fail & mism & copy  
            robocopy_rtc = "fail & mism & copy"  
        Case 14 'fail & mism & xtra  
            robocopy_rtc = "fail & mism & xtra"  
        Case 15 'fail & mism & xtra & copy  
            robocopy_rtc = "fail & mism & xtra & copy"  
        Case 16 'fatal error  
            robocopy_rtc = "fatal error"  
        Case Else
            robocopy_rtc = "unknown"  
    End Select
End function

function get_dtype(byval mytype) '----- Gibt den Laufwerkstypen wieder -----------------------------------------------------------------------------------------------------  
	select case (mytype)
		case 1
			get_dtype = "Austauschdatenträger"  
		case 2
			get_dtype = "Festplatte"  
		case 3
			get_dtype = "Netzlaufwerk"  
		case 4
			get_dtype = "CD-ROM"  
		case 5
			get_dtype = "RAM-Disk"  
		case else
			get_dtype =  "unbekannter Typ"  
	end select
end function