Bedingung in Abhängigkeit vom Alter einer Datei

'----GetFileMinutes.vbs  
Set fso = CreateObject ("Scripting.FileSystemObject")   
Set f = fso.getfile(wscript.arguments(0)) 
WScript.echo DateDiff("n", f.DateLastModified, now())   
'------snapp GetFileMinutes.vbs  

for /f %%i in ('cscript //nologo GetfileMinutes.vbs DeineDatei.xyz') do if %%i GEQ 30 Goto IsOlder  
goto :NothingToDo
....
:IsOlder
....bla....
::-----Ende der Skizze

:: --snipp GetFileMinutesDemo.bat Parameter1 Filename/File-Wildcards
:: Placed in the Public Domain for Educational Purposes Biber 2006
@echo off & setlocal
call :DateToDays todayInDays %date%    && REM Heutiges Datum  als Ganzzahl
call :TimeToMins todaysMinutes %time%  && REM Minuten sei Mitternacht als Ganzzahl

For %%i in (%1) do call :CompareMinutes %%i %todayInDays% %TodaysMinutes%
goto :eof
~~~~~~~~~~ Ende des Hauptbatches... es folgen geCALLte Unterroutinen
:CompareMinutes Parameter1:Datei; Para2: Heute als Ganzzahl; Para3: Minuten heute seit Mitternacht 
For /f "tokens=1-2" %%a in ("%~t1") do (  
   call :DateToDays FileInDays %%a  && REM DateiDatum als Ganzzahl
   call :TimeToMins FileMinutes %%b && Rem Datei-Minuten seit Mitternacht
)
if %fileinDays% GEQ 25550 (echo [GTR] %~t1 %~f1 ist definitiv nicht aus diesem Jahrhundert) && goto:eof
REM wenn Jahresendzahl größergleich 70 dann annehmen 1970....1999. [70*365 = 25550]
Set /a "yesterday=%2-1"  
if %fileinDays% LSS %yesterday% (echo [GTR] %~t1 %~f1 ist definitiv älter als 30 Min) && goto:eof
if %fileinDays% LSS %2                  Set /a "TodayCompMinutes=%3+(60*24)-30"       
If %fileinDays% LSS %2 if 1%todayCompMinutes% GTR 1%fileMinutes% (
    (echo [GTR] %~t1 %~f1: von gestern; älter als 30 Minuten)  && goto :eof
) else (
    (echo [LEQ] %~t1 %~f1: von gestern; jünger als 30 Minuten) && goto :eof
)
REM verbleibender Fall: Datei ist von Heute:
Set /a "FileMinutes+=30"  
If %fileminutes% LSS %3 (
   echo [GTR] %~t1 %~f1: von heute; älter als 30 Minuten
) else (
   echo [LSS] %~t1 %~f1: von heute; jünger als 30 Minuten
)  
goto :eof
~~~~~~~~~~~
:DateToDays ; Para1=Variablenname; Para2 [,Para3] :Datum als "[ttt] TT.MM.[JJ]JJ"  
For %%i in (%2 %3) do set "now=%%i"  
for /f "tokens=1-3 delims=./" %%a in ("%now%") do (  
      Set /a "%1=((%%c%%100)*365)+((1%%b-100)*12)+(1%%a-100)" )  
goto :eof
~~~~~~~~~~
:TimeToMins Parameter1: Variablenname Parameter2:Zeit im Format hh:mm
For /f "tokens=1-2 delims=:" %%a in ("%2") do set /a "%1=(1%%a-100)*60+(1%%b-100)"  
:: ---snapp GetFileMinutesDemo.bat

$cmd$d:\temp\GetFileMinutesDemo.bat *.txt
[GTR] 04.04.00 23:19  Z:\putinenv.txt ist definitiv älter als 30 Min
[GTR] 03.09.06 11:37  Z:\vonheute.txt: von heute; älter als 30 Minuten
[GTR] 02.09.06 18:43  Z:\vongestern.txt: von gestern; älter als 30 Minuten
[GTR] 03.09.06 12:36  Z:\vonheute2.txt: von heute; älter als 30 Minuten

Z:\>
$cmd$echo xx>>vonheute2.txt

Z:\>
$cmd$d:\temp\GetFileMinutesDemo.bat *.txt
[GTR] 04.04.00 23:19  Z:\putinenv.txt ist definitiv älter als 30 Min
[GTR] 03.09.06 11:37  Z:\vonheute.txt: von heute; älter als 30 Minuten
[GTR] 02.09.06 18:43  Z:\vongestern.txt: von gestern; älter als 30 Minuten
[LSS] 03.09.06 13:07  Z:\vonheute2.txt: von heute; jünger als 30 Minuten

d:\temp\GetFileMinutesDemo.bat vonheute2.txt|find "[LSS}" >nul && echo Datei ist jünger als 30 Minuten  
-oder-
d:\temp\GetFileMinutesDemo.bat vonheute2.txt|find "[LSS}" >nul || echo Datei ist älter als 30 Minuten