Batch: Abbrechbarer Countdown, Timeout

@echo off &setlocal
set /a "wait=10"  

call :xtimeout %wait% "Timeout in # s, Abbruch mit beliebiger Taste." #  

echo ERRORLEVEL: %errorlevel%
if errorlevel 1000 (echo Fehler) else if errorlevel 1 (echo Abgebrochen.) else echo %wait% Sekunden abgelaufen.

echo(
pause
goto :eof


:::::::::::::::::::::::::::::::::::
:xtimeout Zeit [Text] [Platzhalter]
call;&(if not defined __bs__ call)&&(if not defined __cr__ call)&&(if not defined __lf__ call)&if errorlevel 1 (
  setlocal DisableDelayedExpansion
  2>nul set /a "countdown = %~1, before = %~1 + 1"&set "txt=%~2 "&set "wildcard=%~3"  
  for /f %%i in ('"prompt;$h&for %%i in (1) do rem"') do set "__bs__=%%i" &REM ~BackSpace~  
  for /f %%a in ('copy /z "%~f0" nul') do set "__cr__=%%a" &REM ~CarriageReturn~  
  set __lf__=^


  REM Zwei Leerzeilen sind erforderlich! ~LineFeed~
  setlocal EnableDelayedExpansion
  call;&(if !countdown! lss 1 call)&&(if !countdown! gtr 300 call)&if errorlevel 1 (endlocal&endlocal&exit /b 2147483647)
  if not defined wildcard set "wildcard=!__bs__!"  
  set "file=!temp!\!random!-!random!.timeout"  
  start "" /b cmd /von /c ">"!file!" timeout /t !countdown!&>"!file!" echo 2147483647"  
)
if not exist "!file!" goto xtimeout  
for /f "delims=" %%i in ('type "!file!"') do set "countdown=%%i"  
for /f "delims=" %%i in ('"call echo %%countdown:!__bs__!=^!__lf__^!%%"') do set "countdown=%%i"  
for /f %%i in ("!countdown!") do set "countdown=%%i"  
if %before% gtr %countdown% (
  if defined txt <nul set /p "=%__bs__%!__cr__!!txt:%wildcard%=%countdown%!%__bs__%"  
  set /a "before = countdown"  
  goto xtimeout
) else (
  if %countdown% equ 2147483647 (
    del "!file!"  
    echo(
    endlocal&endlocal&exit /b %before%
  ) else (
    goto xtimeout
  )
)