Lösung gesucht: aus epub METADATA title leeren. eBookReader soll dadurch nach Dateinamen sortieren bzw. diese anzeigen

@if (@x)==(@y) @end /*

@echo off &setlocal
set "p7z=%ProgramFiles%\7-Zip\7z.exe" 
set "epubdir=D:\eBooks" 

set "flag=" 
for /f "delims=" %%h in ('dir /a-d /b /s "%epubdir%\*.epub"') do ( 
  for /f "tokens=3,5*" %%i in ('call "%p7z%" l "%%~h"^|findstr /ie "\.opf"') do if "%%i" lss "D" ( 
    >nul call "%p7z%" x "%%~h" "%%k" 
    cscript //nologo //e:jscript "%~fs0" "%%k" 
    >nul call "%p7z%" u "%%~h" "%%k" 
    if "%%k"=="%%~nxk" (del "%%k") else ( 
      set "p=%%k" 
      setlocal EnableDelayedExpansion
      for %%l in ("!p:\=" "!") do if not defined flag (set "flag=1" &rd /s /q %%l) 
      endlocal
    )
  )
)
pause
exit /b

*/

var oXmlDoc = new ActiveXObject('Microsoft.XMLDOM');  
oXmlDoc.async = false;
oXmlDoc.load(WScript.Arguments(0));
var oErr = oXmlDoc.parseError;
if (oErr.errorCode == 0) {
  var oNode = oXmlDoc.documentElement.selectSingleNode('//metadata/dc:title');  
  if (null != oNode) {
    oNode.text = '';  
    oXmlDoc.save(WScript.Arguments(0));
  }
}

<#
    Löscht den Title aus der content.opf jeder epub Datei eines Ordners (inkl. Unterordner)
#>
# ===== Variablen anpassen =======
# Pfad zu den Dateien
$pathFiles = 'A:\ebooks'  
# ================================

# Benötigt wird mindestens NET-Framework 4.5 und Powershell 3.0
if ($PSVersionTable.PSVersion.Major -lt 3){write-host "ERROR: Minimum Powershell Version 3.0 is required!" -F Yellow; return}   

# benötigte Assemblies laden
Add-Type -AssemblyName System.IO.Compression
Add-Type -AssemblyName System.IO.Compression.Filesystem

# Verarbeite alle eBooks im Ordner
gci $pathFiles -Filter '*.epub' -Recurse -File | %{  
    # ePub als ZIP-Datei im Update-Modus öffnen
    $zipfile = [System.IO.Compression.ZipFile]::Open($_.FullName,[System.IO.Compression.ZipArchiveMode]::Update)
    
    # Temporäre Extrahierungs-Pfade für die Datei die geändert wird
    $contentfile = "$env:TEMP\content.opf"  
    
    # Falls die temoporäre Datei existiert lösche sie
    if((Test-Path $contentfile)){del $contentfile -Force}
    
    # Einträge der benötigte Dateien aus dem Dokument holen
    $entry = $zipfile.Entries | ?{$_.Name -eq 'content.opf'} | select -First 1  
    
    if ($entry){
        # content.opf extrahieren
        [System.IO.Compression.ZipFileExtensions]::ExtractToFile($entry,$contentfile)

        # Titel leeren (wegen einer Property, hier per einfachem Regex-Replace)
        (gc $contentfile) -replace '(<dc:title[^>]*>).*?(</dc:title>)','$1$2' | set-content $contentfile  

        # Alternative Variante zum Löschen des Titels via XML (nicht aktiv)
        <#
            $xml = [xml](gc $contentfile)
            $xml.package.metadata.title.InnerText = ''  
            $xml.Save($contentfile)
        #>

        # alte content.opf aus der epub-Datei entfernen
        $entry.Delete()

        # geänderte Dateien wieder hinzufügen
        [System.IO.Compression.ZipFileExtensions]::CreateEntryFromFile($zipfile,$contentfile,$entry.Fullname) | out-null

        write-host "$($_.FullName) ==> Update durchgeführt." -ForegroundColor Green  
    }else{
        write-host "$($_.FullName) ==> Datei enthält keine 'content.opf'." -ForegroundColor Yellow  
    }
    # Zipfile-Resourcen freigeben
    $zipfile.Dispose()
}

  echo "%%~h"

@if (@x)==(@y) @end /* Gültige Zeile in Batch und JScript, die einen JScript Kommentar einleitet.

:: Batch Part
@echo off &setlocal
REM Pfad zur 7z.exe
set "p7z=%ProgramFiles%\7-Zip\7z.exe"  
REM Pfad zu den ePUB Dateien
set "epubdir=D:\eBooks"  

REM 7z Pfad zu 8.3 Kurznamen konvertieren
for %%i in ("%p7z%") do set "p7z=%%~fsi"  
REM Rekursiv nach allen .epub Archiven suchen.
for /r "%epubdir%" %%h in ("*.epub") do (  
  REM Fehlerflag. Initial wird angenommen, dass ein Fehler auftritt und die Variable ist definiert.
  set "fail=1"  
  REM Eingenschaften "Schreibgeschützt", "System" und "Versteckt" beim gefundenen Archiv entfernen.  
  attrib -r -s -h "%%~h"  
  REM Inhalt des Archivs auflisten und nur die Zeile mit der .opf Datei aus der Liste extrahieren.
  for /f "delims=" %%i in ('%p7z% l "%%~h" -y^|findstr /ie "\.opf"') do (  
    REM Gefundene Zeile einer Variablen zuweisen.
    set "ln=%%i"  
    REM Verzögerte Variablenerweiterung einschalten, um die neue Variable in einem Zeilenblock verarbeiten zu können.
    setlocal EnableDelayedExpansion
    REM Die ersten 20 Zeichen der Variable werden abgeschnitten. Dort findet sich das Timestamp der Datei, falls dieses gestzt war.
    REM Das erste Token enthält die Dateiattribute, alles nach dem dritten Token ist Pfad und Name der .opf Datei im Archiv.
    REM Nach dem Splitten der Zeile wird die Verzögerte Variablenerweiterung ausgeschaltet und geprüft, dass der gefundene Pfad kein Verzeichnis ist.
    for /f "tokens=1,3*" %%j in ("!ln:~20!") do endlocal &if "%%j" lss "D" (  
      REM Temporäres Verzeichnis für zu entpackende Dateien anlegen.
      md "unzip"  
      REM Die .opf Datei unter Beibehaltung ihres Pfads entpacken.
      >nul 2>&1 %p7z% x "%%~h" "%%l" -o"unzip" -y  
      REM Falls das erfolgreich war und die ausgepackte Datei existiert...
      if exist "unzip\%%l" (  
        REM In das temporäre Verzeichnis wechseln.
        pushd "unzip"  
        REM Eingenschaften "Schreibgeschützt", "System" und "Versteckt" der .opf Datei entfernen.  
        attrib -r -s -h "%%l"  
        REM Diese Scriptdatei als JScript ausführen, wobei der Pfad der .opf Datei übergeben wird um dort den Titel entfernen zu können.
        cscript //nologo //e:jscript "%~fs0" "%%l"  
        REM Wenn das Entfernen erfolgreich war ...
        if not errorlevel 1 (
          REM Update der .opf Datei im Archiv.
          >nul 2>&1 %p7z% u "%%~h" "%%l" -up1q1r2x2y2z2w2 -y  
          REM Falls das erfolgreich war, Fehlerflag entfernen, ansonsten ...
          if not errorlevel 2 (set "fail=") else (  
            REM Alle anderen Dateien und Verzeichnisse aus dem Archiv zur bereits geänderten .opf Datei entpacken.
            >nul 2>&1 %p7z% x "%%~h" -xr!"*.opf" -y  
            REM Falls das erfolgreich war ...
            if not errorlevel 2 (
              REM Originalarchiv löschen.
              del /f "%%~h"  
              REM Archiv aus den entpackten Dateien neu erstellen.
              >nul 2>&1 %p7z% a "%%~h" -r -tzip -y  
              REM Falls das erfolgreich war, Fehlerflag entfernen.
              if not errorlevel 2 set "fail="  
            )
          )
        )
        REM In das ursprüngliche Arbeitsverzeichnis zurückwechseln.
        popd
      )
      REM Temporäres Verzeichnis löschen.
      rd /s /q "unzip"  
    )
  )
  REM Anhand des Fehlerflags Fehler- oder Erfolgsmeldung ausgeben.
  if defined fail (>&2 echo *** Fehler: "%%~h") else echo OK: "%%~h"  
)

pause
REM Batchverarbeitung beenden.
exit /b

Hier endet der JScript Kommentar: */

/* JScript Part */

// Try Block, um Ausnahmefehler der JScript Verarbeitung abzufangen.
try {
  // Instanz des Microsoft.XMLDOM Objektes erstellen
  var oXmlDoc = new ActiveXObject('Microsoft.XMLDOM');  
  // Flag um zu signalisieren, dass auf eine vollständig geldene XML Datei gewartet werden soll.
  oXmlDoc.async = false;
  // Die übergebene .opf Datei als XML Text laden.
  oXmlDoc.load(WScript.Arguments(0));
  // Fehlerobjekt deklarieren.
  var oErr = oXmlDoc.parseError;
  // Falls beim Parsen des Dateiinhalts kein Fehler aufgetreten ist ...
  if (oErr.errorCode == 0) {
    // Knotenobjekt deklarieren und initialisieren, das den Titel enthält.
    var oNode = oXmlDoc.documentElement.selectSingleNode('//metadata/dc:title');  
    // Falls der Knoten gefunden wurde ...
    if (null != oNode) {
      // Text des Knotens löschen.
      oNode.text = '';  
      // XML Text in die .opf Datei zurückschreiben.
      oXmlDoc.save(WScript.Arguments(0));
      // Script beenden und 0 zurückgeben.
      WScript.Quit(0);
    }
  }
  // Diese Punkt wird erreicht, wenn eines der if Statements FALSCH ergeben hat. Script beenden und 1 als Fehlerindikator zurückgeben.
  WScript.Quit(1);
}
// Der catch Block wird ausgeführt, wenn ein Ausnahmefehler aufgetreten ist.
catch(e) {
  // Script beenden und 1 als Fehlerindikator zurückgeben.
  WScript.Quit(1);
}

for /r "%epubdir%" %%h in ("*.epub") do (