BitLocker-Schutz für das Systemlaufwerk anhalten, Computer neustarten und den BitLocker-Schutz wieder fortsetzen

:BitLocker-Schutz für das Systemlaufwerk anhalten, Computer neustarten und den BitLocker-Schutz wieder fortsetzen

:Getestet unter Windows 7 Ultimate, 32-Bit

@echo off
@prompt -$G
chcp 1252 >nul
:PushD %~dp0
echo.

:=================================
:RunAs Administrator
:=================================
set Arguments=%*

:Wenn mind. ein Argument übergeben worden ist, dann die Anführungszeichen verdoppeln.
if defined Arguments set "Arguments=%Arguments:"=""%"  
:echo %Arguments%

:--------------------------------------
:Check for permissions 
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" && goto :gotAdmin  

echo Administrator-Rechte anfordern...

:Write the name from the user witch have first executet the file (prior the UAC request)
>"%temp%\getadmin.vbs" echo 'ExecutedUnderContexFromUser:	%UserName%  

:Argumente in VB-Script mit 2x doppelten Anführungszeichen umrahmen: ""Ar1"" ""Arg2"" ...  
>>"%temp%\getadmin.vbs" echo CreateObject("Shell.Application").ShellExecute "%ComSpec%"," /c "" ""%~f0"" %Arguments% "" ",,"runas",1  
"%temp%\getadmin.vbs"  
exit /b

:gotAdmin
:--------------------------------------

:Den Benutzer anzeigen, unter dessen Kontext diese Batch-Datei zuerst ausgeführt worden ist:
for /f "tokens=2* delims=:	" %%d in ('findstr "ExecutedUnderContexFromUser" "%temp%\getadmin.vbs"') do set ExecutedUnderContexFromUser=%%d  
:echo Ausgeführt zuerst vom Benutzer: %ExecutedUnderContexFromUser%
if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs"  

:=================================
:Execute code
:=================================

:BitLocker-Schutz-Status für das Laufwerk abfragen 
:(bei der Statusabfrage gibt der Parameter {-protectionaserrorlevel | -p} den Errorlevel 0, wenn
:das Volume geschützt ist, und andersrum den Errorlevel -1 zurück).
manage-bde -status %SystemDrive% -protectionaserrorlevel>nul
if not %Errorlevel%==0 (
	cls
	echo.
	echo ###############################################################################
	echo # WARNUNG:                                                                    #
	echo # Der Bit-Locker-Schutz ist auf dem Laufwerk %SystemDrive% nicht aktiv.                  #
	echo # Der geplante Schutz wird nach einem Neustart nicht automatisch fortgesetzt! #
	echo ###############################################################################
	pause >nul
	goto :eof
	)

:BitLocker für das Systemlaufwerk anhalten.
manage-bde -protectors -disable %SystemDrive%

:BitLocker-Schutz für das Systemlaufwerk fortsetzen
set TaskName=Bitlocker-Schutz für das Systemlaufwerk fortsetzen
set ScriptPath=%SystemDrive%\Windows\Temp\%TaskName%.bat

:temporäres Skript erstellen, welches nach Neustart ausgeführt werden soll
echo @echo off>"%ScriptPath%"  
echo echo BitLocker-Schutz für das Systemlaufwerk wird wieder fortgesetzt>>"%ScriptPath%"  
echo chcp 1252 ^>nul>>"%ScriptPath%"  
echo manage-bde -protectors -enable %SystemDrive%>>"%ScriptPath%"  
:BitLocker-Status aktualisieren (Entfernt die alte Warnung von BitLocker im Infobereich - auf der Taskleiste rechts. Wenn der BitLocker-Schutz
:das nächste Mal via GUI angehalten oder fortgesetzt wird, wird der aktuelle Status weiterhin problemlos angezeigt.)
echo taskkill.exe /IM fvenotify.exe>>"%ScriptPath%"  
echo start "" fvenotify.exe>>"%ScriptPath%"  
echo del "%ScriptPath%">>"%ScriptPath%"  

:In der Registry eintragen, dass das Skript beim Anmelden (durch einen beliebiegen Anwender) automatisch ausgeführt werden muss
:Das "!"-Zeichen im Namen des Wertes sorgt hierfür, dass der Wert erst nur dann aus dem Registry-Schlüssel gelöscht wird,  
:wenn sein Befehl vollständig ausgeführt ist.
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce" /v "!%TaskName%" /t REG_SZ /d "\"%ScriptPath%\"" /f  

:Computer herunterfahren und neustarten (/t 0 = sofortiges Herunterfahren)
shutdown /r /t 0 /d p:0:0 /c "Der Computer wird neugestartet"  

echo.
echo Fals der Computer-Neustart aus irgendwelchen Gründen doch nicht erfolgen wird, dann wird der BitLocker-Schutz für das Systemlaufwerk in 60 Sekunden wieder fortgesetzt.
timeout /t 60
manage-bde -protectors -enable %SystemDrive%
timeout /t 3 >nul

:pause >nul