BATCH, VB, C++ or what else - Daten von txt in xls per Suchfunktion

Dim fso,objExcel,xmldoc,wb,ws,rngOut,file,node,XMLPATH

'Objekte erstellen  
Set fso = CreateObject("Scripting.Filesystemobject")  
Set xmldoc = CreateObject("msxml2.domdocument.6.0")  
Set objExcel = CreateObject("Excel.Application")  

'Pfad zu den XML-Dateien setzen (im Moment im gleichen Ordner wie das Script)  
XMLPATH = fso.GetParentFolderName(WScript.ScriptFullName)

'Neues Excel Workbook erstellen  
Set wb = objExcel.Workbooks.Add
Set ws = wb.Worksheets(1)
objExcel.DisplayAlerts = False
objExcel.ScreenUpdating = False
objExcel.Visible = True

'Überschriften setzen  
With ws.Range("A1:K1")  
	.Value = Array("Straße","Ort","PLZ","Geburtsdatum","Nachname","Vorname","Anrede","Geschlecht","Telefon","Mobil","E-Mail")  
	.Font.Bold = True
End With

'Start der Ausgabe im WS  
Set rngOut = ws.Range("A2")  

'Formate für alle Zellen auf Text setzen  
ws.Range("A:L").NumberFormat = "@"  

For Each file In fso.GetFolder(XMLPATH).Files
	If LCase(fso.GetExtensionName(file.Name)) = "xml" Then  
		
		xmldoc.validateOnParse = False
		xmldoc.load file.Path
		
		'gewünschte Nodes mit XPATH selektieren  
		Set node = xmldoc.selectSingleNode("//entry[string='strasse']")  
		If Not node Is Nothing Then
			rngOut.Value = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='ort']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,1) = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='plz']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,2) = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='geburtsdat']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,3) = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='name1']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,4) = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='name3']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,5)= node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='anrede']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,6) = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[string='geschlecht']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,7) = node.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[kommunikationsArt='PHONE']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,8) = node.nextSibling.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[kommunikationsArt='MOBILE']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,9) = node.nextSibling.childNodes.item(1).text
			Set node = Nothing
		End If
		Set node = xmldoc.selectSingleNode("//entry[kommunikationsArt='EMAIL']")  
		If Not node Is Nothing Then
			rngOut.Offset(0,10) = node.nextSibling.childNodes.item(1).text
			Set node = Nothing
		End If
		
		'Zeile um eins nach unten verschieben  
		Set rngOut = rngOut.Offset(1, 0)
	End If
Next
'Spaltenbreiten anpassen  
ws.Range("A:K").Columns.AutoFit  

objExcel.DisplayAlerts = True
objExcel.ScreenUpdating = True

'Objekte releasen  
Set xmldoc = Nothing
Set fso = Nothing
Set objExcel = Nothing