Anmeldeskript mit Darstellung im Anmeldedialog "Kurztext"

Also genau das was du willst ist es nicht, aber es soll ja auch eigenes Denken gefördert werden

Ich habe das mal gebaut weil ich glaubte meine User umfassend informieren zu müssen.
Ist aber leider gar nicht so gut angekommen
Es macht nichts anderes als Netzlaufwerke und -drucker zu trennen und wieder zu verbinden.
Zum Schluß gibt es eine formtierte Auflistung der Ergebnisse als selbstschließendes Popup (10 s) aus.

Die Zeitsynchronisation ist eigentlich nicht erforderlich; die Clients synchronisieren automatisch die Zeit mit dem DC.

' #####BOF#####
' logon.vbs
' #############
Option Explicit
On Error Resume Next

Dim WSHNetwork, WSHShell, CRLF, objArgs, strMsg, Company, i, colDrives
Dim colPrinters, UserName, LogonSRV, Domain, nReturnCode, nSecondsToWait

CRLF = Chr(13) & Chr(10)
LogonSRV = "DerDomänencontroller"

Set WSHNetwork = Wscript.CreateObject("WScript.Network")
Set WSHShell = WScript.CreateObject("WScript.Shell")
Set objArgs = Wscript.Arguments

' ----------------------------------------------------------
' Synchronisieren der Zeit mit dem Domänenkontoller
nReturnCode = wshShell.Run("net time \\" & LogonSRV & " /set /yes", 0, TRUE)
If (nReturnCode <> 0) Then
  MsgBox "Es war nicht möglich die lokale Uhrzeit zu synchronisieren." & vbNewLine &_
      "Bitte melden Sie sich beim System-Administrator.",48,"Logon Script Fehler"
Else
  strMsg = "Zeitsynchronisation mit """ & LogonSRV & """ erfolgreich" & CRLF & CRLF
End If

' ----------------------------------------------------------
' Einrichten der Netzlaufwerke

Company = "Firmenname"
Domain = WSHNetwork.Userdomain
UserName = ""
Do While UserName = ""
  UserName = WSHNetwork.UserName
Loop

WSHNetwork.RemoveNetworkDrive "P:"
WSHNetwork.RemoveNetworkDrive "U:"

WSHNetwork.MapNetworkDrive "P:", "\\" & LogonSRV & "\share"
WSHNetwork.MapNetworkDrive "U:", "\\" & LogonSRV & "\home\" & Username

WSHNetwork.RemovePrinterConnection "Drucker1"

WSHNetwork.AddWindowsPrinterConnection "\\" & LogonSRV & "\Drucker1"
Set colDrives = WSHNetwork.EnumNetworkDrives
Set colPrinters = WSHNetwork.EnumPrinterConnections

' ----------------------------------------------------------
' Überschrift
' "UserDomain" & Chr(9) & "= " & Domain & _
strMsg = strMsg & CRLF & "Anmelde Ergebnisse" & CRLF & CRLF & _
  "Benutzername" & Chr(9) & "= " & UserName & CRLF & "Computername" & Chr(9) & "= " & _
  WSHNetwork.ComputerName & CRLF & "Domäne" & Chr(9) & Chr (9) & "= " & Domain & CRLF

' ----------------------------------------------------------
' Anzeigen der erfolgreich verbunden Laufwerke
If colDrives.Count = 0 Then
  strMsg = strMsg & CRLF & "Kein Netzlaufwerk ist verbunden." & CRLF
Else
  strMsg = strMsg & CRLF & "Verbundene Netzlaufwerk(e):" & CRLF
  For i = 0 To colDrives.Count - 1 Step 2
    strMsg = strMsg & CRLF & colDrives(i) & Chr(9) & colDrives(i + 1)
  Next
End If

' ----------------------------------------------------------
' Anzeigen der erfolgreich verbunden Drucker
If colPrinters.Count = 0 Then
  strMsg = strMsg & CRLF & CRLF & "Kein Netzwerk-Drucker ist verbunden." & CRLF
Else
  strMsg = strMsg & CRLF & CRLF & "Verbundene Netzwerk-Drucker:" & CRLF
  For i = 0 To colPrinters.Count - 1 Step 2
    strMsg = strMsg & CRLF & colPrinters(i) & Chr(9) & colPrinters(i + 1)
  Next
End If

Function zeit
' FormatDateTime formatiert das Datum als langes Datumsformat.
zeit = "Systemzeit: " & Chr(9) & FormatDateTime(Date, 1) & " - " & FormatDateTime(Time, 4)
End Function

WshShell.PopUp zeit & CRLF & CRLF & strMsg,10, " " & Username &"@" & Company, 64

Set WSHNetwork = Nothing
Set WSHShell = Nothing
Set objArgs = Nothing
Set colDrives = Nothing
Set colPrinters = Nothing
' #####EOF#####

Wo hakts denn? Zeile? Zeichen?
Ist natürlich etwas aus dem Zusammenhang gerissen

Wenn du die Zeile 'On Error Resume Next' auskommentierst siehst du wo es kracht.
D.h. es kommt eine MessageBox die sagt, in welcher Zeile bei welchem Zeichen welcher Fehler aufgetreten ist.

Die Zeitsynchronisation würde ich auskommentieren (jeder Zeile ein ' voranstellen), da sie nicht benötigt wird und außerdem der User das Recht dazu braucht.

Manöverkritik:
- Heißt dein DC 'DerDomänencontroller'?
- Wo hast du das Objekt 'Home' generiert? Es existiert nicht, was nicht existiert kann man nicht verwenden.
- Die Variable 'Tester' ist nicht deklariert.

~~~~~~~~~~~~~~~~~~~~~~~~
Die einzigen Angaben, die du an dem Script hättest verändern müssen, wären
a) die Belegung der Variablen LogonSRV sofern dein DC nicht DerDomänencontroller heißt
b) die Bezeichnungen von 'share', 'home' und 'Drucker1' sowie der gemappten Laufwerksbuchstaben 'P:' und 'U:'sofern diese bei dir anders lauten
c) die Auskommentierung der 7 Zeilen zwischen nReturnCode und End If falls der User nicht das Recht zum Ändern der Systemzeit hat.
d) die Belegung der Variablen Company mit deinem Firmennamen. Das passt
~~~~~~~~~~~~~~~~~~~~~~~~

Ich habe es eben in einer Domäne nochmal ausprobiert, bei mir funktioniert es.

Klingt mir eher nach einem Domänennamen.
Wenn der DC z.B. SRV01 heißt, wäre der FQDN (Fully aqualified domain name) SRV01.home.local
Die Angabe der Domain ist nicht nötig, da diese mit 'WSHNetwork.Userdomain' abgefragt wird.