blueberry
Oct 03, 2008, updated at Jan 26, 2012 (UTC)
view7359
view8
0
Goto Top

CMD ein IF-Problem

GermansolvedQuestionBatch, ShellDevelopment
Hallo Zusammen,

Langsam aber sicher geht mir Batch aufen Wecker -.-''
Schon mein 3tes Problem im GLEICHEN Programm, nur dass ich es jetzt gemacht habe...

Was is hier der Fehler? Er nimmt z.B. für %MM% 10 anstatt 09 oder 08 (nur beim IF-Befehl)

@echo ON

REM Erstellen der Variable, um das Datum einzugeben.
SET /P DATE=Geben Sie das Datum ein (DD.MM.JJJJ):

REM Auseinander nehmen des Datums in Tage, Monate, Jahre und zuweisen der Variablen.
FOR /F "TOKENS=1,2,3 DELIMS=:./- " %%A IN ("%DATE%") DO (
SET /A DD=%%A
SET /A MM=%%B
SET /A JJ=%%C)

REM Wenn der Monat einen für den Computer als oktalen Zahlenwert ergibt, soll er das "0" am vor der Zahl wegnehmen.
IF %MM% LSS 10 (FOR /F "TOKENS=1,2,3 DELIMS=0.face-confused " %%A IN ("%MM%") DO (SET /A MONTH2=%%B))

ECHO %MONTH2%


PAUSE

Mit freundlichen Grüssen

Blueberry
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 98400

Url: https://administrator.de/contentid/98400

Printed on: April 26, 2024 at 06:04 o'clock

8 Comments
Latest comment
Goto Top
Member: bastla
bastla Oct 03, 2008 at 15:25:45 (UTC)
Goto Top
Hallo Blueberry!

Vorweg zwei Anmerkungen:

Es ist keine gute Idee, Systemvariablen (wie %DATE% oder allen, die nach der Eingabe von "set" bzw am Ende der Hilfe zu "set" angezeigt werden) neue Werte zuzuweisen, daher zB %DATUM% verwenden (%DATE% könnte auch erklären, warum Du immer 10 als Ergebnis bekkommen hast).

Wenn Du an den Anfang des Batches ein "setlocal" setzt, werden alle in diesem Batch erstellten oder veränderten Variablen am Ende des Batches (oder nach "endlocal") wieder "vergessen", sodass nicht ein anderer Batch daran scheitert, dass er einen unerwünschten Variablenwert "erbt".
Nun zum Oktal-Problem:
Deine Abfrage bzw Zerlegung kommt ohnehin zu spät, wenn Du bereits oben ein "SET /A" verwendest - daher zunächst einmal so (Variable %DATE% bereits auf %DATUM% geändert):
FOR /F "TOKENS=1,2,3 DELIMS=:./- " %%A IN ("%DATUM%") DO (  
SET DD=%%A
SET MM=%%B
SET JJ=%%C)
Was auch nicht klappen kann: Du versuchst, aus einer max zweistelligen Zahl (denn die soll sich ja in %MM% befinden) 3 Teile herauszuholen - so sollte das funktionieren:
IF %MM% LSS 10 (FOR /F "DELIMS=0" %%A IN ("%MM%") DO (SET /A MONTH2=%%A))
Allerdings wird diese Strategie für ein Datum ab Monat 10 scheitern, wenn Du nicht auch für den ELSE-Fall vorsorgst (oder zumindest in einem weiteren IF überprüfst, ob denn nun ein Wert für %MONTH2% gesetzt wurde, daher entweder:
IF %MM% LSS 10 (FOR /F "DELIMS=0" %%A IN ("%MM%") DO (SET /A MONTH2=%%A)) ELSE SET /A MONTH2=%MM%
oder
REM Loeschen einer ev bereits vorhandenen Variable %MONTH2%
SET MONTH2=
IF %MM% LSS 10 (FOR /F "DELIMS=0" %%A IN ("%MM%") DO (SET /A MONTH2=%%A))  
IF NOT DEFINED MONTH2 SET /A MONTH2=%MM%
Falls Dich noch ein anderer Ansatz interessiert:
SET /A MONTH2=1%MM%-100
Bei der letzten Variante musst Du Dich allerdings darauf verlassen, dass der Monatswert zweistellig eingegeben wurde.

Grüße
bastla

[Edit] Löschen der Variable %MONTH2% für Variante 2 ergänzt [/Edit]
Member: Blueberry
Blueberry Oct 03, 2008 at 21:15:53 (UTC)
Goto Top
Hallo Bastla,

Danke für die Erklärung ,vorallem dass du diese so einach gestaltet hast face-smile.

Bist echt ne RIIIIIIIIIIISSEEEEEN Hilfe face-smile

Danke nochma! Von dir kann ich noch viel lernen (also ja wenn ich wieder Fragen habe und du dich meldest und du auch lust hast sollche Fragen zu beantworten. Ich denke die sind eher Kinderkram für dich...face-smile Also sieht jedenfalls so aus als ob es so wäre face-smile)


Mit freundlichen Grüssen

Blueberry
Member: bastla
bastla Oct 03, 2008 at 21:32:51 (UTC)
Goto Top
Hallo Sandro! face-smile

Freut mich, wenn's Dir hilft ...

Grüße
bastla

P.S.: Wenn ich Dir nicht "DEFINED" hätte zeigen wollen, würde Variante 2 einfach so aussehen:
SET MONTH2=%MM%
IF %MM% LSS 10 (FOR /F "DELIMS=0" %%A IN ("%MM%") DO (SET /A MONTH2=%%A))
P.P.S.: Bitte verwende in Zukunft beim Posten von Batch -Tags (siehe ) - ua können dann Antworten leichter auf einzelne Zeilen (da diese nummeriert werden) Bezug nehmen.
Member: Biber
Biber Oct 04, 2008 at 10:08:42 (UTC)
Goto Top
Moin blueberry,

noch eine Ergänzung zu bastlas Variationen:
Falls Dich noch ein anderer Ansatz interessiert:

SET /A MONTH2=1%MM%-100

Bei der letzten Variante musst Du Dich allerdings darauf verlassen, dass der Monatswert zweistellig eingegeben wurde

Da ja genau das Ziel sollte, ebenso unverkrampf einen Januar-Monatswert als Input "01" wie als Input "1" verarbeiten zu können, wäre eher eine "Glättung" des Wertes mit der Modulo-Funktion sinnvoll.
Uberlegung:
Wenn Input=01--> 1001 Mod 100 = 1 genau wie auch 101 Mod 100= 1

Oder (zum Nachspielen am CMD-Prompt; die beiden Eintipp-Zeilen beginnen mit ">")
>for %i in (1 2 3 11 12) do @(SET /A "10%i % 100" & @echo.)  
1
2
3
11
12
> for %i in (01 02 03 11 12) do @(SET /A "10%i % 100" & @echo.)  
1
2
3
11
12
Beide For-Anweisungen bringen dasselbe Ergebnis, egal ob Inputwert 01 oder 1 ist.
Und es kann im Gegensatz zu bastlas Plan B-Variante nicht passieren, dass Du einen negativen Monatswert erhältst.

Grüße
Biber
Member: bastla
bastla Oct 04, 2008 at 13:20:21 (UTC)
Goto Top
@Biber
Natürlich ist Deine Version eleganter, aber letztlich schützt auch diese nicht vor einer (irrtümlichen) Monatsangabe "20" ...

Es würde sich daher, unter Beigabe einer Prise VBScript face-wink, etwa folgendes Rezept anbieten:
@echo off & setlocal
set C=%temp%\\CheckDate.vbs
>%C% echo D=WScript.Arguments(0):If IsDate(D) Then WScript.Echo Year(D)^&"-"^&Right("0"^&Month(D),2)^&"-"^&Right("0"^&Day(D),2)  

:Eingabe
set DatEin=
set /p "DatEin=Geben Sie bitte das Datum (DD.MM.JJJJ) oder E fuer Ende ein: "  
if /i "%DatEin:~,1%"=="E" goto :Abbruch  
set Datum=
for /f %%i in ('cscript //nologo %C% "%DatEin%"') do set Datum=%%i  
if defined Datum goto :Weiter
echo Ungueltige Eingabe!
echo\
goto :Eingabe

:Abbruch
echo Es wurde Abbruch gewaehlt - Batch wird beendet!
goto :eof

:Weiter
echo Eingegebenes Datum: %Datum%
Einem Benutzer, der es dann nicht schafft, das Datum in einer der folgenden Schreibweisen:
04.09.2008
4.09.2008
4.9.2008
04.09.08
4.9.8
2008-09-04
2008-9-4
04/09/2008
04/09/08
4/9/8
4. Sept. 2008
4.Sep.2008
4.Sep.8
4. September 2008
4. September 08
4.September 8
einzugeben, ist wohl ohnehin nicht zu helfen ...

Je nach der beabsichtigten Weiterverarbeitung lässt sich die Ausgabe des VBScrips von "JJJJ-MM-TT" natürlich auch auf "JJJJ-M-T" umstellen, wodurch eine Zuweisung zu numerischen Variablen nach einer Zerlegung mit "delims=-" problemlos möglich wird. Die entsprechend geänderte Zeile 3 sähe so aus:
>%C% echo D=WScript.Arguments(0):If IsDate(D) Then WScript.Echo Year(D)^&"-"^&Month(D)^&"-"^&Day(D)
Grüße
bastla
Member: Biber
Biber Oct 04, 2008 at 21:53:15 (UTC)
Goto Top
Moin bastla,
Es würde sich daher, unter Beigabe einer Prise VBScript , etwa folgendes Rezept anbieten

Nö, nö...
Jetzt aber nicht mit Nebelkerzen werfen... face-wink
Thema war mitnichten die Sicherstellung einer brauchbaren und geprüften Datumseingabe durch den Benutzer, sondern "nur" die gesicherte Aufdröselung eines Datums im %date%-Format in Tag, Monat und Jahr. Mehr nicht.
Auch VBSkript (oder Java oder Excel oder C# oder...) mit vorgegebenen IsDate()-Funktionen/Methoden helfen ja genau im Falle "04.09.08" nicht weiter, wenn dieses ein gültiges Datum im Format tt.mm.yy oder mm.tt.yy oder yy.mm.tt sein kann.

Also lass uns am Thema bleiben - die Frage war:
Wieso bekomme ich in meinem Batch beim TAG-Wert Grütze heraus, obwohl ich ein gültiges Gesamtdatum tt.mm.yyyy als Input genommen habe...?
Und diese Frage hattest Du ja (bis auf meine oben folgende Fussnote) vollständig beantwortet.
Nu' verwirr das junge Talent nicht mit zuviel auf einmal... face-wink

Grüße
Biber
Member: bastla
bastla Oct 04, 2008 at 22:06:16 (UTC)
Goto Top
Hallo Biber!

Also lass uns am Thema bleiben - die Frage war, wieso bekomme ich in meinem Batch beim TAG-Wert Grütze heraus, obwohl ich ein gültiges Gesamtdatum tt.mm.yyyy als Input genommen habe...
Und diese Frage hattest Du ja (bis auf meine oben folgende Fussnote) vollständig beantwortet.
Wenn das Datum tatsächlich im Format "tt.mm.yyyy" vorläge, wäre auch Deine Fußnote hinsichtlich
Januar-Monatswert als Input "01" wie als Input "1"
schon zuviel des Guten ... face-wink

Grüße
bastla
Member: Blueberry
Blueberry Oct 06, 2008 at 07:38:27 (UTC)
Goto Top
Hallo Zusammen,

Ich hoffe, ihr hattet ein schönes Wochenende. Ehm, mein Problem hat sich gelöst.
und Bastla, danke aber ich darf leider auch kein VBScript brauchen. Aber wäre auch ne tolle Lösung.

Biber, danke auch für deine Beiträge!^^

Mit freundlichen Grüssen

Blueberry
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
gleixnerdCheck of ZFW Firewallgleixnerd - 5 Comments