Batch - mit und ohne tee - Konsoleausgaben zugleich in eine Datei leiten und auf dem Bildschirm ausgeben

Tipp: Wird der Inhalt in den Quelltextfenstern chaotisch angezeigt, kann es hilfreich sein dort auf den Link "Quelltext" (oben rechts) zu klicken. Es öffnet sich dann ein separates Fenster, welches in der maximierten Darstellung, je nach Bildschirmauflösung, den unerwünschten Zeilenumbruch unterbindet.  

@echo off
for /F "tokens=1*" %%a in ("%*") do ( ::%%b=Parameterzeile abzüglich %1  
  for /F "tokens=1* delims=:" %%x in ('^(%%b^) 2^>^&1 ^| findstr /n $') do (echo.%%y) >>%1 & echo.%%y  
  rem "findstr /n $" verhindert, dass hierbei Leerzeilen verloren gehen  
)

TeeMyBatch.cmd .\MyLogfile.txt  MyBatch.cmd <Parameter1> <Parameter2> ...

@echo off & setlocal
call :FncTeeOut .\MyLogfile.txt  echo Test 1
call :FncTeeOut .\MyLogfile.txt  net use x: \\server\freigabe /User:x abc
call :FncTeeOut .\MyLogfile.txt  echo Test 2

goto :EOF

:FncTeeOut      ::Version 1.0.1
::Parameters:   <LogFileName> <Command with parameters ...>
::Example:      call :FncTeeOut .\MyLogFile.txt echo It is a test.   (print on screen and to logfile)
  for /F "tokens=1*" %%a in ("%*") do ( ::%%b=Parameterzeile abzüglich %1  
    for /F "tokens=1* delims=:" %%x in ('^(%%b^) 2^>^&1 ^| findstr /n $') do (echo.%%y) >>%1 & echo.%%y  
  )
 exit /b 0

@echo off & setlocal
call :FncTeeOut2 .\MyLogfile.txt  echo Test 1
call :FncTeeOut2 .\MyLogfile.txt  net use x: \\server\freigabe /User:x abc
call :FncTeeOut2 .\MyLogfile.txt  echo Test 2

goto :EOF

:FncTeeOut2     {{comment_single_line_remark:0}}
::Parameters:   <LogFileName> <Command with parameters ...>
::Example:      call :FncTeeOut .\MyLogFile.txt echo It is a test.
  setlocal & set _FncTeeOut_TMP=%TMP%\%~n0_tee%RANDOM%.tmp
  for /F "tokens=1*" %%a in ("%*") do (%%b) > %_FncTeeOut_TMP%  2>&1 &::ParZeile ohne %1 ausführen  
  type %_FncTeeOut_TMP% &::Ausgabe der vorherigen Befehlszeile auf dem Bildschirm anzeigen...
  type %_FncTeeOut_TMP% >> %1 &::... und ins Logfile schreiben
  del %_FncTeeOut_TMP% & endlocal
 exit /b 0

rem Ausgaben innerhalb der Batch zweimal erzeugen und die zweite Ausgabe ins Log schreiben:
echo xyz
echo xyz >>.\MyLogfile.txt

rem Oder nur im Fehlerfall den Befehl nochmals ausführen und Ausgabe ins Log schreiben:
net use x: \\server\freigabe 
if Errorlevel 1 net use x: \\server\freigabe >>.\MyLogfile.txt

rem Alternativ dazu
net use x: \\server\freigabe 2>NUL
if Errorlevel 1 (
  echo Laufwerk X: konnte nicht verbunden werden!
  echo Laufwerk X: konnte nicht verbunden werden! >>.\MyLogfile.txt
)

MyBatch.cmd | tee.exe .\MyLogfile.txt