20.06.2017, aktualisiert am 23.06.2017

4531

Batch starten unter berücksichtigung von Wochenenden, Feiertagen etc

Hallöchen liebe Leute,

ich suche eine Möglichkeit eine Batch-Datei automatisch unter Berücksichtigung von Feiertagen, Monatsmitte, Monatsende sowie Wochenenden auszuführen.

Im Konkreten geht es darum diese Datei nicht auszuführen wenn:

Wochenende
der 15 eines Monats
der 30/31 eines Monats
der letzte Werktag vor dem 15.
der letzte Werktag vor dem 30/31

ist.

Habt ihr eine Lösung wie ich dies automatisieren kann ?

Dankeschön und schöne Grüße

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 341087

Url: https://administrator.de/contentid/341087

Ausgedruckt am: 26.11.2024 um 04:11 Uhr

11 Kommentare

Neuester Kommentar

Taskplaner mit Kalenderfunktion (Feiertage)

WOL an Werktagen ohne Wochenende und Feiertage einrichten

www.tecchannel.de/a/feiertage-berechnen-und-beruecksichtigen-teil-1,465188

Als Beispiel.

Mann könnte auch 1x Jahr die Daten im Voraus eintragen oder Monatlich....

Habe auch etwas in der Richtung gesucht und folgendes gefunden: http://www.supportnet.de/stat/2004/7/id184096.asp

Im letzten Post wird auf eine Seite verwiesen, wo man sich ein selbstgebautes DOS-Util "IFWEKDAY" runterladen kann. Mit dem, bzw. mit den Errorlevel der Ausgabe kannst du zumindest Montag bis Freitag einfangen.

Hallo Kyrinja,

das Forenmitglied @Pedant stellt auf seiner Seite ein Tool zum Rechnen mit Datumswerten zum Download zur Verfügung (der Link ist am Ende der Seite). Dieses Tool wird im beiliegenden Script verwendet. Ich bin allerdings von folgender Anforderungsliste ausgegangen:

Batchfile nicht ausführen

am Wochenende
am 15. eines Monats wenn der 15. nicht auf ein Wochenende fällt, ansonsten am letzten Werktag vor dem 15.
am Monatsletzten wenn der Monatsletzte nicht auf ein Wochenende fällt, ansonsten am letzten Werktag vor dem Monatsletzten
an einem in der Feiertagsdatei enthalten Datum (keine Berücksichtigung des letzten Werktags davor)

In den Zeilen 27 und 28 können die Wochentage eingestellt werden, die als Arbeits- bzw. als Wochenendtage zählen, die Länge der Arbeitswoche ist also flexibel.

Die (optionale) Feiertagsdatei muss für jeden Feiertag einen Eintrag im Format dd.MM.yyyy (z.B. 25.12.2017) enthalten, pro Dateizeile ein Eintrag. Der Pfad zu dieser Datei muss in Zeile 31 eingestellt werden.

Die Codezeilen im Abschnitt "Testdaten" (Zeilen 8 bis 19) habe ich für Test- und Demonstrationszwecke drin gelassen. Sie können einfach entfernt werden, der Rest des Codes muss nicht geändert werden. Kopiere den Eintrag, den Du testen möchtest, ans Ende der Liste.

Hier jetzt der Code:

@echo off & setlocal

::==============================================================================
:: Testdaten, verwendet wird immer der letzte Eintrag in der Liste
:: Für den Produktiveinsatz entfernen oder auskommentieren
::==============================================================================

set "TestDate=/d 24.06.2017" & rem Sa                          -> nicht ausf.  
set "TestDate=/d 25.06.2017" & rem So                          -> nicht ausf.  
set "TestDate=/d 15.06.2017" & rem Do + 15.                    -> nicht ausf.  
set "TestDate=/d 30.06.2017" & rem Fr + Monatsende             -> nicht ausf.  
set "TestDate=/d 31.05.2017" & rem Mi + Monatsende             -> nicht ausf.  
set "TestDate=/d 28.02.2017" & rem Di + Monatsende             -> nicht ausf.  
set "TestDate=/d 29.02.2016" & rem Mo + Monatsende             -> nicht ausf.  
set "TestDate=/d 14.07.2017" & rem Letzter Werktag vor Sa 15.  -> nicht ausf.  
set "TestDate=/d 13.01.2017" & rem Letzter Werktag vor So 15.  -> nicht ausf.  
set "TestDate=/d 30.05.2017" & rem Di + kein Monatsende        -> ausf.  
set "TestDate=/d 14.06.2017" & rem Mi + 15. nicht am WE        -> ausf.  
set "TestDate=/d 28.07.2017" & rem Fr + Monatsende nicht am WE -> ausf.  


::==============================================================================
:: Konfiguration
::==============================================================================

::Arbeitstage und Wochenendtage einstellen
set "WorkDays=Mo Di Mi Do Fr"  
set "WeekendDays=Sa So"  

::Datei mit Feiertagsdaten festlegen
set "HolidaysFile=.\Holidays.txt"  


::==============================================================================
:: Vorbereitungen
::==============================================================================

::Letzten Tag des Monats ermitteln
call :GetLastDayOfCurrentMonth
set /a LastDayOfMonth=%ERRORLEVEL%


::==============================================================================
:: Hauptprogramm
::==============================================================================

::Filter anwenden
call :IsTodayWeekEnd && goto :DoNotRun

call :IsDayOfMonthAtWeekend 15 && (
  call :IsTodayLastWorkDayBeforeDayOfMonth 15 && goto :DoNotRun
) || (
  call :IsTodayDayOfMonth 15 && goto :DoNotRun
)

call :IsDayOfMonthAtWeekend %LastDayOfMonth% && (
  call :IsTodayLastWorkDayBeforeDayOfMonth %LastDayOfMonth% && goto :DoNotRun
) || (
  call :IsTodayDayOfMonth %LastDayOfMonth% && goto :DoNotRun
)

if not exist "%HolidaysFile%" goto :Run  

for /f "usebackq tokens=1-3 delims=." %%a in ("%HolidaysFile%") do (  
  call :IsToday %%a %%b %%c && goto :DoNotRun
)


::Sprungziel für "Batchfile ausführen" 
:Run
echo Batchfile ausführen
echo(

goto :Quit


::Sprungziel für "Batchfile nicht ausführen" 
:DoNotRun
echo Batchfile nicht ausführen
echo(


:Quit
exit /b 0



::==============================================================================
:: Unterprogramme
::==============================================================================

:GetLastDayOfCurrentMonth
  for /f "delims=" %%A in ('pedate %TestDate% ~M.yyyy') do (  
    for /f "delims=" %%B in ('pedate /d 1.%%A /ds 0^,1^,0 ~date') do (  
      for /f "delims=" %%C in ('pedate /d %%B /ds -1 ~d') do (  
        exit /b %%C
      )
    )
  )
exit /b 0


:IsTodayWeekEnd
  for /f "delims=" %%A in ('pedate %TestDate% ~d') do (  
    call :IsDayOfMonthAtWeekend %%A && exit /b 0
  )
exit /b 1


:IsTodayDayOfMonth
  for /f "delims=" %%A in ('pedate %TestDate% ~d') do (  
    if "%%A" equ "%~1" exit /b 0  
  )
exit /b 1


:IsToday
  for /f "delims=" %%A in ('pedate %TestDate% ~date') do set "Date1=%%A"  
  for /f "delims=" %%A in ('pedate /d %~1.%~2.%~3 ~date') do set "Date2=%%A"  
  if "%Date1%" equ "%Date2%" exit /b 0  
exit /b 1


:IsDayOfMonthAtWeekend
  for /f "delims=" %%A in ('pedate %TestDate% ~M.yyyy') do (  
    for /f "delims=" %%B in ('pedate /d %~1.%%A ~ddd') do (  
      for %%C in (%WeekendDays%) do if /i "%%B" equ "%%C" exit /b 0  
    )
  )
exit /b 1


::ACHTUNG!! Dieser Filter funktioniert nur, wenn er für einen Datumswert aufgerufen
::wird, der NICHT auf ein Wochenende fällt
:IsTodayLastWorkDayBeforeDayOfMonth
  setlocal enabledelayedexpansion

  set /a DayShift=1
  set /a CheckPeriod=1
  set /a WeekendLength=0

  for %%A in (%WeekendDays%) do set /a WeekendLength+=1

  for /f "delims=" %%A in ('pedate %TestDate% /ds 1 ~ddd') do set "Result=%%A"  
  for %%A in (%WeekendDays%) do if /i "%Result%" equ "%%A" set /a CheckPeriod=WeekendLength  

  for /l %%I in (1, 1, %CheckPeriod%) do (
    for /f "delims=" %%A in ('pedate %TestDate% /ds !DayShift! ~d') do set "Result=%%A"  
    if "!Result!" equ "%~1" (endlocal & exit /b 0)  
    set /a DayShift+=1
  )

  endlocal
exit /b 1

Die Feiertagsdatei könnte man auch automatisch erzeugen. Die meisten Feiertage in der ersten Jahreshälfte haben feste Offsets zu Ostersonntag und für das Osterdatum und auch für die Berücksichtigung von Schaltjahren gibt es Formeln. Das überlasse ich allerdings genauso wie die evtl. Berücksichtigung des letzten Werktags vor Feiertagen gerne Dir.

Grüße
Friemler

Hallo Kyrinja,

Zitat von @Kyrinja:
...Monatsmitte, Monatsende sowie Wochenenden...
...nicht auszuführen wenn:
Wochenende
der 15 eines Monats
der 30/31 eines Monats
der letzte Werktag vor dem 15.
der letzte Werktag vor dem 30/31

Zu Deinen Bedingungen habe ich ein paar Nachfragen:

Wochenende

Wochentag = Sa oder So
Das ist eindeutig.

der 15 eines Monats

Damit meinst Du die erwähnte Monatsmitte.
Ist die für Dich immer der 15.?
Rechnerisch können diese Werte vorkommen: 14,0 14,5 15,0 15,5
Das Komma-5 kann man generell weglassen, da es am Datum (Tag) nichts ändert, aber die 14 könnte relevant sein.
Sollte das berücksichtigt werden oder bleibt es fest bei 15?
Tag = 15
oder
(Tag = 15 und Monat <> 2) oder (Tag = 14 und Monat = 2)

der 30/31 eines Monats

Damit meinst Du den letzten des Monats, was aber auch der 28 oder 29 sein könnte.
Friemler hat es so gelöst, dass er den Tag vor dem ersten Tag des Folgemontags ermittelt, was der letzte Tag des aktuellen Monats ist.
Das sollte so in Deinem Sinne sein, oder?

der letzte Werktag vor dem 15.
der letzte Werktag vor dem 30/31

Ich bin mir nicht ganz sicher was Du mit "der letzte Werktag vor" meinst.
Der Werktag und damit auch der letzte Werktag vor dem Do., den 15.06.2017 ist Mi., der 14.06.2017.
Ich vermute aber, dass das nicht so allgemein gemeint war, sondern nur für den Fall, dass die Monatsmitte bzw. das Monatgsende auf ein Wochenende fällt.
Dann wäre der Freitag gemeint und falls der ein Feiertag wäre, dann halt der Do. und zu Weihnachten eventuell auch der Mi.
War das so gemeint?

@Friemler,
da hast Du ja wieder ein schönes Batch-Monster geschrieben.
Durch Deine Bedingungen und Fallunterscheidungen bin ich noch nicht ganz durchgestiegen, aber vorab eine Anmerkung:
In den Zeilen: 93, 104, 111, 118, 125, 144, 148
hast Du wahrscheinlich das /d vor %TestDate% vergessen.
Sicher hattest Du pedate /d %TestDate% statt pedate %TestDate% gemeint.

Gruß Frank

Hallo Frank,

Zitat von @Pedant:
In den Zeilen: 93, 104, 111, 118, 125, 144, 148
hast Du wahrscheinlich das /d vor %TestDate% vergessen.

nein, nix vergessen

, das /d ist bereits in der Variablen %TestDate% enthalten, sonst würde nach dem Löschen der Testdaten aus dem Script überall ein Fehler entstehen, wo %TestDate% benutzt wird.

Grüße
Friemler

Hallo Friemler,

ja, jetzt sehe ich es auch: Zeile 8 bis 19.
Wie konnte ich an Dir zweifeln.

Gruß Frank

Zitat von @Pedant:

Hallo Kyrinja,

Zu Deinen Bedingungen habe ich ein paar Nachfragen:

Wochenende

Wochentag = Sa oder So
Das ist eindeutig.

Genau Wochenende = Samstag & Sonntag

der 15 eines Monats

Der 15. ist immer Monatsmitte (auch im Februar ;) ) außer es ist ein Feiertag / Wochenende

der 30/31 eines Monats

genau so! der letzte Wochenentag des Monats ist für mich Monatsende

der letzte Werktag vor dem 15.
der letzte Werktag vor dem 30/31

ja genau so war das gemeint :D das war etwas blöd beschrieben von mir....!

@Friemler,
da hast Du ja wieder ein schönes Batch-Monster geschrieben.
Durch Deine Bedingungen und Fallunterscheidungen bin ich noch nicht ganz durchgestiegen, aber vorab eine Anmerkung:
In den Zeilen: 93, 104, 111, 118, 125, 144, 148
hast Du wahrscheinlich das /d vor %TestDate% vergessen.
Sicher hattest Du pedate /d %TestDate% statt pedate %TestDate% gemeint.

Gruß Frank

Vielen Dank und Gruß

Vielen Vielen Vielen ..... Vielen Dank Friemler!

das hätte ich so nicht hinbekommen. Leider steige ich nicht ganz durch das script und Pedate durch um mir das mit den Feiertagen selbst zu basteln aber ich danke dir trotzdem für das Script! das erleichtert schon mal einiges.

Gruß
Kyrinja

Hallo Kyrinja,

das Problem mit den Feiertagen ist Deine Anforderung:

Das Batchscript soll nicht laufen,

wenn der aktuelle Tag der 15. oder der Monatsletzte oder ein Feiertag ist (kein Problem, geht schon).
wenn der 15./Monatsletzte auf ein Wochenende (geht schon) oder einen Feiertag (geht noch nicht) fällt und der aktuelle Tag der letzte Werktag davor ist.

Wochenenden und Feiertage können auch als Block vorkommen. Die Prüfung auf "letzter Werktag vor" ist bei solchen Blöcken recht aufwendig. Ich habe gerade keine Zeit für diese Aufgabe, sorry.

Grüße
Friemler

Hallo Kyrinja,

Zitat von @Kyrinja:
Leider steige ich nicht ganz durch das script und Pedate durch um mir das mit den Feiertagen selbst zu basteln aber ich danke dir trotzdem für das Script! das erleichtert schon mal einiges.

Wie Friemler schon schrieb machen es diese beiden Bedingungen recht kompliziert:

Nicht ausführen am letzten Werktag vor dem 15., falls der 15. seinerseits kein Werktag ist.
Nicht ausführen am letzten Werktag vor dem Monatsletzten, falls der Monatsletzten seinerseits kein Werktag ist.

Ist das wirklich nötig?

Zitat von @Kyrinja:
ich suche eine Möglichkeit eine Batch-Datei automatisch unter Berücksichtigung von Feiertagen, Monatsmitte, Monatsende sowie Wochenenden auszuführen.

Okay, Du wirst schon Deine Gründe haben, also anders überlegt:

Diese beiden Sonderregeln treffen doch meistens einen Freitag und nur an wenigen Tagen einen Nichtfreitag.
Ganz konkret betrifft das in Hessen in 2017 diese Tage:

13.01.2017 Freitag28.04.2017 Freitag14.07.2017 Freitag29.09.2017 Freitag13.10.2017 Freitag29.12.2017 Freitag13.04.2017 Donnertag14.06.2017 Mittwoch

Die beiden Sonderregeln treffen in Hessen in 2017 also nur auf acht Tage überhaupt zu und nur zwei davon sind ein Freitag.

Feiertage die auf ein Wochenende fallen sind irrelevant, also verbleiben für Hessen für 2017 diese Feiertage:

Fr. 14.04.17Mo. 17.04.17Mo. 01.05.17Do. 25.05.17Mo. 05.06.17Do. 15.06.17Di. 03.10.17Mo. 25.12.17Di. 26.12.17

Wenn Du ohnehin eine Feiertagsliste als Datei anlegen musst, dann deklariere den einen Mittwoch und den einen Donnerstag einfach auch als Feiertag und wenn Du schon dabei bist, dann auch noch die sechs Freitag und schon sind Deine Fallunterscheidungen recht simpel:

Nein wenn Samstag
Nein wenn Sonntag
Nein wenn 15.
Nein wenn Monatsletzer
Nein wenn Feiertag / Pseudofeiertag

Mit der erweiterten Feiertagsdatei und Ausschnitten aus Friemlers Skript, ist die Aufgabe erledigt.

Wenn Du die Monatsletzten (12 Tage) auch als Feiertage einträgst, fällt die letzte aufwändigere Fallunterscheidung auch noch weg.
Dann sieht es so aus:

Nein wenn Samstag
Nein wenn Sonntag
Nein wenn 15.
Nein wenn Feiertag / Pseudofeiertag

Noch primitiver wird es , wenn Du die Logik und ein wenig Handarbeit komplett ins Excel verlegst und Dir eine komplette Blacklist als Textdatei erzeugst, also die wenigen Sonderfälle, alle Feiertage, alle Monatsmitten und -enden und alle Wochenendtage als Feiertage deklarierst. Das ist einmal im Jahr ein Stündchen Arbeit und fertig ist Deine Automatik, denn dann musst Du nur noch automatisiert prüfen, ob das Datum von heute in der Blacklist steht und wenn es das nicht tut, das Batch starten.

Nein wenn Blacklist-Tag

Blacklistcheck.cmd

@echo off

REM heutiges Datum in Liste suchen lassen
find C:\Blacklist.txt "%date%"> nul  

REM Wenn nicht gefunden (errorlevel 1) dann ausführen
if errorlevel 1 goto ausfuehren

REM Nicht ausführen, wenn gefunden (errorlevel 0)
exit /b

:ausfuehren
meineBatchdatei.cmd

Gruß Frank

Hallo Kyrinja,

ich hab mir die Bedingungen nochmal genauer angeschaut.

Es handelt sich letzendlich nicht um Bedingungen, die sich ausschließen, sondern um welche, die sich eventuelle überschneiden.
Damit will ich sagen, wenn ein Tag wegen einer Bedingung tabu ist, dann gibt es keine, die das revidiert, sondern höchsten in Abhängigkeit einen zusäztlichen Tag als tabu erklärt.

a) Sa => neinb) So => neinc) Feitertag => neind) 15. => neine) Monatsletzter => nein
Das ist alles simpel.

f)Wenn der 15. oder der Monatsletzte kein Werktag ist, dann soll auch der letzte Werktag davor tabu sein.
(Den Monatsletzten nenne ich im Folgenden ldM und Sa/So nenne ich WE.)

Hauptsächlich ist ein Freitag betroffen und zwar wenn am anschließenden WE, der 15. oder ldM sein wird.
f1) (WE und 15.) oder (WE und ldM) > nein

Dann bleiben nur noch die Feiertage in Bezug auf 15. und ldM zu berücksichtigen.

Die datumsgebundenen (feste) Feiertage:
- 01.01. Neujahrstag
- 01.05. Tag der Arbeit
- 03.10. Tag der deutschen Einheit
- 25.12. 1. Weihnachtstag
- 26.12. 2. Weihnachtstag
Keiner davon fällt jemals auf Monatsmitte oder Monatsletzen, insofern sind sie für die Sonderregeln (f) nicht relevant.

Feiertage, die auf ein Wochenende fallen
- Ostersonntag
- Pfingstsonntag
sind auch nicht relevant, da sie durch a) und b) schon abgedeckt sind.

Es bleiben dann nur Wenige übrig:
- Karfreitag (immer Freitags)
- Ostermontag (immer Montags)
- Pfingstmontag (immer Montags)
- Christi Himmelfahrt (immer Donnerstags)
- Fronleichnam (immer Donnerstags)

Der Karfreitag als Feiertag kann den Gründonnerstag beeinflussen.
f2)Sollte am Karfreitag oder an den 3 Tagen darauf, der 15. oder ldM sein dann ist Gründonnerstag tabu.
Ostermontag ist damit auch erledigt.

Freitag vor Pfingsten kann ergänzend zu f1) in Abhängigkeit vom Pfingstmontag tabu sein.
f3) Wenn Pfingstmontag der 15. oder ldM, dann Freitag davor tabu

Es bleiben dann nur noch Christi Himmelfahrt und Fronleichnam
Beide fallen immer auf einen Donnerstag, können daher den Mittwoch davor beeinflussen.
f4) Christi Himmelfahrt oder Fronleichnam der 15. oder ldM, dann der Mittwoch davor tabu.

Falls die Aufgabe für Hessen erledigt werden sollte, dann sind die Feiertags-Bedingungen f1-4 ausreichend.

Ich habe mal den Zeitraum 01.01.2017 - 31.12.2037 betrachtet.
f2) kommt dabei nur 5-mal zu tragen,
f4) nur 4-mal und
f3) nicht einmal

In diesen 21 Jahren gibt es also nur 9 Tage insgesamt, die nicht durch die Regeln a) - f1) schon abgedeckt wären.

Unter Berücksichtigung aller Regeln a) - f4) habe ich eine komplette Blacklist für Hessen 2017-2037 geexcelt.

Irrtumer vorbehalten anbei die Liste Blacklist_Hessen_2017-2037.txt

Gruß Frank

Frage Entwicklung Batch, Shell

Mehr von Kyrinja

Windows 10 LTSC Inplace Upgrade auf Windows 11Kyrinja - 3 Kommentare

Zentrale Kontaktverwaltung mit ACL und Abruf auf SmartphoneKyrinja - 7 Kommentare

Zellinhalt in Excel-Kopfzeile übernehmenKyrinja - 2 Kommentare

PHP Tabellen automatisch nach Gruppen ID aus MYSQL erstellenKyrinja - 8 Kommentare

Heiß diskutiert