Csv Datei Tonerwerte prüfen und unter 30 Prozent Emailmeldung

Toner = "D:\Toner.csv"  
Bestellt = "D:\Bestellt.txt"  
Bestellen = 30 'Grenzwert für Nachbestellung  
Geliefert = 90 'Grenzwert für "wieder da"  

Set fso = CreateObject("Scripting.FileSystemObject")  
T = Split(fso.OpenTextFile(Toner).ReadAll, vbCrLf) 'Toner-Datei einlesen und zeilenweise in Array schreiben  

Header = Split(T(0), ",") 'Spaltenüberschriften (Toner-Bezeichnung) einlesen  

If fso.FileExists(Bestellt) Then 'Wenn Bestelllisten-Datei vorhanden, ...  
    Set Best = fso.OpenTextFile(Bestellt, 1, True)
    If Not Best.AtEndOfStream Then B = Best.ReadAll  '... gesamte Bestellliste aus Datei lesen  
    Best.Close
End If    
If B = "" Then B = vbCrLf 'Formatierung für Vergleich anpassen  

Mail = "" 'Variable für Mailtext  

For i = 1 To UBound(T) 'alle Druckerdatensätze (= ab Zeile 2 der .csv) durchgehen  
    PrinterData = Split(T(i), ",") 'Datensatz des Druckers in Felder zerlegen  
    Info = PrinterData(0) & "," & PrinterData(1) 'Drucker-Daten ("Device" und "Serial") in Variable schreiben  

    For j = 3 To 6 'Felder mit Toner-Info durchgehen  
        If InStr(PrinterData(j), "%") > 0 Then 'Prozentsatz vorhanden?  

            Wert = CInt(Replace(Replace(PrinterData(j), "%", ""), """", "")) 'Prozentwert als Zahl ermitteln  
            TonerDaten = Info & "," & Header(j) 'Daten für Toner zusammenstellen (Drucker-Daten + Toner-Name lt Spaltenüberschrift)  

            If Wert < Bestellen And InStr(B, TonerDaten) = 0 Then 'Grenzwert unterschritten und noch nicht in Liste?  
                Mail = Mail & vbCrLf & TonerDaten 'in Mailtext ...  
                B = B & vbCrLf & TonerDaten '... und Bestellliste aufnehmen  
            End If

            If Wert > Geliefert Then 'Grenzwert für "wieder da" überschritten?  
                B = Replace(B, vbCrLf & TonerDaten, "") 'aus Bestellliste entfernen  
            End If

        End If
    Next 'Feld  

Next 'Satz  

fso.CreateTextFile(Bestellt).Write B 'Bestellliste in Datei schreiben  

If Mail <> "" Then  
    WScript.Echo "Mail mit Inhalt:" & vbCrLf & vbCrLf & Mail & vbCrLf & vbCrLf & "versenden!"  
End If