Bereich eines Logfiles in ein separates File zusammenfassen inkl. Logfile Name

Hi,

hab da mal ne Frage:

Ich habe einen Ordner, in dem Logfiles im *.txt Format gespeichert werden.
Der Inhalt der txt-Files sieht in etwa so aus:
WARNING ( 145123): Sicherung nicht komplett
WARNING ( 121345): Fehler ist vernachlässigbar
ERROR ( 135214): Datei ist defekt.
INFO ( 234534): Heute ist ein schöner Tag
DEBUG ( 234230): Debugging successful

Ich möchte nun aus allen Logfiles die Werte Warning und Error
auslesen und in eine separate txt-Datei kopieren. Zusätzlich soll die
Bezeichnung des Logfiles dazugeschrieben werden, aus dem die Information
herausgezogen worden ist.

Das Endergebnis (logsummary.txt) soll ungefähr so aussehen:
Logfilename: 20071008_1647_import_log
ERROR ( 135214): Datei ist defekt.
WARNING ( 145123): Sicherung nicht komplett
WARNING ( 121345): Fehler ist vernachlässigbar

Logfilename: 20071008_1649_import_log
ERROR ( 135214): Datei ist defekt.
WARNING ( 145123): Sicherung nicht komplett

Ist das mit einem Batchfile machbar?


Würde mit folgendem Befehl z.B. find /i "ERROR ("
die Zeilen mit "Error" auslesen, aber dann verließen sie mich,
die geistigen Ergüsse der Programmierkunst.


Gruß
Tom

>for %i in (2007*.txt) do @for /f "delims=" %a in ('findstr /v "^INFO" "%i"^|findstr /v "^DEBUG"') do @echo %a  
WARNING ( 145123): Sicherung nicht komplett
WARNING ( 121345): Fehler ist vernachlässigbar
ERROR ( 135214): Datei ist defekt.

@for %%i in (2007*.txt) do @(
echo Logfilename %%i >>logfile_summary.txt
for /f "delims=" %%a in ('findstr /v "^INFO" "%%i"^|findstr /v "^DEBUG"') do @echo %%a >>logfile_summary.txt  
)

@echo off & setlocal
set "Summary=D:\logfile_summary.txt"  
set "Filter=WARNING ERROR"  

if exist "%Summary%" del "%Summary%"  
for %%i in (D:\2007*.txt) do (
	findstr /b "%Filter%" "%%i">nul && (  
		echo Logfilename: %%i
		for /f "delims=" %%a in ('findstr /b "%Filter%" "%%i"') do echo %%a  
		echo.
	)>>"%Summary%"  
)

@echo off & setlocal
set "Summary=D:\logfile_summary.txt"  
set "PosFilter=WARNING ERROR"  
set "NegFilter=vernachlässigbar"  

if exist "%Summary%" del "%Summary%"  
for %%i in (D:\2007*.txt) do call :ProcessFile "%%i"  
goto :eof

:ProcessFile
findstr /b "%PosFilter%" %1 |findstr /v "%NegFilter%">nul || goto :eof  
echo Logfilename: %~1 >>"%Summary%"  
findstr /b "%PosFilter%" %1 |findstr /v "%NegFilter%" >>"%Summary%"  
echo.>>"%Summary%"  

echo Logfilename: %~1 >>"%Summary%"  

:ProcessFile
echo Bearbeite Logfile: %~1
findstr /b "%PosFilter%" %1 |findstr /v /c:"%NegFilter%">nul || goto :eof  
echo Logfilename: %~1 >>"%Summary%"  
findstr /b "%PosFilter%" %1 |findstr /v /c:"%NegFilter%">>"%Summary%"  
echo.>>"%Summary%"  

@echo off & setlocal
set "Summary=C:\log_summary.txt"  
set "PosFilter=WARNING ERROR"  
set "NegFilter=Sicherung nicht komplett"  
set "NegFilter2=Fehler ist vernachlässigbar"  

if exist "%Summary%" del "%Summary%"  
for %%i in (C:\logs\Log*.txt) do call :ProcessFile "%%i"  
goto :eof

:ProcessFile
echo Bearbeite Logfile: %~1
findstr /b "%PosFilter%" %1 |findstr /v /c:"%NegFilter%">nul |findstr /v /c:"%NegFilter2%">nul| goto :eof  
echo Logfilename: %~1 >>"%Summary%"  
findstr /b "%PosFilter%" %1 |findstr /v /c:"%NegFilter%"|findstr /v /c:"%NegFilter2%">>"%Summary%"  
echo.>>"%Summary%"