Top-Themen

Aktuelle Themen (A bis Z)

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit

gelöst ACL Datenbank erstellen

Mitglied: Praktikantin

Praktikantin (Level 1) - Jetzt verbinden

19.02.2007, aktualisiert 20.02.2007, 10282 Aufrufe, 10 Kommentare

Hallo!

Ich bin seit ein paar Wochen Praktikantin in einer großen Firma und ich habe diese Aufgabe bekommen: Ich muss eine ACL Datenbank erstellen für alle Ordner die es in unserem Netzwek gibt. Ich habe bis jetzt 2 Lösungen gefunden. Erstens habe ich dieses Tool ausprobiert http://www.microsoft.com/technet/sysinternals/Security/AccessEnum.mspx . Zuerst dachte ich es ist nicht so toll weil es auch alle Dateien die es gibt auflistet und man so sehr viel Zeit braucht um die Ordner heraus zu suchen. Dann habe ich aber eine Lösung gefunden. Einfach die Textdatei in Access importieren und dann die abfrage "Nicht wie "*.*"" erstellen. So hatte ich in der neuen Abfrage Tabelle nur die Ordner. Aber leider listet dieses Programm nicht alle Ordner und Dateien auf. Ich weiß wirklich nicht warum. Habe alle Optionen versucht aber von den ca. 500.000 Dokumenten/Ordner habe ich nur 10.000 aufgelistet bekommen.
Dann habe ich ein Vbs gefunden: http://www.codeproject.com/vbscript/VBScript_ACL_Crawl.asp .
Es läuft wunderbar und es exportiert mit hilfe von cacls.exe alle Ordner und die Benutzerrechte. Leider ist die Form die Exportiert wird nicht gerade toll. Ich kann sie in dieser Form nicht in einer Datenbank importieren, weil ich die Zeilen einfach nicht trennen kann. Kann mir irgendjemmand einen Tipp geben? Vielleicht warum AccessEnum nicht alles auflistet oder wie ich calcs.exe manipulieren konnte oder das VBS damit es in einer Tabellen geeigneten Form exportiert wird?

Vielen Dank und jeder eizelne Rat ist wilkommen!!!
Mitglied: Mamut
19.02.2007 um 10:20 Uhr
Hast du mal ein Paar Zeilen aus dem Dokument welches von cacls.exe erstellt wird?

Dann kann man dir event auch helfen daraus ein Importierbares File zu machen :D
Bitte warten ..
Mitglied: Praktikantin
19.02.2007 um 10:29 Uhr
Hallo und danke für die Schnelle Antwort

Also die Text Datei die exportiert wird hat diese Form:

Microsoft (R) Windows Script Host, Version 5.6
Copyright (C) Microsoft Corporation 1996-2001. Alle Rechte vorbehalten.

C:\
C:\263b24a6c00389b5ece90e6cd82031 VORDEFINIERT\Administratoren:F
DOMABC\:F
DOMABC\:F


C:\AccessEnum VORDEFINIERT\AdministratorenOI)(CI)F
NT-AUTORITŽT\SYSTEMOI)(CI)F
DOMABC\:F
ERSTELLER-BESITZEROI)(CI)(IO)F
VORDEFINIERT\BenutzerOI)(CI)R
VORDEFINIERT\BenutzerCI)(Beschr„nkter Zugriff

FILE_APPEND_DATA

VORDEFINIERT\BenutzerCI)(Beschr„nkter Zugriff

FILE_WRITE_DATA



C:\ACMPClient VORDEFINIERT\AdministratorenOI)(CI)F
NT-AUTORITŽT\SYSTEMOI)(CI)F
VORDEFINIERT\Administratoren:F
ERSTELLER-BESITZEROI)(CI)(IO)F
VORDEFINIERT\BenutzerOI)(CI)R
VORDEFINIERT\BenutzerCI)(Beschr„nkter Zugriff

FILE_APPEND_DATA

VORDEFINIERT\BenutzerCI)(Beschr„nkter Zugriff

FILE_WRITE_DATA

Wie soll ich denn diesses Text Dokument in einer Datenbank einfügen? Es wird einfach alles in einer Zelle impotiert! Ich bin wirklich ratlos...
Bitte warten ..
Mitglied: AndreasHoster
19.02.2007 um 10:40 Uhr
Wenn Du einfach mal die Optionen (soviele gibts nicht) von AccessEnum durchliest, dann kannst Du erkennen, warum es nicht alle anzeigt:
By Default AccessEnum treats files and Directories differently:
- Directories are displayed if their permissions differ from their parent folder
- Files are displayed if their permissions are more lax than their parent folder

-> Wenn Ordner und Datei exakt die Rechte von oben ererben, werden sie nicht angezeigt.

Nein, zu CACLS kann ich Dir auch nicht helfen, aber man kann direkt die ACLs mit VBS und WMI auslesen, hier ein kurzes Stück VBS Code (muß natürlich noch angepasst werden), welches entweder eine einzelne Datei oder eine ganz Ordner-Struktur durchgeht und die Berechtigungen ausgibt (nicht in Tabellenform, aber das ließe sich ja anpassen):
01.
' **************************************************
02.
' * HINWEISE: Auslesen der Berechtigung von Dateien / Ordnern
03.
' **************************************************
04.
dim sec(32)
05.
dim art(4)
06.
' Array um Rechte Bits in Lesbare Form umzusetzen
07.
sec(0)="Lesen"
08.
sec(1)="Schreiben"
09.
sec(2)="Anfügen"
10.
sec(3)="Lesen (Extended)"
11.
sec(4)="Schreiben (Extended)"
12.
sec(5)="Ausführen"
13.
sec(6)="Löschen"
14.
sec(7)="Attribute Lesen"
15.
sec(8)="Attribute Schreiben"
16.
sec(9)="9"
17.
sec(10)="10"
18.
sec(11)="11"
19.
sec(12)="12"
20.
sec(13)="13"
21.
sec(14)="14"
22.
sec(15)="15"
23.
sec(16)="Löschen (Force)"
24.
sec(17)="Sicherheit lesen"
25.
sec(18)="ACL Schreiben"
26.
sec(19)="Besitz übernehmen"
27.
sec(20)="Synchronisieren"
28.
sec(21)="21"
29.
sec(22)="22"
30.
sec(23)="23"
31.
sec(24)="24"
32.
sec(25)="25"
33.
sec(26)="26"
34.
sec(27)="27"
35.
sec(28)="28"
36.
sec(29)="29"
37.
sec(30)="30"
38.
sec(31)="31"
39.
art(0)="Erlaubnis"
40.
art(1)="Verbot"
41.
art(2)="Audit"
42.
' Benötigte Objekte erstellen
43.
Set fso = CreateObject("Scripting.FileSystemObject")
44.
Set wshnet = CreateObject("WScript.Network")
45.
sDatei = InputBox("Name der Datei oder Verzeichnis?","Dateiauswahl","D:\temp8")
46.
wscript.echo Time()
47.
If fso.FolderExists(sDatei) then
48.
	Rechte sDatei
49.
	VerzDurchgang(fso.getfolder(sDatei))
50.
else
51.
	wscript.echo Rechte(sDatei)
52.
End If
53.
wscript.echo Time()
54.

55.

56.
' ***********************************
57.
' ***** Funktionen & Prozeduren *****
58.
' ***********************************
59.

60.
Function Rechte(sDatei)
61.
	' Verbindung zur Windows Managment Instrumentation herstellen und ACL Objekt erhalten
62.
	sConnect = "winmgmts:Win32_LogicalFileSecuritySetting='" & sDatei & "'"
63.
	Set oDatei = GetObject(sConnect)
64.
	status = oDatei.getsecurityDescriptor(oDescriptor)
65.
	oACL = oDescriptor.Properties_.Item("dacl").Value
66.
	list = sDatei & vbcrlf
67.
	'  Alle Einträge durchgehen und Ausgabe zusammenbasteln
68.
	For each entry in oACL
69.
		list = list & entry.Trustee.SIDString & vbcrlf & entry.Trustee.Name & ":" & entry.AccessMask & " - " & art(entry.ACEType) &  vbCrLf & secText(entry.AccessMask)
70.
	Next
71.
	Wscript.echo list
72.
	Wscript.echo "--------------------------------"
73.
End Function
74.

75.
Function SecText(binary)
76.
	For x = 0 to 30
77.
		If (binary And 2^x)<>0 then
78.
			sTemp = sTemp & CStr(x) & ":" & CStr(sec(x)) & vbCrLf
79.
		End If
80.
	Next
81.
	SecText = sTemp
82.
End Function
83.

84.
Sub VerzDurchgang(Verzeichnis)
85.
 ' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen
86.
 On Error Resume Next
87.
 FilesDurchgang Verzeichnis
88.
 For each folder in Verzeichnis.Subfolders
89.
  '***** Was jetzt tun? -> Rechte auslesen
90.
  call Rechte(folder.Path)
91.
  VerzDurchgang folder
92.
 Next
93.
End Sub
94.

95.
Sub FilesDurchgang(Verzeichnis)
96.
' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen
97.
On Error Resume Next
98.
 For each file in Verzeichnis.files
99.
 	' ***** Was jetzt tun? Rechte auslesen
100.
	Call Rechte(file.Path)
101.
 Next
102.
End Sub
Bitte warten ..
Mitglied: Praktikantin
19.02.2007 um 11:04 Uhr
Hallo AndreasHoster und vielen Dank für den Tipp!

Der VBScript ist wirklich sehr hilfreich und alles wird angezeigt. Leider bin ich in VBScript keine Leuchte und es ist wirklich sehr schwer für mich in Diesem Script eine Funktion die die Ordner in einer Textdatei exportiert einzufügen. Es wäre wirklich sehr hilfreich wenn sie das auch in dem Script einfügen würden. Es wäre schon toll wenn nur das Verzeichnis und die Rechte in einer Textdatei expotiert werden und sie sich mit einem komma oder " unterscheiden würden. Ich wäre ihnen wirklich seeeeehr dankbar!!!
Bitte warten ..
Mitglied: Praktikantin
19.02.2007 um 14:08 Uhr
Hallo nochmals!

Kann mir irgendjemmand bitte helfen. Das vorrige Script ist wirklich gut aber ich verstehe nicht was es exportiert:
Microsoft (R) Windows Script Host, Version 5.6
Copyright (C) Microsoft Corporation 1996-2001. Alle Rechte vorbehalten.

11:12:17
C:\
S-1-5-32-544
Administratoren:2032127 - Erlaubnis
0:Lesen
1:Schreiben
2:Anfgen
3:Lesen (Extended)
4:Schreiben (Extended)
5:Ausfhren
6:L”schen
7:Attribute Lesen
8:Attribute Schreiben
16:L”schen (Force)
17:Sicherheit lesen
18:ACL Schreiben
19:Besitz bernehmen
20:Synchronisieren
S-1-5-18
SYSTEM:2032127 - Erlaubnis
0:Lesen
1:Schreiben
2:Anfgen
3:Lesen (Extended)
4:Schreiben (Extended)
5:Ausfhren
6:L”schen
7:Attribute Lesen
8:Attribute Schreiben
16:L”schen (Force)
17:Sicherheit lesen
18:ACL Schreiben
19:Besitz bernehmen
20:Synchronisieren
S-1-3-0
ERSTELLER-BESITZER:268435456 - Erlaubnis
28:28
S-1-5-32-545
Benutzer:1179817 - Erlaubnis
0:Lesen
3:Lesen (Extended)
5:Ausfhren
7:Attribute Lesen
17:Sicherheit lesen
20:Synchronisieren
S-1-5-32-545
Benutzer:4 - Erlaubnis
2:Anfgen
S-1-5-32-545
Benutzer:2 - Erlaubnis
1:Schreiben
S-1-1-0
Jeder:1179817 - Erlaubnis
0:Lesen
3:Lesen (Extended)
5:Ausfhren
7:Attribute Lesen
17:Sicherheit lesen
20:Synchronisieren

Ich verstehe es einfach nicht... Das AccessEnum läuft wirklich gut und ich habe auch beide Optionen versucht. Trotzdem gibt es nicht alle Dateien raus (wegen der 2 Optionen).
Ich habe wirklich keine Ahnung von VBScript. Ich erkenne ein paar Befehle da ich mich mit Java, C, HTML, PHP auskenne aber sonst nichts. Hier muss ich wohl was ändern:

Function SecText(binary)
For x = 0 to 30
If (binary And 2^x)<>0 then
sTemp = sTemp & CStr(x) & ":" & CStr(sec(x)) & vbCrLf
End If
Next
SecText = sTemp
End Function

Aber wie gesagt der Output ist nicht verständlich... Wenn mir irgendjemmand einen Rat geben konnte oder ein Buch emphelen könnte wäre ich wirklich sehr Dankbar.

MlG

die Praktikantin
Bitte warten ..
Mitglied: AndreasHoster
19.02.2007 um 14:25 Uhr
Ich bin nur noch nicht zum Antworten gekommen bezüglich Deinen Änderungswünschen, muß schließlich auch arbeiten

Beispiel Erklärung:
S-1-1-0 = Die Gruppe Jeder hat diese SID
Jeder:1179817 - Erlaubnis = Die ACL als Zahl ist 1179817 und ist eine Erlaubnisliste, keine Verbotsliste
Jetzt kommen einzeln Rechte, die Jeder hat:
0:Lesen
3:Lesen (Extended)
5:Ausfhren
7:Attribute Lesen
17:Sicherheit lesen
20:Synchronisieren

Die Zahl davor ist welches Bit bei 1179817 gesetzt ist, daraus ergibt sich welche Berechtigung man hat (z.B. bedeutet gesetztes Bit 0 (wird halt so nummeriert, da Arrays bei 0 anfangen) das man Lesen-Rechte hat, wenn es eine Erlaubt Liste ist).

Am einfachsten bekommt man die Idee, was was bedeutet, wenn man eine Datei nimmt, die Rechte ändert und dann jeweils schaut, was als Ergebniss zurückkommt.
Bitte warten ..
Mitglied: Praktikantin
19.02.2007 um 14:48 Uhr
Hallo!

Das habe ich gemacht und die Rechte für eine Datei geändert und eine andere nummer bokommen. Ich habe das hier entdeckt:

'access level r, w, f 2032127 '2032127 = "Full"; 1245631 = "Change"; 1179817 = "Read

Ich muss wohl dann anhand dieser Nummern arbeiten. Tut mir wirklich leid dass ich so ungeduldig war... Mal sehen was sich machen lässt. Ich mach mich ein bisschen schlau (Visual Basic). Vielen Dank für die Große Hilfe. Ich hoffe ich kenne mich bald auch so gut aus wie Sie...

Wenn Sie die kleinen Änderungen für mich machen würden wäre ich ihnen unendlich dankbar!!!
Bitte warten ..
Mitglied: AndreasHoster
20.02.2007 um 08:50 Uhr
Die Nummern setzen sich aus den Einzelrechten zusammen und da zum normalen Lesen auch sowas gehört wie Sicherheit Lesen und Attribute Lesen etc, ergeben sich dann so Kombinationen wie 1179817 als Wert zur normalen Leseberechtigung.
Allerdings kommt man mit WMI halt eine Stufe tiefer an die Rechte und liest die Einzelrechte aus. Das ist genau das, was man auch sieht wenn man auf Sicherheit -> Erweitert und dann auf Bearbeiten geht. Dort sieht man auch die einzelnen Einträge.

Jetzt bleibt noch die Frage, ob Du für jeden Eintrag in der ACL eine neue Zeile haben willst (hat den Vorteil, daß die Zeile immer 5 Einträge hat, nämlich Ordner-Pfad, Name des Users, SID des Users, Art des Eintrags, Berechtigungsstufe (OK, man könnte SID z.B. weglassen)) oder ob alle User in einer Zeile kommen sollen, dann weiß man halt nicht, wieviele Einträge kommen (macht die automatische Verarbeitung nicht so einfach).
Wenn es in eine relationale DB kommen soll, ist pro Eintrag eine Zeile besser, und ich mache das im Beispielskript auch so.
Außerdem habe ich es so umgebaut, daß der Startordner per Kommandozeile übergeben wird. Trennung per ;
Starten mit cscript.exe skriptname.vbs Pfad_des_Startordners > Ausgabedatei
01.
' **************************************************
02.
' *
03.
' * VBScript Quelldatei -- erstellt mit Scripting Spy 3.0
04.
' *
05.
' *
06.
' *
07.
' * HINWEISE: Auslesen der Berechtigung von Dateien / Ordnern
08.
' *
09.
' **************************************************
10.

11.
' Kommandozeilenparamter
12.
Set args = Wscript.Arguments
13.
'***** Test ob richtige Anzahl an Kommandozeilenparametern angegeben wurde
14.
If args.Count <> 1 Then
15.
    Wscript.echo "Bitte den Startpunkt (Datei oder Ordner) angeben!"
16.
    Wscript.Quit
17.
End If
18.
sDatei = args(0)
19.
' Array, um die Art des Eintrags zu ermitteln
20.
dim art(4)
21.
art(0)="Erlaubnis"
22.
art(1)="Verbot"
23.
art(2)="Audit"
24.
' Dictionary, um die Zahlen in Texte zu übersetzen
25.
' Es können beliebige weitere eingetragen werden
26.
Set dict = CreateObject("Scripting.Dictionary")
27.
call dict.add(2032127,"Full")
28.
call dict.add(1245631,"Change")
29.
call dict.add(1179817,"Read")
30.
' Sonstige benötigte Objekte erzeugen
31.
Set fso = CreateObject("Scripting.FileSystemObject")
32.
Set wshnet = CreateObject("WScript.Network")
33.
' Bei Eingabe einer Einzel-Datei werden nur die Rechte der Einzeldatei ausgegeben
34.
' Bei Angabe eines Verzeichnisses alle Unterverzeichnisse (inklusive des Startverzeichnisses
35.
If fso.FolderExists(sDatei) then
36.
	Rechte sDatei
37.
	VerzDurchgang(fso.getfolder(sDatei))
38.
else
39.
	wscript.echo Rechte(sDatei)
40.
End If
41.

42.

43.
' ***********************************
44.
' ***** Funktionen & Prozeduren *****
45.
' ***********************************
46.

47.
Function Rechte(sDatei)
48.
	sConnect = "winmgmts:Win32_LogicalFileSecuritySetting='" & sDatei & "'"
49.
	Set oDatei = GetObject(sConnect)
50.
	status = oDatei.getsecurityDescriptor(oDescriptor)
51.
	oACL = oDescriptor.Properties_.Item("dacl").Value
52.
	For each entry in oACL
53.
		list = sDatei & ";" & entry.Trustee.Name & ";" & entry.Trustee.SIDString & ";" & art(entry.ACEType) & ";"
54.
		' Jetzt noch die Übersetzung der Accessmask, dabei Abfrage, falls unbekannte Zahlen auftauchen
55.
		If dict.Exists(entry.Accessmask) then
56.
			list = list & dict.item(entry.Accessmask)
57.
		Else
58.
			list = list & "Spezielle Berechtigung: " & entry.Accessmask
59.
		End If
60.
		Wscript.echo list
61.
	Next
62.
End Function
63.

64.
Sub VerzDurchgang(Verzeichnis)
65.
 ' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen
66.
 On Error Resume Next
67.
 ' Da wir keine Einzeldateien wollen, den Datei-Durchgang auskommentiert, daher werden nur Ordner gemacht	
68.
 ' FilesDurchgang Verzeichnis
69.
 For each folder in Verzeichnis.Subfolders
70.
  '***** Was jetzt tun?
71.
  call Rechte(folder.Path)
72.
  VerzDurchgang folder
73.
 Next
74.
End Sub
75.

76.
Sub FilesDurchgang(Verzeichnis)
77.
' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen
78.
On Error Resume Next
79.
 For each file in Verzeichnis.files
80.
 	' ***** Was jetzt tun?
81.
	call Rechte(file.Path)
82.
 Next
83.
End Sub
Bitte warten ..
Mitglied: Praktikantin
20.02.2007 um 14:31 Uhr
Wow! Das ist ja großartig! Genau das wollte ich. Jeder User soll eine Zeile bekommen! Ich probiere es sofort. Heute hatten wir ein Problem mit Arcor und wir konnten ein paar Seiten nicht öffnen! Das ist wirklich super! Vielen Dank! Sie haben mich wirklich gerettet! Danke!!!!!
Bitte warten ..
Mitglied: Praktikantin
20.02.2007 um 14:54 Uhr
Vielen Dank! Ich habe es jetzt laufen lassen und es funktioniert enwandfrei! Ich kann die Daten in dieser Form ganz leicht in eine Datenbank einfügen!!! Danke nochmals sie haben mich gerettet. Es ist eine Schande dass ich VB nicht kann... Schande über mich! Nochmal vielen dank!!!
Bitte warten ..
Ähnliche Inhalte
Windows Userverwaltung
ACL - Vererbung
gelöst Frage von TlBERlUSWindows Userverwaltung8 Kommentare

Guten Morgen, ich schreibe zur Zeit ein Powershell-Skript, um Berechtigungen zu vergeben. Dabei bin ich entsprechend auf Inheritance-Flags gestoßen. ...

Ubuntu
Squid3 ACL httpaccess
gelöst Frage von Florian86Ubuntu1 Kommentar

Hallo, ich habe auf einem Rechner einen Webserver aufgesetzt. Gebe ich keinen Proxy im IE ein komme ich auf ...

Router & Routing
Probleme mit ACL
gelöst Frage von niLuxxRouter & Routing14 Kommentare

Liebe Community, ich konfiguriere derzeit die ACL und ACE auf unserem Cisco Layer-3-Switch Router und ich habe ein Verständnissproblem. ...

Netzwerkmanagement
Switch ACL-Konfiguration
gelöst Frage von Philipp711Netzwerkmanagement9 Kommentare

Hallo Leute, ich habe eine kleine Frage zur Konfiguration von ACL's auf unserem Switch. Unsere Infrastruktur ist in verschiedene ...

Neue Wissensbeiträge
Internet

Kommentar: Bundesregierung erwägt Ausschluss von Huawei im 5G-Netz - Unsere Presse wird immer sensationsgieriger

Information von Frank vor 17 StundenInternet2 Kommentare

Hier mal wieder ein schönes Beispiel für fehlgeleiteten Journalismus und Politik zugleich. Da werden aus Gerüchten plötzlich Fakten, da ...

Windows 10

Netzwerk-Bug in allen Windows 10-Versionen durch Januar 2019-Updates

Information von kgborn vor 21 StundenWindows 101 Kommentar

Nur ein kurzer Hinweis für Admins, die Windows 10-Clients im Portfolio haben. Mit den Updates vom 8. Januar 2019 ...

Windows 10

Windows 10 V1809: Rollout ist gestartet - kommt per Windows Update

Information von kgborn vor 1 TagWindows 102 Kommentare

Eine kurze Information für die Admins, die Windows 10 im Programm haben. Microsoft hat die letzte Baustelle (die Inkompatibilität ...

Sicherheit

Heise Beitrag Passwort-Sammlung mit 773 Millionen Online-Konten im Netz aufgetaucht

Information von Penny.Cilin vor 1 TagSicherheit6 Kommentare

Auf Heise Online ist folgender Beitrag veröffentlicht worden: Heise Beitrag passwörter geleakt Ich bin mir jetzt nicht ganz sicher, ...

Heiß diskutierte Inhalte
Windows Server
Uhren gehen immer wieder falsch
Frage von killtecWindows Server23 Kommentare

Hallo, ich habe folgende Konstellation: 1. Physischer DC Div. Virtuelle DC's auf Hyper-V Servern Die Hyper-V-Server, der Physische DC ...

Batch & Shell
Mit findstr batch doppelte zeilen einer txt löschen
Frage von Burningx2Batch & Shell21 Kommentare

Hi Vor einer weile habe ich im netzt einen windows shell befehl gefunden mit welchem man über die konsole ...

Verschlüsselung & Zertifikate
Netzwerkfreigabe Verschlüsselung
Frage von grill-itVerschlüsselung & Zertifikate20 Kommentare

Moin zusammen, sicher nutzen hier die ein oder anderen ein Produkt zur Verschlüsselung von Netzwerkfreigaben/-laufwerken auf denen hochsensible Daten ...

Debian
OpenSSH Login mit Public Key schlägt fehl, mit Passwort funktioniert
gelöst Frage von DKowalkeDebian19 Kommentare

Hallo zusammen, ich hatte hier schon nach einer Anleitung für einen SFTP Server mit Linux gefragt, habe dort auch ...