Batchfile FOR

@echo off &setlocal

:: Settings
set "ini=Sicherung.ini"  
set "section=Ordner"  

:: Werte lesen
set "key=Musik"  
call :readINI
echo %foundKey% - %foundVal%

set "key=Video"  
call :readINI
echo %foundKey% - %foundVal%

pause
goto :eof

:::::::::::::::::::::::::::::::::::::::::

:readINI
for /l %%i in (1 1 4) do set "n%%i="  
set "line="&set "foundKey="&set "foundVal="  

:: existiert die Datei?
if not exist "%ini%" echo [error] &goto :eof  

:: wie viele Zeilen hat die Datei?
for /f %%i in ('type "%ini%"^|find /c /v ""') do set /a n1=%%i  
if not defined n1 echo [error] &goto :eof

:: in welcher Zeile fängt die Sektion an?
for /f "delims=:" %%i in ('type "%ini%"^|findstr /nbc:"[%section%]"') do if not defined n2 set /a n2=%%i  
if not defined n2 echo [error] &goto :eof

:: wo findet sich die nächste Sektion?
for /f "delims=:" %%i in ('^<"%ini%" more +%n2%^|findstr /rnbc:"\[..*\]"') do if not defined n3 set /a n3=%%i  
if not defined n3 set /a n3=n1-n2

:: wo findet sich der Schlüssel?
for /f "delims=:" %%i in ('^<"%ini%" more +%n2%^|findstr /nbc:"%key%="') do (  
  if not defined n4 (
    if %%i leq %n3% set /a n4=%%i+n2
  )
)
if not defined n4 echo [error] &goto :eof

:: über die INI iterieren
<"%ini%" (  
  for /l %%i in (1 1 %n4%) do (
    set /p "line="  
    )
  )
)
for /f "tokens=1* delims==" %%i in ("%line%") do (set "foundKey=%%i"&set "foundVal=%%j")  
goto :eof