vbs - Dateien löschen die älter als n-Tage sind

Ein Hallo in die Runde,

meine Ziel ist es, eine vbs zu erstellen, die alle Dateien die älter sind als 19 Monate löscht.

Nun habe ich hier im Forum einen Code gefunden und abgewandelt:

Set myArguments = WScript.Arguments

If myArguments.Count <> 1 Then 
call DisplayInfo
Wscript.Quit (1)
End if

Dim heute, olddate
heute = FormatDateTime(Date, 2)
olddate = DateAdd("d", -270, heute)  

set objFS = CreateObject("Scripting.FilesystemObject")  
set myFolder = objFS.GetFolder(myArguments(0))
set myFiles = "J:\ test"  

for each myfile in myFiles
If myFile.DateModified < olddate then
myFile.Delete
end if
next 

Sub DisplayInfo
MsgBox "Usage: delmyordner.vbs [FolderPath]", vbExclamation, "Missing Argument"  
End Sub

Da ich delage32, autoit und andere Drittprogramme nicht nutzen kann, würde ich dies gern mit vbs probieren.

Ich vermute, dass der Fehler by "set myFiles" liegen könnte. Hier stand im Original myFolder.Files. Ich habe das auch in der Variante "J:\test.*" probiert funktioniert leider auch nicht.

Nachdem ich zum Thema Kopieren mittels batch hier im Forum hervorragende Hilfe erfahren habe, hoffe ich, dass es auch hierzu ein Hinweis gegeben werden kann.

Ich bedanke mich ganz herzlich im voraus.

Cu Koido

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 121567

Url: https://administrator.de/forum/vbs-dateien-loeschen-die-aelter-als-n-tage-sind-121567.html

Ausgedruckt am: 23.12.2024 um 12:12 Uhr

9 Kommentare

Neuester Kommentar

Hallo Koido1!

Versuchs mal damit (ungetestet):

Dim  myArguments, objFS, myFolder, myFile, olddate

Set myArguments = WScript.Arguments

If myArguments.Count <> 1 Then Call DisplayInfo:  Wscript.Quit (1)

olddate = DateAdd("m", -19, Now)  '19 Monate  

set objFS = CreateObject("Scripting.FilesystemObject")  

If Not objFS.FolderExists(myArguments(0)) Then Call DisplayInfo: Wscript.Quit (1)

set myFolder = objFS.GetFolder(myArguments(0))

for each myfile in myFolder.Files
    If myFile.DateLastModified < olddate then objFS.DeleteFile myFile.Path
next 

Sub DisplayInfo
    MsgBox "Usage: delmyordner.vbs [FolderPath]", vbExclamation, "Missing Argument"  
End Sub

Gruß Dieter

[edit] Fehler korrigiert und Test Folder hinzugefügt [/edit]

Hallo Dieter,

vielen Dank für die schnelle Antwort. Da meine Kentnnisse gegen Null gehen, habe ich noch ein paar Schwierigkeiten.

Wo ist bei Dir der Ort definiert, welches Laufwerk/Verzeichnis ich bestimme?

Wenn ich myFolders.Files mit meinem betroffenen Pfad bezeichne, funktioniert das Löschen noch nicht.

Cu Koido

Hallo Koido1!

Code oben geändert.

Den Fehler myFile.Delete habe ich leider übersehen

Zusätzlich habe ich noch den Test FolderExists hinzugefügt.

Die Pfadangabe musst in Deinem Code als Argument übergeben. Wenn Du möchtest, kann man eine Abfrage per InputBox machen?

Gruß Dieter

Hallo Dieter,

bin ein wenig langsam im Kopf

Heißt das jetzt, ich benenne FoderExists einfach um in "J:\...test" oder muss ich noch an einer Stelle definieren
set (was?) = "J:\...test"

Das mit der Abfrage klingt auch super. Wenn ich das richtig verstehe, gebe ich in die Inputbox den Pfad ein, welcher dann nach den Kriterien (19 Monate) durchsucht wird. Das wäre zwar für mich schon das nächste Level aber jaaaaaaaaaa

Danke Koido

Hallo Koido1!

Also, am Code änderst Du nichts.

Mit Argument bedeutet, dass Du beim Aufruf des Scripts ein Argument mit übergibst: z.B.: Test.Vbs x:\test

Aber vielleicht doch besser mit einer Abfrage, wie in diesem Code:

Dim  objFS, myPath, myFolder, myFile, olddate

myPath = InputBox("Bitte Pfad eingeben:", "Dateien älter als 19 Monate löschen")  

If myPath = "" Then Call DisplayInfo:  Wscript.Quit (1)  

set objFS = CreateObject("Scripting.FilesystemObject")  

If Not objFS.FolderExists(myPath) Then Call DisplayInfo:  Wscript.Quit (1)

set myFolder = objFS.GetFolder(myPath)

olddate = DateAdd("m", -19, Now)  '19 Monate  

for each myfile in myFolder.Files
    If myFile.DateLastModified < olddate then objFS.DeleteFile myFile.Path
next 

Wscript.Quit (0)

Sub DisplayInfo
    MsgBox "Usage: delmyordner.vbs [FolderPath]", vbExclamation, "Missing Argument"  
End Sub

Den Text in der InputBox kannst Du natürlich ändern. Erstelle einen Test-Ordner zum Testen.

Nach dem Starten des Scripts *.vbs:
1. Erscheint eine Eingabe-Box mit der Pfadabfrage
2. Ist die Pfadangabe Leer oder wird abgebrochen, erscheint die MsgBox und das Script wird beendet.
3. Existiert der Ordner nicht, dann passiert das gleiche wie unter Punkt 2 beschrieben.

Bei der Eingabe kann leider nicht unterschieden werden, ob eine Leer-Eingabe oder ein Abrechen erfolgt ist, daher wird in beiden Fällen die MsgBox ausgegeben und das Script mit Errorlevel 1 beendet. Ansonsten gibt das Script Errorlevel 0 zurück. Errorlevel kann z.B. in einer Batch entsprechend ausgewertet werden.

Noch Fragen?

Gruß Dieter

Yessssssssssss....

Funktioniert hervorragend.
Das mit der Input Box war ne super Idee. Danke für Deine Hilfe.

Danke auch für Deine Erklärungen, das hilft mir für das Verständnis weiter. Super Ding.

Cu Koido

Hallo Koido1!

Yep, gern geschehen

Gruß Dieter

Hall Koido!

Also, Ich bin mir nicht sicher, ob Du weißt, dass es sich bei "DateLastModified" um das letzte
Änderungsdatum handelt. Falls Du aber das Erstellungsdatum verwenden möchtest, dann
ersetze "DateLastModified" durch "DateCreated"

Gruß Dieter

Hallo Dieter,

nein, das ist genau so richtig. Wenn eine Datei verändert wurde, soll sie nicht gelöscht werden, sondern die Zeit fängt wieder von vorn an. Danke Dir

Cu Koido

gelöst Frage VB for Applications Entwicklung

Mehr von Koido1

Batch Sicherung der Dateien der letzten 18 MonateKoido1 - 26 Kommentare

Heiß diskutiert