(obsolet) CodeBlocks Portable mit MinGW 32 und 64 Bit unter Windows

CodeBlocksPortable
    ├─ Additional_Include
    ├─ CodeBlocks
    └─ Projects

CodeBlocksPortable
    ├─ Additional_Include
    ├─ CodeBlocks
    │      ├─ share
    │      └─ (codeblocks.exe)
    │
    └─ Projects

CodeBlocksPortable
    ├─ Additional_Include
    ├─ CodeBlocks
    │      ├─ mingw32
    │      ├─ mingw64
    │      ├─ share
    │      └─ (codeblocks.exe)
    │
    └─ Projects

CodeBlocksPortable
    ├─ Additional_Include
    ├─ CodeBlocks
    │      ├─ mingw32
    │      ├─ mingw64
    │      ├─ share
    │      │      └─ CodeBlocks
    │      │             └─ locale
    │      │                   └─ de_DE
    │      │                          └─ (codeblocks.mo)
    │      │ 
    │      └─ (codeblocks.exe)
    │
    └─ Projects

Option Explicit
Const prtblConf = "CB-Portable-Config.xml", adVarChar = 200, adDate = 7, BIF_RETURNONLYFSDIRS = &h1, BIF_NONEWFOLDERBUTTON = &h200  
Dim oFSO, oWSH, oSH, oRS, oXML, arrFields
Set oFSO = CreateObject("Scripting.FileSystemObject")  
Set oWSH = CreateObject("WScript.Shell")  
Set oSH = CreateObject("Shell.Application")  
Set oRS = CreateObject("ADODB.Recordset")  
Set oXML = CreateObject("Microsoft.XMLDOM")  
oXML.async = False
oXML.validateOnParse = False
oXML.resolveExternals = False
arrFields = Array("path", "lastMod")  
Main

Function GetLastVer()
  Dim oReq, html, oRx
  GetLastVer = ""  
  On Error Resume Next
  Set oReq = CreateObject("Microsoft.XMLHTTP")  
  oReq.open "GET", "https://sourceforge.net/projects/mingw-w64-dgn/files/mingw-w64/", False  
  oReq.setRequestHeader "Cache-Control", "no-cache, no-store"  
  oReq.send
  If oReq.readyState <> 4 Or oReq.status <> 200 Then Exit Function
  html = oReq.responseText
  Set oRx = New RegExp
  oRx.Pattern = "<tr\s+title=""mingw-w64-\d+-gcc-\d+-win64-(20\d{6})\.7z"""  
  If Not oRx.Test(html) Then Exit Function
  GetLastVer = oRx.Execute(html)(0).SubMatches(0)
End Function

Sub CheckVer()
  Const url = "https://administrator.de/knowledge/codeblocks-portable-mingw-32-64-bit-windows-202510.html#toc-20", gcc = "mingw64\bin\gcc.exe"  
  If Not oFSO.FileExists(gcc) Then Exit Sub
  Dim compDate : compDate = oFSO.GetFile(gcc).DateCreated
  If GetLastVer <= Year(compDate) & Right("0" & Month(compDate), 2) & Right("0" & Day(compDate), 2) Then Exit Sub  
  If MsgBox("Es liegt eine neue Version des Compilers vor. Besuchen Sie" & vbLF & url & vbLF & "und lesen Sie, wie Sie den Compiler updaten können." & vbLF & vbLF & "Möchten Sie die Seite jetzt öffnen?", vbYesNo Or vbInformation Or vbDefaultButton2 Or vbSystemModal, "Neue Compilerversion") = vbYes Then oWSH.Run url  
End Sub

Sub CheckDir(oDir, dir)
  dir = Trim(Replace(dir, "/", "\"))  
  If Not oFSO.FolderExists(dir) Then oSH.NameSpace(oWSH.CurrentDirectory).NewFolder dir
  dir = oFSO.BuildPath(oWSH.CurrentDirectory, dir)
  Set oDir = oFSO.GetFolder(dir)
  dir = oDir.Path
End Sub

Function GetOSArch()
  Dim os
  GetOSArch = "32"  
  For Each os In GetObject("winmgmts:\\.\root\CIMV2").ExecQuery("SELECT * FROM Win32_OperatingSystem WHERE NumberOfProcesses > 0")  
    If InStr(1, os.OSArchitecture, "64", vbTextCompare) Then GetOSArch = "64"  
  Next
End Function

Sub GetAllProjs(oDir)
  Dim oFile, oSubD, path
  For Each oFile In oDir.Files
    path = oFile.Path
    If StrComp(oFSO.GetExtensionName(path), "layout", vbTextCompare) = 0 Then oRS.AddNew arrFields, Array(Left(path, Len(path) - 6) & "cbp", oFile.DateLastModified)  
  Next
  For Each oSubD In oDir.SubFolders
    If oSubD.Name <> "_archive_" Then GetAllProjs oSubD  
  Next
End Sub

Sub CreatePrtblConf(cbDir, projDir, aInclDir, updtCmplr)
  Const tail = " - Rootverzeichnis, RELATIV zum Script"" />"  
  oFSO.CreateTextFile(prtblConf).Write "<?xml version=""1.0"" encoding=""Windows-1252"" standalone=""yes""?>" & vbCrLf & "<!-- Einstellungen für CB-Portable-Launcher -->" & vbCrLf & "<CB_Portable_Launcher_Config version=""1"">" & vbCrLf & _  
    vbTab & "<relative_pathes description=""Die path-Attribute geben die relativen Pfade an."">" & vbCrLf & _  
    vbTab & vbTab & "<CBDir path=""" & cbDir & """ description=""Pfad zum CodeBlocks" & tail & vbCrLf & _  
    vbTab & vbTab & "<ProjDir path=""" & projDir & """ description=""Pfad zum Projects" & tail & vbCrLf & _  
    vbTab & vbTab & "<AdditionalIncludeDir path=""" & aInclDir & """ description=""Pfad zum Additional_Include" & tail & vbCrLf & _  
    vbTab & "</relative_pathes>" & vbCrLf & _  
    vbTab & "<search_compiler_update check=""" & updtCmplr & """ description=""Versionsdatum des Compilers verifizieren, 0=nein, 1=ja"" />" & vbCrLf & _  
    "</CB_Portable_Launcher_Config>"  
End Sub

Sub CreateConfFile(confFile)
  oFSO.CreateTextFile(confFile).Write "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes"" ?><CodeBlocksConfig version=""1""><app><environment><CHECK_ASSOCIATIONS bool=""0"" /></environment><SHOW_TIPS bool=""0"" /><RECENT_PROJECTS><astr /></RECENT_PROJECTS>" & _  
    "<locale><ENABLE bool=""1"" /></locale></app><project_manager><DEFAULT_PATH><str /></DEFAULT_PATH></project_manager><compiler><build_progress /><SETTINGS_VERSION><str><![CDATA[0.0.3]]></str></SETTINGS_VERSION>" & _  
    "<sets><gcc><NAME><str><![CDATA[GNU GCC Compiler]]></str></NAME><COMPILER_OPTIONS><str><![CDATA[-Wall;-std=c++20;-std=c17;-s;-ffunction-sections;-fdata-sections;]]></str></COMPILER_OPTIONS>" & _  
    "<LINKER_OPTIONS><str><![CDATA[-O3;-static-libstdc++;-static-libgcc;-Wl,-Bstatic -lstdc++ -lpthread;-Wl,--gc-sections;]]></str></LINKER_OPTIONS><MASTER_PATH><str /></MASTER_PATH><C_COMPILER><str><![CDATA[gcc.exe]]></str></C_COMPILER>" & _  
    "<CPP_COMPILER><str><![CDATA[g++.exe]]></str></CPP_COMPILER><LINKER><str><![CDATA[g++.exe]]></str></LINKER><MAKE><str><![CDATA[make.exe]]></str></MAKE></gcc></sets><DEFAULT_COMPILER><str><![CDATA[gcc]]></str></DEFAULT_COMPILER></compiler>" & _  
    "<debugger_common><sets><gdb_debugger><conf1><NAME><str><![CDATA[Default]]></str></NAME><values><EXECUTABLE_PATH><str /></EXECUTABLE_PATH></values></conf1></gdb_debugger></sets></debugger_common><scripts><generic_wizard><WANT_DEBUG bool=""1"" /><DEBUG_NAME><str><![CDATA[Debug]]></str></DEBUG_NAME>" & _  
    "<DEBUG_OUTPUT><str /></DEBUG_OUTPUT><DEBUG_OBJECTS_OUTPUT><str /></DEBUG_OBJECTS_OUTPUT><WANT_RELEASE bool=""1"" /><RELEASE_NAME><str><![CDATA[Release]]></str></RELEASE_NAME><RELEASE_OUTPUT><str /></RELEASE_OUTPUT><RELEASE_OBJECTS_OUTPUT><str /></RELEASE_OBJECTS_OUTPUT></generic_wizard></scripts></CodeBlocksConfig>"  
End Sub

Sub UpdtCData(baseNode, data)
  Dim oNode, oItem
  Set oNode = oXML.documentElement.selectSingleNode(baseNode & "/str")  
  If Not oNode Is Nothing Then oNode.parentNode.removeChild oNode
  Set oItem = oXML.createNode(1, "str", "")  
  Set oNode = oXML.documentElement.selectSingleNode(baseNode)
  oNode.appendChild oItem
  Set oNode = oXML.documentElement.selectSingleNode(baseNode & "/str")  
  Set oItem = oXML.createCDATASection(data)
  oNode.appendChild oItem
End Sub

Sub ClearNode(baseNode, node)
  Dim oNode, oItem
  Set oNode = oXML.documentElement.selectSingleNode(baseNode & "/" & node)  
  If Not oNode Is Nothing Then oNode.parentNode.removeChild oNode
  Set oNode = oXML.documentElement.selectSingleNode(baseNode)
  Set oItem = oXML.createElement(node)
  oNode.appendChild oItem
End Sub

Sub UpdtRecents()
  Dim oNode, oItem, i
  Set oNode = oXML.documentElement.selectSingleNode("app/RECENT_PROJECTS/astr")  
  oRS.Sort = arrFields(1) & " DESC"  
  oRS.MoveFirst
  i = 0
  While Not oRS.EOF And i < 20
    If oFSO.FileExists(oRS(arrFields(0))) Then
      Set oItem = oXML.createNode(1, "s", "")  
      oNode.appendChild oItem
      Set oItem = oXML.createCDATASection(oRS(arrFields(0)))
      oNode.childNodes(i).appendChild oItem
      i = i + 1
    End If
    oRS.MoveNext
  Wend
End Sub

Function UpdtConf(confFile, projDir, aInclDir, mingwDir, os)
  Dim oNode, oItem
  UpdtConf = False
  oXML.load confFile
  If oXML.parseError.errorCode Then Exit Function
  UpdtCData "compiler/sets/gcc/MASTER_PATH", mingwDir  
  UpdtCData "debugger_common/sets/gdb_debugger/conf1/values/EXECUTABLE_PATH", mingwDir & "\bin\gdb.exe"  
  UpdtCData "project_manager/DEFAULT_PATH", projDir & "\"  
  ClearNode "compiler/sets/gcc", "INCLUDE_DIRS"  
  UpdtCData "compiler/sets/gcc/INCLUDE_DIRS", mingwDir & "\mingw\include;" & aInclDir & ";"  
  ClearNode "compiler/sets/gcc", "LIBRARY_DIRS"  
  UpdtCData "compiler/sets/gcc/LIBRARY_DIRS", mingwDir & "\mingw\lib;"  
  UpdtCData "scripts/generic_wizard/DEBUG_OUTPUT", "bin\Debug_x" & os & "\"  
  UpdtCData "scripts/generic_wizard/DEBUG_OBJECTS_OUTPUT", "obj\Debug_x" & os & "\"  
  UpdtCData "scripts/generic_wizard/RELEASE_OUTPUT", "bin\Release_x" & os & "\"  
  UpdtCData "scripts/generic_wizard/RELEASE_OBJECTS_OUTPUT", "obj\Release_x" & os & "\"  
  Set oNode = oXML.documentElement.selectSingleNode("app/RECENT_PROJECTS/astr")  
  If Not oNode Is Nothing Then oNode.parentNode.removeChild oNode
  Set oItem = oXML.createNode(1, "astr", "")  
  Set oNode = oXML.documentElement.selectSingleNode("app/RECENT_PROJECTS")  
  oNode.appendChild oItem
  If oRS.RecordCount Then UpdtRecents
  oXML.save confFile
  UpdtConf = True
End Function

Sub UpdtCBProjFiles(os)
  Dim oNode, file
  If oRS.RecordCount = 0 Then Exit Sub
  oRS.MoveFirst
  While Not oRS.EOF
    On Error Resume Next
    file = oRS("path")  
    oXML.load file
    Set oNode = oXML.documentElement.selectNodes("Project/Build/Target[@title='Debug']")(0).selectNodes("Option[@output]")(0)  
    oNode.setAttribute "output", "bin/Debug_x" & os & "/" & oFSO.GetFileName(oNode.getAttribute("output"))  
    oXML.documentElement.selectNodes("Project/Build/Target[@title='Debug']")(0).selectNodes("Option[@object_output]")(0).setAttribute "object_output", "obj/Debug_x" & os & "/"  
    Set oNode = oXML.documentElement.selectNodes("Project/Build/Target[@title='Release']")(0).selectNodes("Option[@output]")(0)  
    oNode.setAttribute "output", "bin/Release_x" & os & "/" & oFSO.GetFileName(oNode.getAttribute("output"))  
    oXML.documentElement.selectNodes("Project/Build/Target[@title='Release']")(0).selectNodes("Option[@object_output]")(0).setAttribute "object_output", "obj/Release_x" & os & "/"  
    oXML.save file
    On Error Goto 0
    oRS.MoveNext
  Wend
End Sub

Function GetRelFolder(msg, style)
  Dim oDir, sel, diff, siz
  GetRelFolder = ""  
  Set oDir = oSH.BrowseForFolder(0, "Bitte wählen Sie das " & msg & "-Verzeichnis aus.", style, oWSH.CurrentDirectory)  
  If oDir Is Nothing Then Exit Function
  sel = oDir.Self.Path
  siz = Len(oWSH.CurrentDirectory)
  If Left(sel, siz) <> oWSH.CurrentDirectory Then Exit Function
  If siz = 3 Then siz = 2
  diff = Len(sel) - siz
  If diff < 1 Then Exit Function
  GetRelFolder = Right(sel, diff - 1)
  If Not oFSO.FolderExists(GetRelFolder) Then GetRelFolder = ""  
End Function

Sub ObtainSettings(cbDir, projDir, aInclDir, updtCmplr)
  Const head = "Wählen Sie nachfolgend das Verzeichnis aus, in dem ", tail = "Dieser Schritt wird wiederholt, wenn es sich nicht um ein Unterverzeichnis relativ zu diesem Script handelt."  
  oSH.MinimizeAll
  Do
    If MsgBox(head & """codeblocks.exe"" zu finden ist." & vbLf & tail, vbOKCancel Or vbInformation Or vbSystemModal, "Code::Blocks - Verzeichnis") = vbCancel Then WScript.Quit  
    cbDir = GetRelFolder("Code::Blocks", BIF_RETURNONLYFSDIRS Or BIF_NONEWFOLDERBUTTON)  
  Loop While cbDir = ""  
  Do
    If MsgBox(head & "Ihre Projekte gespeichert werden." & vbLf & tail, vbOKCancel Or vbInformation Or vbSystemModal, "Projects - Verzeichnis") = vbCancel Then WScript.Quit  
    projDir = GetRelFolder("Projects", BIF_RETURNONLYFSDIRS)  
  Loop While projDir = ""  
  Do
    If MsgBox(head & "Sie weitere Dateien ablegen können, die Sie in Ihre Codes einbeziehen wollen." & vbLf & tail, vbOKCancel Or vbInformation Or vbSystemModal, "Additional_Include - Verzeichnis") = vbCancel Then WScript.Quit  
    aInclDir = GetRelFolder("Additional_Include", BIF_RETURNONLYFSDIRS)  
  Loop While aInclDir = ""  
  updtCmplr = MsgBox("Möchten Sie, dass bei jedem Start überprüft wird, ob eine neue Version des Compilers verfügbar ist?" & vbLf & "(Zu diesem Zweck werden Informationen aus dem Internet angefordert.)", vbYesNoCancel Or vbQuestion Or vbSystemModal, "Versionsüberprüfung Compiler")  
  If updtCmplr = vbCancel Then WScript.Quit
  updtCmplr = vbNo - updtCmplr
  CreatePrtblConf cbDir, projDir, aInclDir, updtCmplr
  MsgBox "Ihre Einstellungen wurden in """ & prtblConf & """ abgelegt und können nachträglich in den ""path""- bzw. ""check""-Attributen geändert werden.", vbInformation Or vbSystemModal, prtblConf  
End Sub

Sub ReadSettings(cbDir, projDir, aInclDir, updtCmplr)
  oXML.load prtblConf
  If oXML.parseError.errorCode Then WScript.Quit MsgBox("Fehler in Datei """ & prtblConf & """" & vbLf & oXML.parseError.reason, vbCritical Or vbSystemModal, "Fehler")  
  Dim oNode : Set oNode = oXML.documentElement.selectSingleNode("relative_pathes/CBDir")  
  cbDir = oNode.getAttribute("path")  
  Set oNode = oXML.documentElement.selectSingleNode("relative_pathes/ProjDir")  
  projDir = oNode.getAttribute("path")  
  Set oNode = oXML.documentElement.selectSingleNode("relative_pathes/AdditionalIncludeDir")  
  aInclDir = oNode.getAttribute("path")  
  Set oNode = oXML.documentElement.selectSingleNode("search_compiler_update")  
  updtCmplr = CInt(oNode.getAttribute("check"))  
End Sub

Sub Main()
  Dim oProjDir, cbDir, projDir, aInclDir, confFile, mingwDir, appdataDir, os, updtCmplr
  If GetObject("winmgmts:\\.\root\CIMV2").ExecQuery("SELECT * FROM Win32_Process WHERE Name='codeblocks.exe'").Count Then WScript.Quit  
  oWSH.CurrentDirectory = oFSO.GetParentFolderName(WScript.ScriptFullName)
  If oFSO.FileExists(prtblConf) Then : ReadSettings cbDir, projDir, aInclDir, updtCmplr : Else : ObtainSettings cbDir, projDir, aInclDir, updtCmplr : End If
  CheckDir , aInclDir
  CheckDir , cbDir
  CheckDir oProjDir, projDir
  oWSH.CurrentDirectory = cbDir
  If updtCmplr = 1 Then CheckVer
  If Not oFSO.FileExists("codeblocks.exe") Then WScript.Quit MsgBox("""codeblocks.exe"" konnte nicht gefunden werden." & vbLf & "Prüfen Sie den Pfad in """ & prtblConf & """.", vbCritical Or vbSystemModal, "Fehler")  
  oRS.Fields.Append arrFields(0), adVarChar, 255
  oRS.Fields.Append arrFields(1), adDate
  oRS.Open
  GetAllProjs oProjDir
  os = GetOSArch
  If os = "64" Then If MsgBox("Sollen 64-Bit-Anwendungen erstellt werden?", vbYesNo Or vbQuestion Or vbSystemModal, "Windows x64 detektiert.") = vbNo Then os = "32"  
  confFile = oFSO.BuildPath(cbDir, "AppData\codeblocks\default.conf")  
  mingwDir = oFSO.BuildPath(cbDir, "mingw" & os)  
  appdataDir = oFSO.BuildPath(cbDir, "AppData")  
  If Not oFSO.FileExists(confFile) Then
    If Not oFSO.FolderExists(appdataDir) Then oFSO.CreateFolder appdataDir
    If Not oFSO.FolderExists(appdataDir & "\codeblocks") Then oFSO.CreateFolder appdataDir & "\codeblocks"  
    CreateConfFile confFile
  End If
  If os = "32" Then os = "86"  
  If Not UpdtConf(confFile, projDir, aInclDir, mingwDir, os) Then WScript.Quit MsgBox("Der Pfad zu MinGW konnte in Datei" & vbLf & """" & confFile & """" & vbLf & "nicht angepasst werden." & vbLf & "Code::Blocks kann den Compiler nicht aufrufen.", vbCritical Or vbSystemModal, "Fehler")  
  oWSH.Environment("PROCESS")("APPDATA") = appdataDir  
  oWSH.Run "codeblocks.exe"  
  UpdtCBProjFiles os
End Sub

CodeBlocksPortable
    ├─ Additional_Include
    ├─ CodeBlocks
    │      ├─ mingw32
    │      ├─ mingw64
    │      ├─ share
    │      └─ (codeblocks.exe)
    │
    ├─ Projects
    └─ (CB-Portable-Launcher.vbs)