Domain user in C Sharp Programm einbinden für Berechtigung

    ''' <summary>  
    ''' Liest die aktuellen User-Daten aus dem AD  
    ''' </summary>  
    ''' <returns></returns>  
    Public Function ActiveUserDatasFromAD() As Dictionary(Of String, String)
        'AD  ---> Der User wird über den aktuell am AD angemeldeten Benutzernamen ermittelt  
        'zuerst den Namen des angemeldeten Nutzers ermitteln  
        Dim _objADUser As New System.Security.Principal.WindowsPrincipal(System.Security.Principal.WindowsIdentity.GetCurrent)
        Dim _strBenutzerName As String = _objADUser.Identity.Name
        Dim _bolAutorisiert As Boolean = _objADUser.Identity.IsAuthenticated
        If Not _bolAutorisiert Then Throw New Exception("Die AD-Autorisierung für %1 konnte nicht bestätigt werden.".Replace("%1", _strBenutzerName.Replace("ASENDIA\", "")))  
        'Nutzerdaten ermitteln  
        Dim _lst As New List(Of String)
        _lst.Add("givenName")  
        _lst.Add("sn")  
        _lst.Add("cn")  
        _lst.Add("telephoneNumber")  
        _lst.Add("department")  
        _lst.Add("physicalDeliveryOfficeName")  
        _lst.Add("mail")  
        _lst.Add("distinguishedName")  
        Dim dt As DataTable = GetLDAPUserAttributs(_strBenutzerName.Replace("ASENDIA\", ""), _lst, True).Copy  
        If dt.Rows.Count <> 1 Then
            Throw New Exception("Es wurden im AD mehrere User für %1 gefunden ? [ActiveUserDatasFromAD] ".Replace("%1", _strBenutzerName.Replace("ASENDIA\", "")))  
        End If
        'in Dictonary schreiben  
        Dim UserDatas As New Dictionary(Of String, String)
        For Each _item As DataColumn In dt.Columns
            UserDatas.Add(_item.ColumnName.ToString, IIf(IsDBNull(dt.Rows(0)(_item.ColumnName)), "", dt.Rows(0)(_item.ColumnName)))  
        Next
        UserDatas.Add("BenutzerName", _strBenutzerName.Replace("ASENDIA\", ""))  
        Return UserDatas
    End Function

    ''' <summary>  
    ''' Return DataTable with LDAP UserAttributs  
    ''' </summary>  
    ''' <param name="SearchPerson">SearchPattern for sn or cn</param>  
    ''' <param name="List<string>">List of Attributs</param>  
    ''' <param name="GlobalCatalog">False for Local Domain, True for Search in GlobalCatalog</param>  
    ''' <returns></returns>  
    ''' <example>  
    '''    in C#:   
    '''    DataTable dt = GetLDAPUserAttributs("Fischer", new List<string>(new string { "givenName", "sn", "cn", "telephoneNumber", "department", "physicalDeliveryOfficeName", "mail", "distinguishedName" }), true);     
    ''' </example>  
    Public Function GetLDAPUserAttributs(ByVal SearchPerson As String, ByVal LDAPProperties As List(Of String), ByVal GlobalCatalog As Boolean) As DataTable
        SearchPerson = SearchPerson '& "*"  
        Dim dt As New DataTable()
        Dim dr As DataRow
        Dim Searcher As New DirectorySearcher()
        Dim SearchResults As SearchResultCollection = Nothing
        Searcher.Filter = "(&(objectClass=user)(|(displayName=" & SearchPerson & ")(cn=" & SearchPerson & ")(sAMAccountName=" & SearchPerson & ")))"  
        Searcher.SearchScope = SearchScope.Subtree
        dt.Columns.Add(New DataColumn("Domain", GetType(String)))  
        For Each Name As String In LDAPProperties
            dt.Columns.Add(New DataColumn(Name, GetType(String)))
            Searcher.PropertiesToLoad.Add(Name)
        Next Name
        If GlobalCatalog Then
            Dim d As Domain = System.DirectoryServices.ActiveDirectory.Domain.GetCurrentDomain()
            Dim gc As GlobalCatalog = d.Forest.FindGlobalCatalog()
            Searcher.SearchRoot = New DirectoryEntry("GC://" & gc.Name)  
        Else
            Dim adsiRoot As New System.DirectoryServices.DirectoryEntry("LDAP://RootDSE")  
            Searcher.SearchRoot = New DirectoryEntry("LDAP://" & adsiRoot.Properties("defaultNamingContext")(0))  
        End If
        SearchResults = Searcher.FindAll()
        For Each Result As SearchResult In SearchResults
            dr = dt.NewRow()
            Dim Domain As String = Result.Path
            Domain = Domain.Substring(Domain.IndexOf("DC="))  
            Domain = Domain.Replace("DC=", "")  
            Domain = Domain.Replace(",", ".")  
            dr("Domain") = Domain  
            For Each Name As String In LDAPProperties
                If Result.Properties(Name).Count >= 1 Then
                    dr(Name) = Result.Properties(Name)(0)
                End If
            Next Name
            dt.Rows.Add(dr)
        Next Result

        'Dim searcher As DirectorySearcher = Nothing  
        Dim lMembers As New List(Of String)()
        'Searcher = New DirectorySearcher(New DirectoryEntry(String.Concat("LDAP://", Domain), USERname, password))  
        Searcher.Filter = String.Concat("(&(objectClass=User) (sAMAccountName=", SearchPerson, "))")  
        Searcher.PropertiesToLoad.Add("MemberOf")  
        Dim result2 As SearchResult = Searcher.FindOne()
        Dim i As Integer = 0
        Do While i < result2.Properties("MemberOf").Count  
            Dim sProp As String = result2.Properties("MemberOf")(i).ToString()  
            lMembers.Add(sProp.Substring(3, sProp.IndexOf(",") - 3))  
            i += 1
        Loop

        dt.Columns.Add("GroupsMemberShip", System.Type.GetType("System.String"))  
        If lMembers.Count > 0 Then
            Dim _groups As String = ""  
            For Each _item As String In lMembers
                _groups += IIf(_groups = "", "", vbCrLf) + _item  
            Next
            dt.Rows(0)("GroupsMemberShip") = _groups  
        End If
        dt.AcceptChanges()
        Return dt
    End Function