Variablen Text einfügen

Hallo zusammen,

ich hab ein Makro, welches automatisch eine E-MAil verschickt nachdem man in einer Message Box einen Text eingegeben hat. Dieser Text soll nicht an einer beliebigen Stelle ausgegeben werden sondern

in dem Bereich zwischen >>>> <<<< nach Möglichkeit dann auch Fett und unterstrichen

Sub SMSmatalarm()

'Makro zum starten einer SMS - Email Materialalarm

Dim strSupportEMail As Variant

' SMS und E-Mail Adresse werden gesendet an:
' SMS ensteht wenn man Handynummer@t-mobile-sms.de schreibt

' Alexander, Test2, Test3
strSupportEMail = Array("alexander@test.de")
VariableMailtext = InputBox("Hier kurz angeben was fehlt und wie dringend" & Chr(13) & "Sachnummer Material")

Dim notesdb As Object
Dim notesdoc As Object
Dim notesrtf As Object
Dim notessession As Object
Set notessession = CreateObject("Notes.Notessession")
Set notesdb = notessession.getdatabase("", "")
Call notesdb.openmail

' Mail erstellen
Set notesdoc = notesdb.createdocument
Call notesdoc.replaceitemvalue("Sendto", strSupportEMail)

' Betreffzeile
Call notesdoc.replaceitemvalue("Subject", "Es Fehlt ein Teil aus dem Regal")

Set notesrtf = notesdoc.createrichtextitem("body")

' Info Text
Call notesrtf.appendtext("Es Fehlt im Berreich Test folgendes Teil: >>>> <<<<. ( Bei Rückfragen Tel. )")
Call notesrtf.addnewline(2)
Call notesrtf.appendtext(VariableMailtext)

Call notesrtf.addnewline(2)

' Mail senden und Hinweis
Call notesdoc.Send(False)
Set notessession = Nothing
MsgBox "Das Team Material Team wurde informiert"

End Sub

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 230402

Url: https://administrator.de/forum/variablen-text-einfuegen-230402.html

Ausgedruckt am: 23.12.2024 um 18:12 Uhr

14 Kommentare

Neuester Kommentar

Hallo TheFalcon,
mit Notes habe ich schon ewig nicht mehr hantiert, aber da es VB ist sollte die Abänderung des folgenden Abschnitts den gewünschten Erfolg bringen:

' Info Text  
Call notesrtf.appendtext("Es Fehlt im Bereich Test folgendes Teil: >>>>" & VariableMailtext & "<<<<. ( Bei Rückfragen Tel. )")  

Im Zusammenhang dann also so:

Sub SMSmatalarm()

  'Makro zum starten einer SMS - Email Materialalarm  
  Dim strSupportEMail As Variant

  ' SMS und E-Mail Adresse werden gesendet an:  
  ' SMS ensteht wenn man Handynummer@t-mobile-sms.de schreibt  

  ' Alexander, Test2, Test3  
  strSupportEMail = Array("alexander@test.de")  
  VariableMailtext = InputBox("Hier kurz angeben was fehlt und wie dringend" & Chr(13) & "Sachnummer Material")  

  Dim notesdb As Object
  Dim notesdoc As Object
  Dim notesrtf As Object
  Dim notessession As Object
  Set notessession = CreateObject("Notes.Notessession")  
  Set notesdb = notessession.getdatabase("", "")  
  Call notesdb.openmail

  ' Mail erstellen  
  Set notesdoc = notesdb.createdocument
  Call notesdoc.replaceitemvalue("Sendto", strSupportEMail)  

  ' Betreffzeile  
  Call notesdoc.replaceitemvalue("Subject", "Es Fehlt ein Teil aus dem Regal")  

  Set notesrtf = notesdoc.createrichtextitem("body")  

  ' Info Text  
  Call notesrtf.appendtext("Es Fehlt im Bereich Test folgendes Teil: >>>>" & VariableMailtext & "<<<<. ( Bei Rückfragen Tel. )")  

  ' Mail senden und Hinweis  
  Call notesdoc.Send(False)
  Set notessession = Nothing
  MsgBox "Das Team Material Team wurde informiert"  
End Sub

Grüße Uwe

Das klingt schon mal sehr gut! Danke Uwe, mal etwas anderes es wurde noch der Wunsch geäußert eine Auswahlmöglichkeit zu machen zum Beispiel man gibt erst den Text ein und kann dann noch drei Haken setzen. Die dann je nachdem welcher Haken gesetzt ist, dort mit eingefügt wird.

Haken 1 Beispiel Fahrrad
Haken 2 Routenzug
Haken 3 Direkt

Gruss

Alexander

habe hier leider kein Notes mehr ... deshalb kenne ich die Möglichkeiten dort nicht. Normalerweise müsste man dafür eine extra Form erstellen...

Im Prinzip erfordert das ja nicht direkt Notes. Ich muss nur irgendwie ein anderes Auswahl Fenster erstellen. Gibt es da nicht auch einen Befehl für?

Ach so, das ist ja ein VBS-Script, sorry. Dachte das Ding läuft in Notes selber ...
Oberflächen kannst du mit VBS nicht erstellen. Was du machen könntest wäre eine MsgBox mit Ja/Nein Abfragen...
Oder eine zusätzliche InputBox mit dem Eintragen einer Nummer die für den enstprechenden Text steht

Oder direkt Powershell oder AutoIT nutzen, damit steht einem das ganze Areal an Forms zur Verfügung...

Grüße Uwe

Beispiel:

strText = ""  
auswahl = InputBox("Geben Sie die Nummer entsprechende Nummer an: " & vbNewLine & "[1] Beispiel Fahrrad / [2] Routenzug / [3] Direkt","Auswahl","1")  
Select Case auswahl
	Case 1
		strText = "Beispiel Fahrrad"  
	Case 2
		strText = "Routenzug"  
	Case 3
		strText = "Direkt"  
End Select
msgbox strText

Gibt es keine Möglichkeit wo ich dann nen Haken setzen könnte bei der MsgBox?

Zitat von @TheFalcon:
Gibt es keine Möglichkeit wo ich dann nen Haken setzen könnte bei der MsgBox?

Nein Häkchen gibts nicht ....

Ok, Danke ich werd mal schauen was ich mir so basteln werde, auf jeden Fall wurde mir schon mal geholfen. TOP

Was du noch machen könntest wäre eine HTA-Datei zu erstellen, damit kann man Oberflächen mit HTML zusammenbauen und dein Script dort einbauen. Ich mach dir dazu später mal ein Beispiel...

Grüße Uwe

So, den folgenden Code in eine Textdatei kopieren und die Endung in .HTA umbenennen:
Sieht dann so aus:

Zum Ausführen dann einfach Doppelklick auf die Datei.

<html>
<head>
<title>Material-Alarm</title>
<HTA:APPLICATION
  APPLICATIONNAME="Dialog"  
  ID="Dialog"  
  VERSION="1.0"  
  BORDER="dialog"  
  INNERBORDER="no"  
  MAXIMIZEBUTTON="no"  
  MINIMIZEBUTTON="no"  
  SCROLL="no"  
  SCROLLFLAT="yes"  
  CONTEXTMENU="no"  
  SELECTION="no"/>  
</head>
<script language="VBScript">  
Dim txtBeschreibung
Dim txtAuswahl

Sub Window_OnLoad
	window.resizeTo 350,280
End Sub

Sub OnClickButtonbtnOK()
  txtBeschreibung = txtFehlt.Value
  txtAuswahl = GetAuswahlRadioValue()
  SMSmatalarm
  Window.Close
End Sub

Function GetAuswahlRadioValue()
  For i=0 to Auswahl.length-1
    If Auswahl.Item(i).Checked Then
      GetAuswahlRadioValue = Auswahl.Item(i).Value
      Exit Function
    End If
  Next
  GetAuswahlRadioValue = ""  
End Function

Sub SMSmatalarm()
  'Makro zum starten einer SMS - Email Materialalarm  
  Dim strSupportEMail

  strSupportEMail = Array("alexander@test.de")  
  Dim notesdb
  Dim notesdoc
  Dim notesrtf
  Dim notessession
  Set notessession = CreateObject("Notes.Notessession")  
  Set notesdb = notessession.getdatabase("", "")  
  Call notesdb.openmail

  ' Mail erstellen  
  Set notesdoc = notesdb.createdocument
  Call notesdoc.replaceitemvalue("Sendto", strSupportEMail)  

  ' Betreffzeile  
  Call notesdoc.replaceitemvalue("Subject", "Es Fehlt ein Teil aus dem Regal")  

  Set notesrtf = notesdoc.createrichtextitem("body")  

  ' Info Text  
  Call notesrtf.appendtext("Es Fehlt im Bereich Test folgendes Teil:" & vbNewLine & ">>>>" & txtBeschreibung & "<<<<." & vbNewLine & txtAuswahl & vbNewLine & "( Bei Rückfragen Tel. )")  

  ' Mail senden und Hinweis  
  Call notesdoc.Send(False)
  Set notessession = Nothing
  MsgBox "Das Team Material Team wurde informiert"  
End Sub

</script>

<body bgcolor="#FEB794">  
<h3 style="font-size:12pt; margin-bottom:0">MATERIAL ALARM</h3>  
<p>Hier kurz angeben was fehlt und wie dringend<br/>
<span style="font-size:10pt">(Sachnummer Material)</span>  
<input type="text" name="txtFehlt" id="txtFehlt" style="width:100%"></p>  
<input type="radio" name="Auswahl" value="Beispiel Fahrrad" checked>Beispiel Fahrrad<BR>  
<input type="radio" name="Auswahl" value="Routenzug">Routenzug<BR>  
<input type="radio" name="Auswahl" value="Direkt">Direkt<BR>  
<div style="margin:10px auto; text-align: center"><input type="button" name="btnOK" id="btnOK" value="Mail senden" onclick="OnClickButtonbtnOK"></div>  
</body>
</html>

Aus dem ganzen kann man auch eine *.exe-Datei generieren, wenn das benötigt wird.
Als Hilfestellung zum erstellen solcher Files, kannst du dir auch mal folgendes Programm anschauen:
http://www.htaedit.com/

Grüße Uwe

Das ist ja der absoluter Hammer!!!! Mit was hast du das so erstellt? Das sieht Super aus!!!!!

Werde das gleich morgen mal testen

Zitat von @TheFalcon:

Das ist ja der absoluter Hammer!!!! Mit was hast du das so erstellt? Das sieht Super aus!!!!!

Eigentlich braucht's dazu nur etwas Wissen wie HyperTextApplication-Dokumente aufgebaut sind, der Rest ist HTML und VB-Script. Wenn du eine spezielle Oberfläche dafür haben willst, schau dir den Link im letzten Post an...

Uwe