searchbox
Goto Top

Outlook Emails nach dem lesen automatisch in bestimmte Ordner sortieren

Hallo Admins,

ich suche schon länger nach einer Möglichkeit Emails nach dem Lesen automatisch in bestimmte Odner zu sortieren.

zum Beispiel ein Newsletter von Mercedes: ich habe einen Ordner Newsletter worin sich ein erneuter Odner befindet mit dem Namen Mercedes. Ich lese mir den Artikel durch, und klicke dann auf die Nächste mail, während die eben gelsene Mail in den dafür vorgesehenen Ordner gelegt wird.

Könnt ihr mir erkären wie dies Funktioniert ?
Ich habe bis jetzt noch nicht wirklich was gefunden, zwar Sortiert Outlook E-Mails ein, jedoch sind die dann als ungelesen markiert.

Gruße
SB

Content-Key: 1644529704

Url: https://administrator.de/contentid/1644529704

Printed on: April 23, 2024 at 23:04 o'clock

Member: BirdyB
BirdyB Dec 21, 2021 at 13:32:20 (UTC)
Goto Top
Moin,

ich denke, da musst du mit VBA arbeiten und dann den Sortierprozess anstoßen.
Out-of-the-Box wäre mir da nichts bekannt.

VG
Member: SearchBox
SearchBox Dec 21, 2021 at 13:44:23 (UTC)
Goto Top
Von VBA habe ich gehört,

Werd mich damit mal beschäftigen, danke dir, vielleicht hat ja noch jemand eine Idee.

SB
Mitglied: 149569
149569 Dec 21, 2021 updated at 15:19:14 (UTC)
Goto Top
Biddö, was zum Basteln ...
Dim WithEvents exp As Explorer
Dim WithEvents cItem As MailItem
Dim WithEvents oldItem As MailItem

Private Sub Application_MAPILogonComplete()
    Set exp = ActiveExplorer
End Sub

Private Sub exp_SelectionChange()
    If exp.Selection.Count > 0 Then
        With exp.Selection.Item(1)
            If .Class = olMail Then
                Set oldItem = cItem
                Set cItem = exp.Selection.Item(1)
            End If
        End With
    End If
End Sub

Private Sub oldItem_PropertyChange(ByVal Name As String)
    If Name = "UnRead" And oldItem.UnRead = False Then  
        MoveItemToArchive oldItem
    End If
End Sub

Private Sub cItem_PropertyChange(ByVal Name As String)
    If Name = "UnRead" And cItem.UnRead = False Then  
        MoveItemToArchive cItem
    End If
End Sub

Sub MoveItemToArchive(ByVal itm As MailItem)
    On Error Resume Next
    Select Case LCase(itm.SenderEmailAddress)
        Case "werbung@mercedes-whatever.de"  
            itm.Move exp.CurrentFolder.Store.GetRootFolder.Folders("Newsletter").Folders("Mercedes")  
        Case Else
            itm.Move exp.CurrentFolder.Store.GetRootFolder.Folders("Newsletter")  
    End Select
End Sub
Member: SearchBox
SearchBox Dec 21, 2021 at 20:15:00 (UTC)
Goto Top
Hallo Haktor,

Danke für deinen Beitrag, hast du vielleicht eine gute Lektüre oder Quelle wo ich mich als Anfänger rantasten bzw. Einlesen kann?
Mitglied: 149569
149569 Dec 21, 2021 at 21:22:13 (UTC)
Goto Top
Zitat von @SearchBox:

Hallo Haktor,

Danke für deinen Beitrag, hast du vielleicht eine gute Lektüre oder Quelle wo ich mich als Anfänger rantasten bzw. Einlesen kann?

An der Quelle
https://docs.microsoft.com/de-de/office/vba/api/overview/outlook