Login bei Dyn.com automatisieren

login.exe [username] [password]

#NoTrayIcon
; -------------ÄNDERUNGEN -------------
; 01.03.2014 Login Status wurde nach dem Einloggen nicht mehr korrekt erkannt wegen Deutsch / Englisch-Anpassung der Seite
; 19.09.2013 Dyn.com Seite hat sich geändert (zusätzliche Form ist hinzugekommen, Prüfung auf die ersten 5 Buchstaben der ID der Form hinzugefügt
;--------------------------------------
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_outfile=login.exe
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <IE.au3>
if $Cmdline = 2 then
	$username = $Cmdline[1]
	$password = $Cmdline[2]
Else
	ConsoleWrite(@CRLF & "Fehler in Parametern !   --> Info: " & @CRLF & "    login.exe [USERNAME] [PASSWORD]" & @CRLF)  
	Exit 1
EndIf
ConsoleWrite("Login bei Dyn.com..." & @CRLF)  
$objIE = _IECreate("https://de.account.dyn.com/entrance/",0,0,1)  
if $objIE = 0 then
	ConsoleWriteError("Error: Internet-Explorer-Objekt kann nicht erstellt werden!")  
	exit 1
EndIf
$arrForms = _IEFormGetCollection($objIE)
dim $loginForm
if @error <> 0 then
	ConsoleWriteError("Error: Login-Form kann nicht gefunden werden!")  
	quitError()
Else
	for $oForm in $arrForms
		if StringLower(StringLeft($oForm.id,5)) = "login" then  
			$loginForm = $oForm
		endif
	Next

	if $loginForm = "" then  
		ConsoleWriteError("Error: Login Form nicht gefunden!")  
		quitError()
	endif

EndIf

$objUsername = _IEGetObjById($objIE,$loginForm.id & "_username")  
$objPassword = _IEGetObjById($objIE,$loginForm.id & "_password")  
$objSubmitBtn = _IEGetObjById($objIE,$loginForm.id & "_submit")  
if $objUsername = 0 or $objPassword = 0 or $objSubmitBtn = 0 then
	ConsoleWriteError("Error: Mindestens ein benötigtes Steuerelement nicht gefunden!")  
	quitError()
EndIf

if _IEFormElementSetValue($objUsername,$username) = 1 and _IEFormElementSetValue($objPassword,$password) = 1 then
	_IEAction($objSubmitBtn,"Click")  
	if _IELoadWait($objIE) = 1 then
		$links = _IELinkGetCollection($objIE)
		$loginSuccess = false
		for $l in $links
			if StringRegExp($l.innerHTML ,"Log Out|Ausloggen",0) then  
				$loginSuccess = true
				ExitLoop
			Endif
		Next

		if $loginSuccess then
			ConsoleWrite("Logout..." & @CRLF)  
			_IENavigate($objIE,"https://de.account.dyn.com/entrance/?__logout=1",1)  
			_IEQuit($objIE)
			ConsoleWrite("Fertig...")  
			exit 0
		Else
			ConsoleWriteError("Error: Falscher Benutzername oder Kennwort!")  
			quitError()
		EndIf
	Else
		Switch @error
			Case 6
				ConsoleWriteError("Error: Website Lade-Timeout!")  
			Case Else
				ConsoleWriteError("Error: Website Ladefehler / Code: " & @error)  
		EndSwitch
		quitError()
	Endif
Else
	ConsoleWriteError("Error: Benutzername oder Passwort konnten nicht gesetzt werden")  
	quitError()
EndIf

func quitError()
	_IEQuit($objIE)
	exit 1
EndFunc