Outlook 2003 - Ein Programm versucht auf Ihre in Outlook gespeicherten E-Mail-Adressen zuzugreifen...

; fcw: 2012-06-06: Skript mit dem man die lästige Abfragen von "Advanced Security für Outlook"   
; automatisch bestätigen und schließen kann

; Skript bleibt am laufen
#Persistent
; kein Icon (aber Hotkey STRG+SHIFT+ALT+O, s.u.)
#NoTrayIcon

SetTitleMatchMode 1
DetectHiddenWindows, on

fenstertitel := "Advanced Security für Outlook"  

; mit SetTimer, weil weniger Auslastung als Loop.
SetTimer, Check, 500
Check:
if WinExist(fenstertitel)
{
	; Mauskoordinaten beziehen sich auf den Screen (absolut):
	CoordMode, Mouse, Screen
	; Mauskoordinaten zwischenspeichern:
	MouseGetPos, xpos, ypos
	; Mauskoordinaten auf das aktuelle Fenster beziehen:
	CoordMode, Mouse, Relative
   
	; fcw: direkt in das Fenster klicken, also Position vom Fenster aus, nicht vom Control (funktioniert nicht)
	; zuerst die Auswahlliste, oberster Eintrag: "Zugriff erlauben"  
	; evtl. müssen die Werte x114 y237 (der oberste Eintrag der Liste, bezogen auf links oben des Fensters) angepasst werden
	ControlClick, x114 y237, %fenstertitel%
	; dann die CheckBox setzen fuer dauerhaftes Merken, hier auch, evtl. x41 y359 (die CheckBox) anpassen.
	ControlClick, x41 y359, %fenstertitel%
	; schliesslich OK druecken
	ControlClick, OK, %fenstertitel%	
	
	; wieder auf Screen-Koordinaten schalten:
	CoordMode, Mouse, Screen
	; Maus wieder zuruecksetzen wo sie vorher war:
	MouseMove, %xpos%, %ypos%, 0	
}
return

; bei STRG+SHIFT+ALT+O TrayIcon (t wie "OutookAdvancedSecurity") zeigen  
^+!o::
   If (A_IconHidden = 1) ; 1 = TrayIcon ist versteckt
      Menu, Tray, Icon  ; und wir machen es jetzt sichtbar
   else
      Menu, Tray, NoIcon  ; unsichtbar machen, da es sichtbar war
return