Nero 8 Softwareverteilung über gpo

@Echo Off
::
:: Silent Installation Batch File V1.13
:: Last Updated 29.02.2008
::
::
::==========================================================================================================================
:: Make your settings here
:: Use %~dp0<fileName> for files in the same folder as this batch file
::==========================================================================================================================

:: Install provided DirectX, possible values: true, false
set installDirectX=true

:: (optional) provide your serial number here
set serialNumber=none

:: (optional, volume license only) provide the path to an exported BurnRights registry file 
set neroBurnRightsRegFile=none

:: Provide the path to the installation files
set neroExeFilePath=none

:: Provide the destination path for the installation. Using "default" will install to the default location.  
set NeroDestinationPath=default

:: Provide your custom parameters used for the installation
set customParameters=/qb! ADDLOCAL="ALL"  

:: (optional) modify burn rights, possible values: /admin, /all, "/group={group name}"  
set neroBurnRightsUsers=none

::==========================================================================================================================

:: Path the contents of the exe is extracted to and then used for installation
set N7InstallationPath=%Temp%\Nero_ExtractedFiles

::==========================================================================================================================

cls
echo Nero unattended installation
echo ----------------------------

:: Prompt for missing information
:: ------------------------------

if "%neroExeFilePath%" == "none" (  
    echo Please provide the path to the Nero archive exe!
    Pause
    Exit /B 1
)

if "%serialNumber%" == "none" (  
    set serialNumParam= 
) else (
    set serialNumParam=SERIALNUMBER=%serialNumber%
)

:: Extraction process
:: ------------------

echo Extracting Nero archive to local folder... [step 1 of 3]
:: Extract demo files
if exist "%N7InstallationPath%" (  
    rmdir /S /Q "%N7InstallationPath%"  
)
mkdir "%N7InstallationPath%"  
"%~dp07za.exe" x -y "%neroExeFilePath%" -o"%N7InstallationPath%"  

:: Prepare information needed for installation
:: -------------------------------------------

 if exist "%N7InstallationPath%\Installation" (  
    set N7InstallationPath=%N7InstallationPath%\Installation
)

:: Check Location of the DirectX Installer
::----------------------------------------

if exist "%N7InstallationPath%\Redist\DirectX" (  
	set NeroDirectXLocation=%N7InstallationPath%\Redist\DirectX
) else if exist "%N7InstallationPath%\data\Redist\DirectX" (  
	set NeroDirectXLocation=%N7InstallationPath%\Data\Redist\DirectX
) else (
	set installDirectX=false
)

cls
echo Nero unattended installation
echo ----------------------------
echo Extracting Nero archive to local folder... [step 1 of 3]

:: Installation process
:: --------------------

echo Installing Nero... [step 2 of 3]

if "%installDirectX%" == "true" (  
    echo Installing DirectX... [substep]
    "%NeroDirectXLocation%\dxsetup.exe" /silent  
    echo Installing Nero... [substep]
)

:: Optionally import customised NeroBurnRights' registry settings here  
if not "%neroBurnRightsRegFile%" == "none" (  
    regedit /s "%neroBurnRightsRegFile%"  
)

:: Install Nero silently
if not "%NeroDestinationPath%" == "default" (  
	"%N7InstallationPath%\SetupX.exe" %customParameters% %serialNumParam% TARGETPATH="%NeroDestinationPath%"  
) else (
	"%N7InstallationPath%\SetupX.exe" %customParameters% %serialNumParam%  
)

:: Set up users that may burn using Nero (Win2k/XP only)
if not "%neroBurnRightsUsers%" == "none" (  
    if not "%NeroDestinationPath%" == "default" (  
        if exist "%NeroDestinationPath%\Nero\Nero 7\Nero Toolkit\NeroBurnRights.exe" (  
    	    "%NeroDestinationPath%\Nero\Nero 7\Nero Toolkit\NeroBurnRights.exe" %neroBurnRightsUsers%  
)       else if exist "%NeroDestinationPath%\Nero\Nero8\Nero Toolkit\NeroBurnRights.exe" (  
	    "%NeroDestinationPath%\Nero\Nero8\Nero Toolkit\NeroBurnRights.exe" %neroBurnRightsUsers%  
)
)   else (
	if exist "%programfiles%\Nero\Nero 7\Nero Toolkit\NeroBurnRights.exe" (  
    	    "%programfiles%\Nero\Nero 7\Nero Toolkit\NeroBurnRights.exe" %neroBurnRightsUsers%  
)       else if exist "%programfiles%\Nero\Nero8\Nero Toolkit\NeroBurnRights.exe" (  
	    "%programfiles%\Nero\Nero8\Nero Toolkit\NeroBurnRights.exe" %neroBurnRightsUsers%  
)
)
)

:: Removal of temporary files
:: --------------------------

echo Removing temporary files... [step 3 of 3]
:: Remove temporary files after installation
rmdir /S /Q "%N7InstallationPath%"  

if %ERRORLEVEL% == 0 (
    echo Installation finished successfully
) else if %ERRORLEVEL% == 1 (
    echo Installation failed with error code 1
) else if %ERRORLEVEL% == 2 (
    echo Installation failed with error code 2
) else if %ERRORLEVEL% == 3 (
    echo Installation failed with error code 3
) else if %ERRORLEVEL% == 3010 (
    echo Setup was executed successfully, please reboot to finish the installation
) else (
    echo Installation failed with error code %ERRORLEVEL%
)

:: PAUSE