batchdatein nach logonserver

Hallo zusammen,

ich habe folgendes Problem:

1 AD X Standorte

ich möchte wenn sich Person A an Standort 1 anmeldet das Laufert LW1 gemappt bekommt und wenn sie sich am Standort 2 anmeldet Laufwerk LW2 +3 bekommt. Hat da jemand eine IDee für eine Batch?

Meine Idee war:

if %logonserver% == \\server2 goto Standort2

:Standort2
net use y: \\10.185.0.1\daten2
cscript "%logonserver%\netlogon\umbenennen.vbs" y "Standort2"

if %logonserver% == \\server1 goto Standort1

:Standort1
net use m: \\10.181.0.10\daten1
cscript "%logonserver%\netlogon\umbenennen.vbs" m "Standort1"

net use r: \\10.181.0.20\daten11
cscript "%logonserver%\netlogon\umbenennen.vbs" r "Daten1"

es wird momentan immer das komplette script ausgeführt, was es aber nicht soll.... Jemand eine Idee?

Gruß

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 103254

Url: https://administrator.de/forum/batchdatein-nach-logonserver-103254.html

Ausgedruckt am: 03.04.2025 um 13:04 Uhr

1 Kommentar

Hallo joerg!

Da vor ":Standort1" kein "goto :eof" aufscheint, wird nach dem Durchlaufen des Teiles ":Standort2" einfach weiter gemacht (wobei das jeweilige "if" ja ohnehin witzlos ist, da auch ohne Sprung die nächste Zeile, also ":Standort2" bzw später ":Standort1", erreicht wird) ...

... daher entweder:

if "%logonserver%"=="\\server1" goto Standort1  
if "%logonserver%" neq "\\server2" rem auch nicht Standort2: Was dann - Sprung zu einer Fehlerbehandlung oder gleich "goto :eof"?  
net use y: \\10.185.0.1\daten2
cscript "%logonserver%\netlogon\umbenennen.vbs" y "Standort2"  
goto :eof

:Standort1
net use m: \\10.181.0.10\daten1
cscript "%logonserver%\netlogon\umbenennen.vbs" m "Standort1"  

net use r: \\10.181.0.20\daten11
cscript "%logonserver%\netlogon\umbenennen.vbs" r "Daten1"  

oder:

if "%logonserver%"=="\\server2" (  
    net use y: \\10.185.0.1\daten2
    cscript "%logonserver%\netlogon\umbenennen.vbs" y "Standort2"  
) else (
    if "%logonserver%"=="\\server1" (  
        net use m: \\10.181.0.10\daten1
        cscript "%logonserver%\netlogon\umbenennen.vbs" m "Standort1"  
        net use r: \\10.181.0.20\daten11
        cscript "%logonserver%\netlogon\umbenennen.vbs" r "Daten1"  
    ) else (
        rem weder Standort 1 noch Standort 2 erkannt ...
    )
)