ISO Datei für diverse Zwecke erstellen

@ECHO OFF & SETLOCAL

:: Rückgabecodes und Ihre Bedeutung in dieser Batchdatei
:: 1 = Der Eingabepfad existiert nicht
:: 2 = Der Ausgabepfad existiert nicht
:: 3 = Die mkisofs.exe fehlt
:: 9 = Vorzeitige Abbruch bei der Kontrolle der Konfigurationsoptionen

SET "MKISOFS=%~dp0mkisofs.exe"  
SET "INPUT_PATH=%~1"  
SET "OUTPUT_PATH=%~dp0"  

:: Die ISO Volumen- und Dateibezeichnung wird tiefer ermittelt, 
:: wenn sichergestellt ist, dass das Verzeichnis auch existiert... ;)
SET "ISO_VOLID="  
SET "ISO_IMAGE="  

::  Logische Überprüfung...
:: Eingabepfad
if "%INPUT_PATH%" EQU "" EXIT 1  
dir /AD "%INPUT_PATH%" >NUL 2>NUL || EXIT 1  

:: Danke an Bastla und miniversum für die nächste Zeile
set "ISO_VOLID=%~nx1" & set "ISO_IMAGE=%~nx1"  

:: Ausgabepfad
if "%OUTPUT_PATH%" EQU "" EXIT 2  
dir /AD "%OUTPUT_PATH%" >NUL 2>NUL || EXIT 2  

:: MKISOFS.exe vorhanden???
if not exist "%MKISOFS%" EXIT 3  

echo Konfigurationsoptionen
echo ********************************************************
echo Pfad zu mkisofs            : %MKISOFS%
echo Eingabepfad                : %INPUT_PATH% 
echo Ausgabepfad                : %OUTPUT_PATH%
echo IsoImage-Dateiname         : %ISO_IMAGE%.iso
echo IsoImage Volumenbezeichnung: %ISO_VOLID%
echo ********************************************************
echo.
set /P ERGEBNIS=[Sind diese Einstellungen richtig? (j/n) ]
if /I "%ERGEBNIS%" NEQ "j" exit 9  
echo Imageerstellung...
:: BugFix: 2009-04-20
if '%INPUT_PATH:~-1%' NEQ '\' "%MKISOFS%" -iso-level 4 -joliet -joliet-long -rational-rock -output "%OUTPUT_PATH%\%ISO_IMAGE%.iso" -volid "%ISO_VOLID%" "%INPUT_PATH%"  
if '%INPUT_PATH:~-1%' EQU '\' "%MKISOFS%" -iso-level 4 -joliet -joliet-long -rational-rock -output "%OUTPUT_PATH%\%ISO_IMAGE%.iso" -volid "%ISO_VOLID%" %INPUT_PATH%  
echo.
echo Imageerstellung...FERTIG! Beliebige Taste zum Beenden!
pause > NUL