HowTo For Schleife mit TokenTrenner AnführungsZeichen ( double quotes as Delimiter )

    %~I         - Expandiert %I und entfernt alle umschließenden
                   Anführungszeichen (").

 usebackq        - Gibt an, dass die neue Semantik in Kraft ist,
                   wobei eine Zeichenfolge in umgekehrten Anführungs-
                   zeichen als Befehl ausgeführt wird und eine
                   Zeichenfolge in Anführungszeichen ein literaler
                   Befehl ist, der die Verwendung von doppelten
                   Anführungszeichen um Dateinamen in Dateien-
                   sätzen erlaubt.
wogegen in XP so darüber geplänkelt wird
usebackq 	Gibt an, dass Sie bei der Angabe von Dateinamen in Dateinamensatz Anführungszeichen 
		verwenden können; eine Zeichenfolge in schrägen, einzelnen Anführungszeichen wird als 
		Befehl ausgeführt, und eine Zeichenfolge in einfachen Anführungszeichen ist ein literaler 
		Zeichenfolgenbefehl.

@echo off&setlocal
if not "%~1" == "" goto :Weiter  
set "E=echo on"&set "A=@echo off"  

set "Log=1>>"%temp%\CMD.log" 2>&1 "  

prompt $g
if not defined Log goto :NoLog
type nul>"%temp%\CMD.log.on"  
type nul>"%temp%\CMD.log"  
start "Test Ausgabe" "%~0" Out  
ping localhost -n 2 >nul
:NoLog
%log%(
for %%i in (Test0 Test1 Test2 Test3 Test4) do cmd /c ""%~0" %%i"  
)
:: 
del "%temp%\CMD.log.on"  
if not defined Log pause
goto :eof

:weiter
goto :%~1


:Out
for %%i in ("%temp%\CMD.log") do set /a Gr = %%~zi  
for /f %%i in ('find /v /c "" ^< "%temp%\CMD.log" 2^>nul ') do set /a lastline = %%i  
:Out2
if not exist "%temp%\CMD.log.on" (echo\&echo\Programm beendet&pause&exit)  
for %%i in ("%temp%\CMD.log") do if "%%~zi" neq "%Gr%" (set /a Gr = %%~zi ) else goto :Out2  
for /f %%i in ('" find /v /c "" < "%temp%\CMD.log" 2>nul "') do if %%i neq %lastline% set /a lastline = %%i&more +%lastline% "%temp%\CMD.log"|find /v ""  
goto :Out2


:test0
@echo off&setlocal
echo Dieser Test soll Zeigen in welchen Bereichen zwischen AnfuehrungsZeichen
echo eine Maskierung mit dem Zirkumflex Funktioniert
echo Wenn nur das ZirkumFlex Maskiert wir ist der Effekt schon beim setzen
echo der Variablen erkennbar in welchem Bereich eine Maskierung Funktioniert
%e%
set "Test=                             " Maskierbar ^^ "  
set "Test=KEIN Maskierbarer Bereich ^^ "              "  
%a%
echo\
goto :eof


:test1
%e%
set "Test=a   b	c"1 1   1!2	2		2^^"  def	" ghi"  
%a%
echo Test voll:
echo %Test%
%e%
for /f eol^=^"^ delims^=^"^!^ tokens^=1^,2-5 %%i in ("%Test%") do @echo\Test aus der For: 1%%i.2%%j.3%%k.4%%l.5%%m.  
%a%
echo Hier ist schon erkennbar das im Maskierbaren Bereich die Leerzeichen und Tab
echo zu einem Leerzeichen zusammengezogen werden.
%e%
set "Test="   .a		.b .c""  
for /f "delims=. tokens=1-3" %%i in ("%Test%") do @echo\Test aus der For: 1%%i.2%%j.3%%k.  
%a%
echo Das war Test Nr. 1 - diese Maskierung funktioniert.
echo\
goto :eof


:test2
echo Zum zweiten Test ...

%e%
set "Test=a   b	c"1 1   1!2	2		2^^"  def	^^" ghi"  
%a%
echo im Set wird die Zweite Maskierung trozdem trozdem nicht ausgefuehrt
echo Test        voll:
echo %Test%
echo\
%e%
for /f eol^=^"^ delims^=^"^!^ tokens^=1^,2-5 %%i in ("%Test%") do @echo\Test aus der For: 1%%i.2%%j.3%%k.4%%l.5%%m.  
%a%
echo Das war Test Nr.2 - die Zweite Maskierunge funktioniert Nicht.
echo obwohl die erste Maskierung greift bleibt der Zweite Abschnitt Unmaskierbar
echo sonst wuerde bei ungerader Anzahl Anführungszeichen die For nicht klappen
echo\
goto :eof


:test3
echo Zum dritten Test ...
%e%
set "Test=a   b	c"1 1   1!2	2		2"  def	^" ghi"  
%a%
echo die Zweite Maskierung mit nur "einem" Zirkumflex  
echo Test        voll:
echo %Test%
echo\
%e%
for /f eol^=^"^ delims^=^"^!^ tokens^=1^,2-5 %%i in ("%Test%") do @echo\Test aus der For: 1%%i.2%%j.3%%k.4%%l.5%%m.  
goto :eof


:test4
echo Das war Test Nr.3 - die Zweite Maskierung funktioniert Nicht.
echo der Zweite Abschnitt bleibt Unmaskierbar
echo\
echo Zum vierten Test ...
%e%
set "Test=a   b	c"1 1   1!2	2		2"  def	^^" ghi"  
%a%
echo Test        voll: %Test%
echo Die ForSchleife wird nicht ausgefuehrt
for /f eol^=^"^ delims^=^"^!^ tokens^=1^,2-5 %%i in ("%Test%") do @echo\Test aus der For: 1%%i.2%%j.3%%k.4%%l.5%%m.