Batch Script zum Verschieben von Dateien mit bestimmten Namen erstellen - Anfang der Dateinamen mit Ordnernamen vergleichen (Leerzeichen, Sonderzeichen, unterschiedliche Dateinamenlänge)

Hallo,

ich benötige dringend eure Hife bei der Lösung eines Problems. Meine eigenen Versuche verliefen leider größtenteils erfolglos. Ich konnte zwar ein Scipt erstellen, aber es funktioniert nur, wenn die Dateinamen und der Name vom Zielordner 100% übereinstimmen und nicht wie gewünscht, wenn der Dateiname nur mit dem Ordnernamen beginnen.

Ich habe versucht eine Batchdatei (s.u.) zu erstellen, die Dateien aus einem Quellordner in verschiedene Zielordner auf unterschiedlichen Festplatten nach bestimmten Kriterien sortieren und verschieben soll. Am einfachsten kann man es mit den Filterregeln eines Mailprogamms vergleichen.

Alle Dateien eines Ordners sollen in die jeweils zur Datei gehörenden Ordner auf verschiedenen Festplatten verschoben werden. Die Dateinamen beginnen jeweils mit dem Namen des Zielordners und dann folgen völlig willkürliche alphanummerische Zeichen mit immer unterschiedlichen Längen. Die Namen der Zielordner enthalten Umlaute, Leerzeichen und Sonderzeichen und sie sind immer länger als 1 Zeichen.
In den Zielordnern können bereits Dateien mit dem gleichen Namen vorhanden sein. Wenn das der Fall ist, soll die Datei nicht in den eigentlichen Zielordner, sondern in den Ordner "Bearbeiten" im Rootverzeichnis des Quellordners veschoben werden, zur späteren manuellen Bearbeitung. Auf den Festplatten mit den Zielordnern sind Ordner, deren Name nur aus 1 Buchstaben besteht. Diese "Register"-Verzeichnisse dienen nur der Unterteilung der Ordner und sind keine Zielordner.

Nachdem meine eigenen Bemühungen und auch meine Suche im Internet und diesem Forum leider erfolglos waren, habe ich versucht, das Script in einzelne Aufgaben aufzubrechen.

1. Ein Script zur Ermittlung der Verzeichnisnamen
Ich habe ein Script erstellt, welches alle Namen der Unterordner (Zielordner) einer Festplatte in eine Logdatei schreibt.
Das Erstellen der Logdatei funktioniert, zumindest für 1 Festplatte. Leider enthält sie auch die "Register"-Ordern. Die krieg ich da nicht raus. Ich weiß nicht, wie. Hatte nach einem Befehl gesucht, der nur Ordnernamen mit mindestens 2 Zeichen Länge in die Logdatei schreibt. Im Internet steht, für die Ermittlung der Ordnernamenlänge wird ein eigenes, sehr aufwändiges Script dafür benötigt. Das war für mich zu kompliziert und den Aufwand nicht wert.

2. Vergleiche Dateinamen mit Ordnernamen aus Logdatei
Dann wollte ich mithilfe einer For-Schleife die Dateinamen mit den Name aus der Logdatei vergleichen. Zeile für Zeile. Bei Gleichheit soll die Datei in den Zielordner verschoben werden.
Ich habe es geschafft ein Script (s.u.) zu schreiben, welches die Ordnernamen aus der Logdatei mit den Dateinamen aus dem Quellordner vergleicht und bei Gleichheit die Dateien in die jeweiligen Zielordner mit gleichem Namen verschiebt. Soweit, so gut.

Mein eigentliches Problem ist jetzt, die Dateinamen sind nicht 100% identisch mit den Ordnernamen, sondern sie beginnen nur mit dem Ordnernamen!! Und genau dafür finde ich kein Script! Ich bekomme es einfach nicht hin!

Ich stelle das einmal zur besseren Verdeutlichung grafisch da.

Vorher:
c:\Test\Bearbeiten\
c:\Test\verzeichnis1
474 - Ü l452.txt
titel 1_543236.txt
titel#4 rh323.txt
titel7.txt

c:\Test\verzeichnis-xyz\
c:\Test\verzeichnis-xyz\0-1\
c:\Test\verzeichnis-xyz\474 - Ü\
c:\Test\verzeichnis-xyz\A\
c:\Test\verzeichnis-xyz\B\
c:\Test\verzeichnis-xyz\C\
...
c:\Test\verzeichnis-xyz\T\
c:\Test\verzeichnis-xyz\titel 1_54\
c:\Test\verzeichnis-xyz\titel#4 r\
c:\Test\verzeichnis-xyz\titel2\
c:\Test\verzeichnis-xyz\U\
...

Nach dem Sortieren:
c:\Bearbeiten\
titel7.txt
c:\Test\verzeichnis1\
c:\Test\verzeichnis-xyz\
c:\Test\verzeichnis-xyz\0-1\
c:\Test\verzeichnis-xyz\474 - Ü\
474 - Ü l452.txt
c:\Test\verzeichnis-xyz\A\
c:\Test\verzeichnis-xyz\B\
c:\Test\verzeichnis-xyz\C\
...
c:\Test\verzeichnis-xyz\T\
c:\Test\verzeichnis-xyz\titel 1_54\
titel 1_543236.txt
c:\Test\verzeichnis-xyz\titel#4 r\
titel#4 rh323.txt
c:\Test\verzeichnis-xyz\U\
...

Hier mein Script:

Kann mir bitte einer von den erfahrenen Profis hier bei meinem Problem helfen?

Danke!

Gruß,
Sully16

@echo off & setlocal

rem ****** Konfigurationsabschnitt ******
set "SrcFolder=C:\Test\verzeichnis1"  
set "DstFolder=C:\Test\verzeichnis-xyz"  
set "EditFolder=C:\Test\Bearbeiten"  
rem *************************************

rem Alle Verzeichnisse im Zielverzeichnis auflisten
for /d %%d in ("%DstFolder%\*.*") do (  
  rem Alle Dateien im Quellverzeichnis auflisten und ihre Namen durch
  rem einen Suchfilter laufen lassen, der alle Dateinamen liefert, die
  rem mit dem Namen des aktuellen Verzeichnisses beginnen
  for /f "delims=" %%f in ('dir /b /a:-d "%SrcFolder%" 2^>NUL ^| findstr /ibr /c:"%%~nxd.*"') do (  
    rem Aus dem Namen des aktuellen Verzeichnisses und dem Namen der aktuellen
    rem Quelldatei den vollständigen Zielpfad erzeugen und prüfen, ob die Datei
    rem bereits vorhanden ist
    if not exist "%%d\%%~nxf" (  
      rem Wenn nicht, wird sie in das Verzeichnis verschoben
      echo move "%SrcFolder%\%%~nxf" "%%d" > NUL  
    ) else (
      rem Wenn ja, wird sie in das Bearbeiten-Verzeichnis verschoben
      echo move "%SrcFolder%\%%~nxf" "%EditFolder%" > NUL  
    )
  )
)

rem Alle übrig gebliebenen Dateien ins Bearbeiten-Verzeichnis verschieben
echo move "%SrcFolder%\*.*" "%EditFolder%" > NUL  

@echo on & setlocal 

REM Ich wollte sehen, was passiert

DATE /T >> M:\Bearbeiten\friemler.log
TIME /T >> M:\Bearbeiten\friemler.log


rem ****** Konfigurationsabschnitt ****** 
set "SrcFolder=M:\_ Quelle _"   
set "DstFolder=H:\- TEST - 01-A-Dem\Ordner\Zielordner"   
set "EditFolder=M:\Bearbeiten"   

rem ************************************* 


rem Alle Verzeichnisse im Zielverzeichnis auflisten 
rem
  for /d %%d in ("%DstFolder%\*.*") do (   
rem
  rem Alle Dateien im Quellverzeichnis auflisten und ihre Namen durch 
  rem einen Suchfilter laufen lassen, der alle Dateinamen liefert, die 
  rem mit dem Namen des aktuellen Verzeichnisses beginnen 
rem
  for /f "delims=" %%f in ('dir /b /a:-d "%SrcFolder%" 2^>NUL ^| findstr /ibr /c:"%%~nxd.*"') do (   
rem
    rem Aus dem Namen des aktuellen Verzeichnisses und dem Namen der aktuellen 
    rem Quelldatei den vollständigen Zielpfad erzeugen und prüfen, 
    rem ob die Datei bereits vorhanden ist 
rem
    if not exist "%%d\%%~nxf" (  
rem
      rem Wenn nicht, wird sie in das Verzeichnis verschoben 
rem
      move "%SrcFolder%\%%~nxf" "%%d" > NUL >> M:\friemler.log  
    ) else ( 
rem
      rem Wenn ja, wird sie in das Bearbeiten-Verzeichnis verschoben 
rem
      move "%SrcFolder%\%%~nxf" "%EditFolder%" > NUL >> M:\friemler.log  
    ) 
  ) 
) 

rem
rem Alle übrig gebliebenen Dateien ins Bearbeiten-Verzeichnis verschieben 
rem
move "%SrcFolder%\*.*" "%EditFolder%" > NUL >> M:\friemler.log  
rem

pause

findstr /ibr /c:"%%~nxd.*"

findstr /ib /c:"%%~nxd"

C:\Windows\system32>(
rem 
 rem Aus dem Namen des aktuellen Verzeichnisses und dem Namen der aktuellen   
 rem Quelldatei den vollständigen Zielpfad erzeugen und prüfen,   
 rem ob die Datei bereits vorhanden ist   
 rem 
 if not exist "H:\- TEST - 01-A-Dem\Ordner\Zielordner\C\C - ”ffentlich#_8763_.txt" (  
rem 
 rem Wenn nicht, wird sie in das Verzeichnis verschoben   
 rem 
 move "M:\_ Quelle _\C - ”ffentlich#_8763_.txt" "H:\- TEST - 01-A-Dem\Ordner\Zielordner\C"   1>NUL   
)  else (
rem 
 rem Wenn ja, wird sie in das Bearbeiten-Verzeichnis verschoben   
 rem 
 move "M:\_ Quelle _\C - ”ffentlich#_8763_.txt" "M:\Bearbeiten"   1>NUL   
) 
) 

C:\Windows\system32>(
rem 
 rem Alle Dateien im Quellverzeichnis auflisten und ihre Namen durch   
 rem einen Suchfilter laufen lassen, der alle Dateinamen liefert, die   
 rem mit dem Namen des aktuellen Verzeichnisses beginnen   
 rem 
 for /F "delims=" %f in ('dir /b /a:-d "M:\_ Quelle _" 2>NUL | findstr /ibr /c:"C - ”ffentlich#.*"') do (  
rem 
 rem Aus dem Namen des aktuellen Verzeichnisses und dem Namen der aktuellen   
 rem Quelldatei den vollständigen Zielpfad erzeugen und prüfen,   
 rem ob die Datei bereits vorhanden ist   
 rem 
 if not exist "H:\- TEST - 01-A-Dem\Ordner\Zielordner\C - ”ffentlich#\%~nxf" (  
rem 
 rem Wenn nicht, wird sie in das Verzeichnis verschoben   
 rem 
 move "M:\_ Quelle _\%~nxf" "H:\- TEST - 01-A-Dem\Ordner\Zielordner\C - ”ffentlich#"   1>NUL   
)  else (
rem 
 rem Wenn ja, wird sie in das Bearbeiten-Verzeichnis verschoben   
 rem 
 move "M:\_ Quelle _\%~nxf" "M:\Bearbeiten"   1>NUL   
) 
) 
) 

type M:\Bearbeiten\friemler.log

dir /o:gne

@echo off & setlocal

rem ****** Konfigurationsabschnitt ******
set "SrcFolder=C:\Test\verzeichnis1"  
set "DstFolder=C:\Test\verzeichnis-xyz"  
set "EditFolder=C:\Test\Bearbeiten"  
rem *************************************

rem Alle Verzeichnisse im Zielverzeichnis auflisten,
rem deren Name mindestens 2 Zeichen lang ist
for /f "delims=" %%d in ('dir /b /a:d "%DstFolder%" 2^>NUL ^| findstr /ibr /c:"...*"') do (  
  rem Alle Dateien im Quellverzeichnis auflisten und ihre Namen durch
  rem einen Suchfilter laufen lassen, der alle Dateinamen liefert, die
  rem mit dem Namen des aktuellen Verzeichnisses beginnen
  for /f "delims=" %%f in ('dir /b /a:-d "%SrcFolder%" 2^>NUL ^| findstr /ib /c:"%%d"') do (  
    rem Aus dem Namen des aktuellen Verzeichnisses und dem Namen der aktuellen
    rem Quelldatei den vollständigen Zielpfad erzeugen und prüfen, ob die Datei
    rem bereits vorhanden ist
    if not exist "%DstFolder%\%%d\%%f" (  
      rem Wenn nicht, wird sie in das Verzeichnis verschoben
      move "%SrcFolder%\%%f" "%DstFolder%\%%d" > NUL  
    ) else (
      rem Wenn ja, wird sie in das Bearbeiten-Verzeichnis verschoben
      move "%SrcFolder%\%%f" "%EditFolder%" > NUL  
    )
  )
)

rem Alle übrig gebliebenen Dateien ins Bearbeiten-Verzeichnis verschieben
move "%SrcFolder%\*.*" "%EditFolder%" > NUL  

findstr /?