RoboCopy mit sichern von gelöschten Dateien

@echo off
REM
REM Job zum Auswerten des Logfiles von Robocopy und verschieben der gelöschten Dateien in ein Sicherungsverzeichnis
REM

REM "Hilfsprogramme" ausführen  
if "%1" == "-CHECK-" GOTO DoCheck  
if "%1" == "-COPYF-" GOTO DoCopyFile  
if "%1" == "-COPYD-" GOTO DoCopyDir  

REM Hier die gewünschten Parameter eintragen:
REM COPY_DIR: Verzeichnis in welches die gelöschten Daten verschoben werden
REM LogFile: RoboCopy Logdatei
SET COPY_DIR=Deleted\%date%_%time:~0,2%_%time:~3,2%_%time:~6,2%
SET LogFile=Sicherung.log

REM Logdatei durcharbeiten
FOR /F "tokens=1,2,3,*" %%i in (%LogFile%) DO CALL %0 -CHECK- %%i %%j %%k "%%l"  
goto Fertig

REM Prüfen einer Log-Zeile
:DoCheck
REM      %2    %3         %4         %5
REM *ZUS. Verz.       -1 D:\test\robo\d\u1\
REM  *EXTRA Datei 1875110 D:\test\robo\d\cygwin1.dll

SET iii=%2
IF "%iii:~0,1%"=="*" (  
echo %2 %3 %4 %5
IF "%4"=="-1" (  
CALL %0 -COPYD- %5
) ELSE (
CALL %0 -COPYF- %5
)
ECHO.
)
goto end


REM Datei verschieben
:DoCopyFile
IF NOT EXIST "%COPY_DIR%\%~p2" (  
ECHO MD "%COPY_DIR%\%~p2"  
MD "%COPY_DIR%\%~p2"  
)
ECHO CopyFile: %2 to "%COPY_DIR%\%~pnx2"  
move %2 "%COPY_DIR%\%~pnx2"  
goto end

REM Verzeichnis verschieben
:DoCopyDir
IF NOT EXIST "%COPY_DIR%\%~pnx2" (  
ECHO MD "%COPY_DIR%\%~pnx2"  
MD "%COPY_DIR%\%~pnx2"  
)
ECHO CopyDir: "%~2*.*" TO "%COPY_DIR%\%~pnx2"  
FOR /R %2 %%f IN (*.*) DO MOVE %f "%COPY_DIR%\%~pnx2"  
rem XCOPY "%~2*.*" "%COPY_DIR%\%~pnx2"  
goto end

:Fertig

:end