Batch als Generationenbackup mit Robocopy

' Backup folder using 7-Zip  
' Written by Steve Allison 2014 - steve@allison.im  

Dim fso, rs, shell

' File System Object  
Set fso = CreateObject("Scripting.FileSystemObject")  
' RecordSet  
Set rs = CreateObject("Ador.Recordset")  
' Shell  
Set shell = CreateObject("WScript.Shell")  

Const adVarChar = 200
Const adDate = 7

srcFolder="E:\RA\ZEIT"  
dstFolder="E:\RAMDASIZEIT"  
backupName="backup"  
zipEXE="E:\DASI-Zeit\7za.exe"  

' Number of files to keep  
iNum = 15000

' Get the date in the correct order. Why does vbscript suck so hard at date formatting?  
Function getDateString()
    d = ZeroPad(Day(Now()), 2)
    m = ZeroPad(Month(Now()), 2)    
    y = Year(Now())
    getDateString = y & m & d
End Function

' No printf() in VBScript it seems  
Function ZeroPad(int, length)
	If Len(int) < length Then
		ZeroPad = Right(String(length, "0") & int, length)  
		Else
			ZeroPad = int
	End If
End Function

' Sanity checking  
If Not fso.FolderExists(srcFolder) Then
	Wscript.Echo "Aborted. Source folder does not exist: " & srcFolder  
	Wscript.Quit
End If
If Not fso.FolderExists(dstFolder) Then
	Wscript.Echo "Aborted. Destination folder does not exist: " & dstFolder  
	Wscript.Quit
End If
If Not fso.FileExists(zipEXE) Then
	Wscript.Echo "Aborted. 7-Zip program does not exist: " & zipEXE  
	Wscript.Quit
End If

' Create suffix of date-time  
backupFileDate = getDateString() & "-" & replace(FormatDateTime(now,4),":","")  

' File extension  
backupFileExt = ".7z"  

' Backup path without extension  
backupFilePre = dstFolder & "\" & backupName & "_" & backupFileDate  

' Full backup path  
backupFile = backupFilePre & backupFileExt

' More sanity checking  
n = 1
Do While fso.FileExists(backupFile)
	' Add integeer to file, loop until it doesn't already exist  
	backupFile = backupFilePre & "_" & ZeroPad(n, 2) & backupFileExt  
	n = n + 1
Loop

'''' Zip Source Folder  
' Create shell command  
shCommand = """" & zipEXE & """ a -r """ & backupFile & """"  
' Change to source directory  
shell.CurrentDirectory = srcFolder & "/"  
' Run 7-Zip in shell  
shVal = shell.Run(shCommand,4,true)
'WScript.Echo shCommand  
' Check 7-Zip exit code  
If shVal > 1 Then
	Wscript.Echo "7-Zip failed with error code: " & shVal  
	Wscript.Quit
End If

' Wscript.Echo "Backup complete at " & backupFile