17.09.2014

2067

Undefinierte XML mit verändertem Content mit Batch auslesen

Hallo Community,

ich möchte eine Batch erstellen, die mir die mir meine Aufgaben erleichtert.
Dazu muss ich eine bzw. mehrer XML Dateien auslesen...

Dazu gibt es immer eine Index.xml die mir die Verweise auf die nächsten benötigten xml liefert

1. Ich kenne den Namen der XML (Index.xml)
das benötigte steht immer in der 2. Zeile
<IndexFile index="ordner:andereXML.zip" version="4.10.0" />
und ich möchte nur andereXML.zip oder ordner:andereXML.zip in eine neue .txt file schreiben

2. Der Name der Xml entspricht dem was ich gerade aus der Index.xml geholt habe (andereXML.zip)
das benötigte steht hier immer in der 8. Zeile
<FileName val="ordner2:file.zip" />
und ich benötige das zwischen den ", also ordner2:file.zip

Ich würde gerne sagen wie weit ich schon bin, aber leider habe ich bisher nicht gefunden, wie man mit batch etwas aus einer xml auslesen kann....
Und bei "Java ist auch eine Insel" bin ich erst bei Kapitel 3

Bin für jede erdenkliche Hilfe dankbar

greetz

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 249472

Url: https://administrator.de/contentid/249472

Ausgedruckt am: 24.11.2024 um 23:11 Uhr

12 Kommentare

Neuester Kommentar

Hallo pascallantzsch, willkommen im Forum.

Batch ist grundsätzlich ungeeignet um XML zu verarbeiten, weil

XML in den unterschiedlichsten Zeichensätzen vorliegen kann
XML Zeilenumbrüche und Leerzeichen zwischen Knoten ignoriert (der gesamte Inhalt könnte theoretisch in einer Zeile stehen und wäre trotzdem valide)
Der Aufbau von XML sich an Knotenobjekten, Werten, Eigenschaften, CDATA Objekten etc. orientiert, Batch aber stupide zeilenweise abarbeitet.

Es ist also immer ein Lotteriespiel. Egal ...

Dein erstes Problemchen lässt sich (ungetestet) evtl. so lösen:

@echo off &setlocal
for /f skip^=1^ tokens^=2^ delims^=^" %%i in ('type "Index.xml"') do (  
  if not defined filename for /f "tokens=2 delims=:" %%j in ("%%i") do (  
    set "filename=%%j"  
    setlocal EnableDelayedExpansion
    >"neue.txt" echo !filename!  
    endlocal
  )
)

Deinen Punkt 2 verstehe ich allerdings nicht. Eine ZIP Datei ist kein XML und enthält binären Inhalt. Wo willst du da eine Zeile 8 und einem Plaintext Inhalt herholen?

Grüße
rubberman

Hallo, danke erstmal für die schnelle Antwort... Punkt 1 werde ich gleich mal testen...
Bei Punkt 2 habe ich mich etwas falsch ausgedrückt... es gibt einen zwischenschritt bei dem die zip entpackt wird und eine xml (mit dem selben namen) zum Vorschein kommt

Dass batch nicht unbedingt gut für die XML ist, habe ich schon gelesen... aber es geht trotzdem wurde mir gesagt... ich werde gleich mal deinen Code testen

Edit: der erste funktioniert einwandfrei
kann ich das noch so verändern, dass er vor dem, was er aus der xml hat eine http adresse hinzufügt?

also zum Beispiel http://meineSeite.de/ und dann die Abfrage aus der xml z.B. xmlcode1.zip
und dass es dann zusammen da steht, also http://meineSeite.de/xmlcode1.zip

es gibt einen zwischenschritt bei dem die zip entpackt wird und eine xml (mit dem selben namen) zum Vorschein kommt

OK, und welches Programm hast du installiert, mit dem du kommandozeilengesteuert die ZIP Datei auspacken kannst?

Grüße
rubberman

winrar
derzeit nutze ich für diesen schritt aber den jitbit macro recorder
aber in der kommandozeile dürfte dies ja mit

start C:\Program Files\WinRAR\WinRAR.exe x C:\Temp\macro\Index.zip *.* C:\Temp\macro\

gehen

winrar
derzeit nutze ich für diesen schritt aber den jitbit macro Recorder

Von Macrorecordern habe ich keinen Schimmer. Die winrar Zeile sollte so auch nicht funktionieren, da der Pfad Leerzeichen enthält. START (ohne /WAIT) ist auch kontraproduktiv, da asynchron gearbeitet wird. Teste:

start "" /wait "C:\Program Files\WinRAR\WinRAR.exe" x C:\Temp\macro\Index.zip *.* C:\Temp\macro\  

Für die Syntax von winrar lege ich meine Hand aber nicht ins Feuer. Hab's nicht installiert.

kann ich das noch so verändern, dass er vor dem, was er aus der xml hat eine http adresse hinzufügt?

Kann man. Schreibe sie einfach vor !filename! in die ECHO Ausgabe. Falls das aber bedeutet, dass du die Datei erst downloaden musst, ist das noch mal was ganz anderes.
Es macht wenig Sinn wenn du häppchenweise mit deinen Anforderungen kommst ...

Grüße
rubberman

Ok, danke erstmal für die Hilfe

ich wollte es so knapp wie möglich halten, soll ja nicht so rüber kommen, als würde ich mich hier anmelden und mir mein programm quasi schreiben lassen

das will ich auch nicht

hab mich jetzt an punkt 2 gewagt... erst dachte ich ich nutze !filename! um in der selben batch den herusgefundenen text als 2. dateinamen mit xml dahinter zu nehmen... hat nicht geklappt
als nächstes dachte ich, dass ich in einer 2. batch den namen aus der generierten txt irgendwie heraus nehme, herausholen klappt, aber wie setze ich das dann als dateinamen?
müsste dann ja so sein
set filename2 = !filename!
for /f skip^=1^ tokens^=2^ delims^=^" %%i in ('type "filename2.xml"') do ( usw....

soll ja nicht so rüber kommen, als würde ich mich hier anmelden und mir mein programm quasi schreiben lassen

Das finde ich völlig in Ordnung, führt aber zu Verwirrungen.
So was wie ...

1. ...
2. ...
3. ...
4. ...
Wobei ich für 2. und 3. bereits folgende Lösungen habe:
...

... würde ungemein helfen (ggf. auch Leuten mit ähnlichen Problemen).

@echo off &setlocal
for /f skip^=1^ tokens^=2^ delims^=^" %%i in ('type "Index.xml"') do (  
  if not defined filename1 for /f "tokens=2 delims=:" %%j in ("%%i") do (  
    set "filename1=%%j"  
    set "basename1=%%~nj"  
    setlocal EnableDelayedExpansion
    >"neue1.txt" echo  http://meineSeite.de/!filename1!  
    endlocal
  )
)

:: download, winrar etc.

for /f skip^=7^ tokens^=2^ delims^=^" %%i in ('type "C:\Temp\macro\%basename1%.xml"') do (  
  if not defined filename2 for /f "tokens=2 delims=:" %%j in ("%%i") do (  
    set "filename2=%%j"  
    set "basename2=%%~nj"  
    setlocal EnableDelayedExpansion
    >"neue2.txt" echo !filename2!  
    endlocal
  )
)

:: Testausgabe
echo "%basename1%"  
echo "%basename2%  
pause

So oder ähnlich (wieder ungetestet) ...

Grüße
rubberman

EDIT %basename% zu %basename1% in Zeile 14

Super, hat mit nen paar Änderungen und dem hinzufügen einer 3. Sache, damit ich noch das vor dem Doopelpunkt aus 2 bekomme geklappt... hier nochmal der Code

@echo off &setlocal
for /f skip^=1^ tokens^=2^ delims^=^" %%i in ('type "Index.xml"') do (
if not defined filename1 for /f "tokens=2 delims=:" %%j in ("%%i") do (
set "filename1=%%j"
set "basename1=%%~nj"
setlocal EnableDelayedExpansion
>"neue1.txt" echo !filename1!
endlocal
)
)
:: download, winrar etc.
for /f skip^=7^ tokens^=2^ delims^=^" %%i in ('type "%basename1%.xml"') do (
if not defined filename2 for /f "tokens=2 delims=:" %%j in ("%%i") do (
set "filename2=%%j"
set "basename2=%%~nj"
setlocal EnableDelayedExpansion
>"neue2.txt" echo !filename2!
endlocal
)
)
for /f skip^=7^ tokens^=2^ delims^=^" %%i in ('type "%basename1%.xml"') do (
if not defined filename3 for /f "tokens=1 delims=:" %%j in ("%%i") do (
set "filename3=%%j"
set "basename3=%%~nj"
setlocal EnableDelayedExpansion
>"neue3.txt" echo !filename3!
endlocal
)
)
:: Testausgabe
echo "%basename1%"
echo "%basename2%"
echo "%basename3%"
pause

Das kannst du abkürzen.

for /f skip^=7^ tokens^=2^ delims^=^" %%i in ('type "%basename1%.xml"') do (  
  if not defined filename2 (
    set "property2=%%i"  
    for /f "tokens=1,2 delims=:" %%j in ("%%i") do (  
      set "folder2=%%j"  
      set "filename2=%%k"  
      set "basename2=%%~nk"  
      REM * Für den Test auskommentiert: *
      REM setlocal EnableDelayedExpansion
      REM >"neue2.txt" echo !filename2!  
      REM endlocal
    )
  )
)

echo "%property2%"  
echo "%folder2%"  
echo "%filename2%"  
echo "%basename2%"  

Je nachdem, was du tatsächlich benötigst, kannst du ggf. noch weiter einkürzen.

Grüße
rubberman

Batch ist grundsätzlich ungeeignet um XML zu verarbeiten, weil

Hey,
@rubberman grundsätzlich hast du natürlich recht, aber...

häufig kann xml ganz gut gebatcht werden. Die Struktur muss exakt eingehalten werden (wie immer bei Batch), 1-Byte-Zeichencodierung (ANSI), zeilenorientierte Fragestellung. Dann geht sogar Regex, obwohl das ja quasi verboten ist. Manchmal helfen die xmlStarlet Tools weiter.
Gruss, Endoro

Hi Endoro.

Zitat von @Endoro:
@rubberman grundsätzlich hast du natürlich recht, aber...

häufig kann xml ganz gut gebatcht werden. Die Struktur muss exakt eingehalten werden (wie immer bei Batch), 1-Byte-Zeichencodierung (ANSI), zeilenorientierte Fragestellung.

Joa, wenn oben nicht etwas wie "immer in der X. Zeile" gestanden hätte, hätte ich auch nicht mit Batch gestartet, sondern (wie üblich) gleich auf das XML DOM verwiesen. Für/gegen unterschiedliche Zeichensätze hilft TYPE auch schon mal aus dem gröbsten heraus.

Dann geht sogar Regex, obwohl das ja quasi verboten ist.

LOL That would have been a link for the "Humor" forum as well

Manchmal helfen die xmlStarlet Tools weiter.

Kannte ich noch nicht. Danke! Persönlich halte ich es dann aber doch lieber mit dem WSH (weil es ohne 3rd Party Tools auskommt).

Grüße
rubberman