Rechnername über den Usernamen finden

If WScript.Arguments.Count = 0 Then
	strUserName = InputBox("Gesuchter Username?")  
Else
	strUserName = WScript.Arguments(0)
End If
If strUserName = "" Then WScript.Quit(1)  
strUserName = UCase(strUserName)

strSQL = "SELECT name " _  
   & "FROM 'LDAP://DC=firma,DC=de' " _  
   & "WHERE objectClass='computer' "  

' ADO-Verbindung herstellen  
Set objDom = CreateObject("ADODB.Connection")  
objDom.Open "Provider=ADsDSOObject;"  

' Suche ausführen  
Set objRS = objDom.Execute(strSQL)

objRS.MoveFirst
Do Until objRS.EOF
	strComputer = objRS("name")  
	If IsOnline(strComputer) Then
		Set objWMIService = GetObject("winmgmts:" _  
			& "{impersonationLevel=impersonate}!\\" _  
			& strComputer & "\root\cimv2")  
			
		Set colComputer = objWMIService.ExecQuery _
			("Select * from Win32_ComputerSystem")  

		For Each objComputer in colComputer
			If Not IsNull(objComputer.UserName) Then
				strLogonUser = Split(objComputer.UserName,"\")  
				strLoggedonUser = UCase(Trim(strLogonUser(1)))
			
				If strUserName = strLoggedOnUser Then 
					WScript.Echo strLoggedOnUser & " is logged on at " _  
						& strComputer
				End If
			End If
		Next
	End If
	objRS.MoveNext
Loop
WScript.Echo "Suche nach User " & strUserName & " beendet."  

Function IsOnline(PCName)
' Läuft nur unter Windows XP, Windows Server 2003 und Nachfolgern  
    IsOnline=False
    Set objPing = GetObject("winmgmts:" _  
    & "{impersonationLevel=impersonate}"). _  
    ExecQuery("select ReplySize from " _  
    & "Win32_PingStatus where address= '" _  
    & PCName & "'")  

    For Each objStatus In objPing
        If Not IsNull (objStatus.ReplySize) Then
           IsOnline = True
        Else
           IsOnline=False
        End If
    Next
End Function

cscript //nologo Scriptname.vbs GesuchterUser > CompListe.txt