Mikrotik - Limitierung d. gesamten Traffics

# Queue Namen und deren zugehöriges Maximum an zulässigen Bytes
:local QUEUES {"queue1"=10000000;"queue2"=2000000}  
# Name der Block Address-List
:local BLOCKLISTNAME "MyBlocklist"  
# ------------
:foreach qname,maxbytes in=$QUEUES do={
    :local qnum [/queue simple find name="$qname"]  
    :if ([:len $qnum] > 0) do={
        :local qtarget [:pick [:tostr [/queue simple get $qnum target]] 0 [:find [:tostr [/queue simple get $qnum target]] "/" 0]]  
       :if ([:len [/ip firewall address-list find list="$BLOCKLISTNAME" address="$qtarget"]] = 0) do={  
            :local bytes [/queue simple get $qnum bytes]
            :local bytesUP [:tonum [:pick $bytes 0 [:find $bytes "/" 0]]]  
            :local bytesDOWN [:tonum [:pick $bytes ([:find $bytes "/" 0]+1) 50]]  
            :local bytesTOTAL ($bytesUP + $bytesDOWN)
            :if ($bytesTOTAL > $maxbytes) do={
                 /log info message="Queue ->$qname<- exceeded max bytes ($[($bytesTOTAL / 1024)] KB), adding target '$qtarget' to blocklist."  
                 /ip firewall address-list add list="$BLOCKLISTNAME" address=$qtarget  
             }
        } else={
            :put "Target already in blocklist, skipping queue check."  
        }
     } else={
         /log warning message="A queue with the name '$qname' was not found!"  
     }
}

# reset queue limits for next day
# -----------------------------------------------
# Namen der Queues im Array angeben
:local QUEUES [:toarray ("queue1","queue2")]  
# Name der Block Address-List
:local BLOCKLISTNAME "MyBlocklist"  
# -----------------------------------------------
# Entferne alle IPs aus der Addressliste
/ip firewall address-list remove [find list="$BLOCKLISTNAME"]  
# counter reset der Queues
:foreach qname in=$QUEUES do={/queue simple reset-counters "$qname"}  

/ip firewall filter add chain=input action=reject reject-with=icmp-host-prohibited src-address-list="MyBlocklist"