Wo ist der Unterschied zwischen POP3 ud IMAP bei mehreren Benutzern

'Explorer Object  
Dim WithEvents objExplorer As Explorer
'aktuelles Mailitem  
Dim WithEvents mItem As MailItem

Private Sub Application_Startup()
    'aktiven Explorer beim Outlookstart setzen  
    Set objExplorer = ActiveExplorer
End Sub

'Sub die ausgelöst wird wenn auf eine Mail geantwortet wird  
Private Sub mitem_Reply(ByVal Response As Object, Cancel As Boolean)
    SetSendAccount Response
End Sub
'Sub die ausgelöst wird wenn auf wenn allen geantwortet wird  
Private Sub mItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    SetSendAccount Response
End Sub

Sub SetSendAccount(ByVal Response As Object)
    On Error Resume Next
    ' Wenn Item eine Mail ist  
    If Response.Class = olMail Then
        Dim m As MailItem, acc As Account, regex As Object, strHeaders As String, to_matches As Object, to_mails As Object, mail As Object
        Set regex = CreateObject("vbscript.regexp")  
        regex.IgnoreCase = True: regex.Global = True: regex.MultiLine = True
        'TO: Header Pattern  
        regex.Pattern = "^To:([\s\S]*)^(Subject|BCC|CC)"  
        'Transportheader extrahieren  
        strHeaders = mItem.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x007D001E")  
        Set to_matches = regex.Execute(strHeaders)
        If to_matches.Count > 0 Then
            'Mailadressen aus dem TO-Header extrahieren  
            regex.Pattern = "[A-Z0-9._%+-]+@[A-Z0-9.-]+\.[A-Z]{2,}"  
            Set to_mails = regex.Execute(to_matches(0).submatches(0))
            If to_mails.Count > 0 Then
                'Checke alle TO-Mailadressen ob ein passender Account in Outlook zur Mailadresse existiert  
                For Each mail In to_mails
                    Set acc = GetAccountFromMailAddress(mail)
                    Exit For
                Next
            End If
        End If
        ' wenn Account gefunden wurde, setze ihn als Absender in der Antwort  
        If Not acc Is Nothing Then
            Set m = Response
            m.SendUsingAccount = acc
        End If
        'cleanup  
        Set regex = Nothing
        Set acc = Nothing
        Set to_matches = Nothing
        Set to_mails = Nothing
        Set mail = Nothing
    End If
End Sub

Private Function GetAccountFromMailAddress(strEMail) As Account
    Dim acc As Account
    For Each acc In Application.Session.Accounts
        If LCase(acc.SmtpAddress) = LCase(strEMail) Then
            Set GetAccountFromMailAddress = acc
            Exit Function
        End If
    Next
End Function

Private Sub objExplorer_SelectionChange()
    If objExplorer.Selection.Count > 0 Then
        If objExplorer.Selection.Item(1).Class = olMail Then
            Set mItem = objExplorer.Selection.Item(1)
        End If
    End If
End Sub