CMD-Batch, Stringzerlegung, String in Token teilen und letztes Token bei unbekannter Anzahl von Token finden

USER:[I][OI][CI][NP][IO][DENY][lange,Liste,mit,Permissions]

USER:[I]:[OI][CI][NP][IO]:[DENY][lange,Liste,mit,Permissions]

for %%i in (!VAR:[= !) do for /f "delims=]" %%B in ("%%i") do set "GroupLast=%%B"  

:ENVIRONMENT
@echo off
setlocal
pushd %~dp0
setlocal enabledelayedexpansion

	
:ROUTINE
call :INHERITANCE_NODES

	
:EXIT
setlocal disabledelayedexpansion
popd
endlocal
goto :eof


:INHERITANCE_NODES
setlocal
cls
echo.
echo   ===================================================================
echo   =              Find Inheritance Parent directory                  =
echo   ===================================================================
echo.
echo   Dieses Tool dient der Analyse von vergebenen Berechtigungen unter
echo   EINEM Erbknoten. Der naechst hoehere Erbknoten wird ermittelt und
echo   seine Struktur ab dem Verzeichnis der Abfrage ausgewiesen. Voraus-
echo   setzung ist eine entsprechende Berechtigung.
echo.
echo   Einsatz:
echo   Ermittlung des Verzeichnisses, welches als "Parent Directory" im  
echo   Sinn von "icacls /save" verstanden werden kann. Dieses Tool ist  
echo   Bestandteil eines etwas komplexeren Projektes.
echo.
echo   Begriffe:
echo   Eine Protokollierung ist noch nicht eingearbeitet. Doch die
echo   vorliegende Ausgabe beinhaltet bereits wesentliche Informationen.
echo   Zuornungen beziehen sich auf das Berechtigungsystem.
echo   Benutzer:         Weist den User zur jeweiligen Berechtigung aus
echo   Quelle Vererbung: Verzeichnis dem die jeweiligen Berechtigungen
echo                     zugeordnet sind
echo   Permission:       Gruppierung von Berechtigungen
echo   Object:           Das betrachtete Objekt selbst. Hier immer Verzeichnis
echo   Directories:      Alle dem "Object" untergeordneten Verzeichnisse  
echo   Files:            Alle dem "Object" untergeordneten Dateien  
echo   Sub Directories:  Dem "Object" direkt untergeordnete Verzeichnisse  
echo   Sub Files:        Dem "Object" direkt untergeordnete Dateien  
echo   ---------------------------------------------------------------------
echo   Bitte Verzeichnis zu dem der Erbknoten ermittelt werden soll eingeben
echo.
set /p "FilePath="  
set "ParentDir=%FilePath%"  
echo   Pruefverzeichnis: %FilePath%
echo.
	:FindParent
set "Parent=0"  
FOR /F "tokens=* useback" %%A in (`icacls "%ParentDir%"^|findstr /R /C:":(.*.)"`) DO (  
	set A=%%A
	set A=!A:%ParentDir% =!
	set A=!A:^(=[!
	set A=!A:^)=]!
	For /f "tokens=2 delims=:" %%1 in ('echo !A!^|findstr /L /C:"[I]["') DO (  
		set "Parent=1"  
		)
	set "Objects="  
	IF "!Parent!" EQU "0" (  
		For /F "tokens=1-2 delims=:" %%B in ('echo !A!') do (  
			for /f %%1 in ('echo %%C^|findstr /V /L /C:"[IO]["') do (  
				set "Objects=Object;"  
				)
			for /f %%2 in ('echo %%C^|findstr /L /C:"[CI]["') do (  
				for /f %%a in ('echo %%C^|findstr /L /C:"[NP]["') do (  
					set "Objects=!Objects!Sub Directories;"  
					)
				for /f %%a in ('echo %%C^|findstr /V /L /C:"[NP]["') do (  
					set "Objects=!Objects!Directories;"  
					)
				)
			for /f %%3 in ('echo %%C^|findstr /L /C:"[OI]["') do (  
				for /f %%a in ('echo %%C^|findstr /L /C:"[NP]["') do (  
					set "Objects=!Objects!Sub Files;"  
					)
				for /f %%a in ('echo %%C^|findstr /V /L /C:"[NP]["') do (  
					set "Objects=!Objects!Files;"  
					)
				)
			set "Permissions=%%C"  
			for %%4 in ([OI] [CI] [IO] [NP] [I]) do set "Permissions=!Permissions:%%4=!"  
			echo   Benutzer:         %%B
			echo   Quelle Vererbung: %ParentDir%
			echo   Permission:       !Permissions!
			echo                     Recht gilt fuer: !Objects!
			echo.
			)
		)
	)
if "%Parent%" EQU "1" (  
	for /F "tokens=* useback" %%I in (`echo %ParentDir%`) do (  
		set "ParentDir=%%~dpI"  
		set "ParentDir=!ParentDir:~0,-1!"   
		)
	goto :FindParent
	)
echo   Erbknoten:     %ParentDir%
endlocal
goto :eof