Workshop Batch for Runaways - Part III - Datums- und Zeitvariablen im Batch

>reg add "HKCU\Control Panel\International" /v idate /t REG_SZ /d 1 /f  
>date
Aktuelles Datum: Sa 01-10-2005
Geben Sie das neue Datum ein: (TT-MM-JJ)

>date /t
Sa 01-10-2005
>reg add "HKCU\Control Panel\International" /v idate /t REG_SZ /d 0 /f  
>date /t
Sa 10-01-2005

>date
Aktuelles Datum: Sa 10-01-2005
Geben Sie das neue Datum ein: (MM-TT-JJ)

For %%i in (%AllDateTimeVars%) do @if defined %%i set %%i 

For %%i in (%AllSystemDateTimeVars%) do @if defined %%i set %%i 

:: Vers 0.09 11.7.2007:  Windows NT kennt weder %date%  noch %time%.

@echo off

:: With the help of the tutorial
:: 
set "myDate=%date%"  
for /f "tokens=2" %%i in ("%myDate%") do set "myDate=%%i"  

if not exist DateOrder?.txt (
start /wait regedit /e SystemDateTimeInfo.reg "HKEY_CURRENT_USER\Control Panel\International"  
for /f "tokens=1* delims==" %%i in ('type SystemDateTimeInfo.reg ^| findstr /i "iDate"') do set "iDate=%%j"  
del SystemDateTimeInfo.reg
)

if defined iDate echo File represents order in date output. Delete it, if you change the regional settings on this computer. > DateOrder%iDate%.txt

for /f "tokens=1-3 delims=-/." %%a in ("%myDate%") do (  
if exist "DateOrder0.txt" for %%i in ("JJ=%%c" "MM=%%a" "TT=%%b") do set %%i  
if exist "DateOrder1.txt" for %%i in ("JJ=%%c" "MM=%%b" "TT=%%a") do set %%i  
if exist "DateOrder2.txt" for %%i in ("JJ=%%a" "MM=%%b" "TT=%%c") do set %%i  
)

for /f "tokens=1-3 delims=:,." %%a in ("%time%") do for %%i in ("hh=%%a" "min=%%b" "ss=%%c") do set %%i  
set "hh=%hh: =0%"  

echo Log %JJ%-%MM%-%TT% @ %hh%;%min%;%ss%
pause

@echo off
set "alpha=beliebig"  
if not defined alpha echo alpha ist nicht definiert.
set /a "beta=1%alpha%" 2>NUL  
if errorlevel 1 (
echo %alpha% ist weder Dezimal- noch Oktalzahl, aber m”glicherweise eine Hexadezimalzahl.
) else (
echo %alpha% ist eine Dezimal- oder Oktalzahl, keinesfalls aber eine Hexadezimalzahl.
)
pause

Habe ich der Übersicht wegen gelöscht, da im Wesentlichen so wie in EDITIERT 4

@echo off

:: With the help of the tutorial
:: 
set "myDate=%date%"  
for /f "tokens=2" %%i in ("%myDate%") do set "myDate=%%i"  

if not exist DateOrder?.txt (
start /wait regedit /e SystemDateTimeInfo.reg "HKEY_CURRENT_USER\Control Panel\International"  
for /f "tokens=1* delims==" %%i in ('type SystemDateTimeInfo.reg ^| findstr /i "iDate"') do set "iDate=%%j"  
del SystemDateTimeInfo.reg
)

if defined iDate echo File represents order in date output. Delete it, if you change the regional settings on this computer. > DateOrder%iDate%.txt

for /f "tokens=1-3 delims=-/." %%a in ("%myDate%") do (  
if exist "DateOrder0.txt" for %%i in ("YY=%%c" "MM=%%a" "DD=%%b") do set %%i  
if exist "DateOrder1.txt" for %%i in ("YY=%%c" "MM=%%b" "DD=%%a") do set %%i  
if exist "DateOrder2.txt" for %%i in ("YY=%%a" "MM=%%b" "DD=%%c") do set %%i  
)

for %%i in (YY MM DD) do if not defined %%i goto :ViaVBS

set /a "test=1%YY%" 2>NUL  
if errorlevel 1 goto :ViaVBS
set /a "test=1%MM%" 2>NUL  
if errorlevel 1 goto :ViaVBS
set /a "test=1%DD%" 2>NUL  
if errorlevel 1 goto :ViaVBS

if 1000 GTR %YY% goto :ViaVBS
if 12 LSS %MM% goto :ViaVBS
if 31 LSS %DD% goto :ViaVBS

goto :output

:ViaVBS
echo Wscript.Echo Year(Now)^&"-"^&Month(Now)^&"-"^&Day(Now) > ComputeDateVia.vbs  
for /f "tokens=1-3 delims=-" %%a in ('cscript //nologo ComputeDateVia.vbs') do (  
for %%i in ("YY=%%a" "MM=%%b" "DD=%%c") do set %%i  
)
if %MM% LSS 10 set "MM=0%MM%"  
if %DD% LSS 10 set "DD=0%DD%"  
del ComputeDateVia.vbs

:output
for /f "tokens=1-3 delims=:,." %%a in ("%time%") do for %%i in ("hh=%%a" "min=%%b" "ss=%%c") do set %%i  
set "hh=%hh: =0%"  

echo Log %YY%-%MM%-%DD% @ %hh%;%min%;%ss%
pause

:: Algorithmus frei nach [http://www.commandline.co.uk/lib/treeview/index.php]
::                                 '-->Klick: Batch Function Library/Date and Time Functions/DateToDOW  
...
set yy=42 & set mm=05 & set dd=23 & set TwoDigitYearMax=70
if 1%yy% LSS 200 if 1%yy% LSS 1%TwoDigitYearMax% (set yy=20%yy%) else (set yy=19%yy%)
...
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1
...

@echo off & setlocal EnableExtensions

::Das Datum "tag.monat.jahr" in seine Bestandteile zerlegen: 
  if "%~1" == "" ( ::kein Parameter angegeben; das aktuelle Datum %DATE% soll verwendet werden...  
    for /f "tokens=1-3 delims=." %%a in ("%DATE:* =%") do set _dd=%%a & set _mm=%%b & set _yy=%%c  
  ) else ( ::das übergebene Datum verwenden...
    for /f "tokens=1-3 delims=." %%a in ("%~1")    do set _dd=%%a & set _mm=%%b & set _yy=%%c  
  )

::Rufen wir den Code von Ritchie Lawrence auf, um den Wochentag des Datums zu berechnen:
  call :DateToDOW %_yy% %_mm% %_dd% _WoTgNr

::Die Wochentagsnummer (1 bis 7) in den Namen des Wochentags umwandeln:
  for /f "tokens=%_WoTgNr%" %%a in ("Montag Dienstag Mittwoch Donnerstag Freitag Samstag Sonntag") do set _Wochentag=%%a  

::Wochentag ausgeben
  echo Der gesuchte Wochentag ist ein: %_Wochentag%

goto :EOF   ::Springe an das Ende der Datei, also verlasse die Batch (weil fertig)

:DateToDOW %yy% %mm% %dd% dow
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: By:   Ritchie Lawrence, 2003-04-29. Version 1.1
:: Func: Creates a day of week number from a calendar date, where 1 = Mon
::       and 7 = Sun. For NT4/2000/XP/2003.
:: Args: %1 year component to be converted, 2 or 4 digits (by val)
::       %2 month component to be converted, leading zero ok (by val)
::       %3 day of month to be converted, leading zero ok (by val)
::       %4 var to receive day of week number, 1 to 7 (by ref)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  set yy=%1&set mm=%2&set dd=%3
  if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  set /a dd=100%dd%%%100,mm=100%mm%%%100
  set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
  set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1
  set %4=%dow%
 exit /b 0
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::  

c:\>MyBatch.cmd 05.05.2005
-------------------------------
  Ausgabe:  "Der gesuchte Wochentag ist ein: Donnerstag"

@echo off & setlocal EnableExtensions

call :FncPartDate -f DD/MM/YY -0 _Year _Month _Day %1 &::Das übergebene Datum in seine Bestandteile zerlegen

echo ------------------------------------------------------------------------------
echo #     Wochentagsberechnung stur nach dem Gregorianischen Kalendersystem:     #
echo ------------------------------------------------------------------------------
set /a _WDNr=0
call :DateToDOW %_Year% %_Month% %_Day% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo Der gesuchte Wochentag ist ein: %_WDName%  ^(laut DateToDOW^)

set /a _WDNr=0  
call :FncDateToWeekdayNr_Hack_00 %_Year% %_Month% %_Day% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo Der gesuchte Wochentag ist ein: %_WDName%  ^(laut FncDateToWeekdayNr_Hack_00^)

set /a _WDNr=0  
call :FncDateToWeekdayNr_Hack_01 %_Year% %_Month% %_Day% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo Der gesuchte Wochentag ist ein: %_WDName%  ^(laut FncDateToWeekdayNr_Hack_01^)

set /a _WDNr=0  
call :FncDateToWeekdayNr_Hack_10 %_Year% %_Month% %_Day% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo Der gesuchte Wochentag ist ein: %_WDName%  ^(laut FncDateToWeekdayNr_Hack_10^)

set /a _WDNr=0  
call :FncDateToWeekdayNr_Hack_11 %_Year% %_Month% %_Day% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo Der gesuchte Wochentag ist ein: %_WDName%  ^(laut FncDateToWeekdayNr_Hack_11^)

echo.
echo ------------------------------------------------------------------------------
echo # Berechnung des Julianischen Tages stur nach dem Gregorian. Kalendersystem: #
echo ------------------------------------------------------------------------------
set /a _JDay=0  
call :FncDateToJulianDay_Hack_00 %_Year% %_Month% %_Day% _JDay 
echo Umrechnung Datum nach JulianDay: %_JDay%  ^(laut FncDateToJulianDay_Hack_00^)
set /a _JDay=0  
call :FncDateToJulianDay_Hack_01 %_Year% %_Month% %_Day% _JDay 
echo Umrechnung Datum nach JulianDay: %_JDay%  ^(laut FncDateToJulianDay_Hack_01^)
set /a _JDay=0  
call :FncDateToJulianDay_Hack_10 %_Year% %_Month% %_Day% _JDay 
echo Umrechnung Datum nach JulianDay: %_JDay%  ^(laut FncDateToJulianDay_Hack_10^)
echo.
set /a _WDNr=0
call :FncJulianDayToWeekdayNr %_JDay% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo         Berechneter Wochentag aus JulianDay %_JDay%:       %_WDName%
echo.
echo ------------------------------------------------------------------------------
echo # Julian Day bis 04.10.1582 nach dem Julianischen, dann Gregorian. Kalender: #
echo ------------------------------------------------------------------------------
set /a _JDay=0  
call :FncDateToJulianDay_Hack_11 %_Year% %_Month% %_Day% _JDay 
echo.
echo Umrechnung Datum nach JulianDay: %_JDay%  ^(laut FncDateToJulianDay_Hack_11^)
echo.
set /a _WDNr=0
call :FncJulianDayToWeekdayNr %_JDay% _WDNr
call :FncWeekdayNrToName %_WDNr% _WDName
echo         Berechneter Wochentag aus JulianDay %_JDay%:       %_WDName%

goto :EOF   ::Springe an das Ende der Datei, also verlasse die Batch (weil fertig)

:FncPartDate  {{comment_single_line_remark:2}}
::Options:    -f DD/MM/YY or YY/MM/DD or MM/DD/YY                  /*Input-Date-Format by YY=Year, MM=Month, DD=Day*/
::            -yy <SplitYear>  /*if e.g. SplitYaer==70 then double-digit-year form 00 to 69 make to 20xx, else 19xx*/
::            -0 /* remove leading zeros by returns; on this option the 0xxxx-year can have no more than 5 digits  */
::Parameters: <VarReturnsYear> <VarReturnsMonth> <VarReturnsDay> [date or nothing for current date]
::Example:    call :FncPartDate -f DD/MM/YY -yy 70 -0 _Year _Month _Day "05.05.55"    /*returns _Year=2055, _Day=5 */ 
::            call :FncPartDate -f DD/MM/YY           _Year _Month _Day "05.05.55"    /*returns _Year=55,   _Day=05*/ 
::            call :FncPartDate -f YY/MM/DD -yy 70    _Year _Month _Day "84.05.05"    /*returns _Year=1984, _Day=05*/ 
::            call :FncPartDate -f YY/MM/DD        -0 _Year _Month _Day "84.05.05"    /*returns _Year=84,   _Day=5 */ 
::###################################################################################################################
  setlocal EnableDelayedExpansion
   if "%~1" == "-f"  ( set _#2=%~2 &set "_F1=_!_#2:~0,2!" &set "_F2=_!_#2:~3,2!" &set "_F3=_!_#2:~6,2!" &shift &shift  
   ) else ( set "_F1=_DD" &set "_F2=_MM" &set "_F3=_YY" )  
   if "%~1" == "-yy" ( set "_SpYY=%~2" &shift &shift ) else ( set "_SpYY=" )  
   if "%~1" == "-0"  ( set "_RLZ=on"   &shift        ) else ( set "_RLZ="  )  

   if "%~4" == "" ( set "_MyDate=%DATE:* =%" ) else ( set "_MyDate=%~4" )  
   for /f "tokens=1-3 delims=./ " %%a in ("%_MyDate%") do set "%_F1%=%%a" & set "%_F2%=%%b" & set "%_F3%=%%c"  

   if "%_YY:~0,1%" == "-" (set "_YY=%_YY:~1,100%" &set "_NS=-") else (set "_NS=") &::Vorzeichen entfernen  
   if defined _RLZ ( ::führende Nullen entfernen
     if "%_YY:~0,1%" == "0" set /a _YY"=(100000%_YY%)%%100000"  
     if "%_MM:~0,1%" == "0" set /a _MM"=(100000%_MM%)%%100000"  
     if "%_DD:~0,1%" == "0" set /a _DD"=(100000%_DD%)%%100000"  
   )
   set "_YY=%_NS%%_YY%" &::Vorzeichen wieder einfügen  

   if not defined _NS if defined _SpYY if %_YY% LSS 100 if 1%_YY% LSS 1%_SpYY% (set _YY=20%_YY%) else (set _YY=19%_YY%)
  endlocal & set "%~1=%_YY%" & set "%~2=%_MM%" & set "%~3=%_DD%"  
 exit /b 0

:FncWeekdayNrToName  {{comment_single_line_remark:15}}
::Options:    -s "Monday Tuesday Wednesday Thursday Friday Saturday Sunday unknown" /*use my own weekdayname-string*/ 
::Parameters: <weekday-number form 1(=Monday) to 7(=Sunday)> <VarReturnsWeekdayName>
::Example:    call :FncWeekdayNrToName -s "Mo Tu We Th Fr Sa Su unknown" 5 _Name          /*returns _Name="Fr"     */ 
::            call :FncWeekdayNrToName                                   5 _Name          /*returns _Name="Freitag"*/ 
::###################################################################################################################
  setlocal EnableDelayedExpansion
   if "%~1" == "-s"  ( set "_WNS=%~2" &shift &shift  
   ) else ( set "_WNS=Montag Dienstag Mittwoch Donnerstag Freitag Samstag Sonntag unbekannt" )  
   set /a _WeekdayNumber"=%~1"  
   if %_WeekdayNumber% LSS 1 set /a _WeekdayNumber"=8"  
   if %_WeekdayNumber% GTR 7 set /a _WeekdayNumber"=8"  
   for /f "tokens=%_WeekdayNumber%" %%a in ("%_WNS%") do set _WeekdayName=%%a  
  endlocal & set "%~2=%_WeekdayName%"  
 exit /b 0

:FncDateToWeekdayNr_Hack_00  {{comment_single_line_remark:21}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnWeekdayNr>
::Note:       The date less than 01/01/1970 is invalid
::Example:    call :FncDateToWeekdayNr 5555 05 05 _DayOfWeekNr
::#################### Berechnung des Wochentages vom dd.mm des Jahres 1970 bis 5881579 #######################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
::Algorithmus frei nach http://www.commandline.co.uk/lib/treeview/index.php, Autor: Ritchie Lawrence
  set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3
  if %_MyYear% LSS 1970 exit /b 1                                      &::Berechnung nur bis 29.12.1969 möglich
  ::Mit den vorhandenen Daten frei nach dem Algorithmus von Ritchie Lawrence den Wochentag berechnen:
    if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 ) &::Jan or Feb = 1, sonst 0
    set /a _MonthsFactor"=(12*_bJanOrFeb)+(_MyMonth-3)"                &::im Mär=0, Apr=1 ... Feb=11  
    set /a _ElapsedDaysUntilMyMonths"=(153*_MonthsFactor+2)/5"         &::im Mär=0, Apr=31 ... Feb=337  
    set /a _ElapsedDaysOfMyYear"=_ElapsedDaysUntilMyMonths+_MyDay"     &::+ verstrichene Tage des akt. Monats  
    set /a _MyYear"-=_bJanOrFeb"                                       &::Jan und Feb liegen hier im verg. Jahr  
    set /a _ElapsedDaysUntilMyYear"=_MyYear*365 + (_MyYear/4 - _MyYear/100 + _MyYear/400)"  
    set /a _Weekday"=(_ElapsedDaysUntilMyYear+_ElapsedDaysOfMyYear - 719466)%%7 + 1"  
  set %4=%_Weekday%
 exit /b 0

:FncDateToWeekdayNr_Hack_01 {{comment_single_line_remark:35}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnWeekdayNr>
::Example:    call :FncDateToWeekdayNr 5555 05 05 _DayOfWeekNr
::################ Berechnung des Wochentages vom dd.mm des Jahres -2147483648 bis 5879609 ####################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
  set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3
  
  if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
    echo FncDateToWeekdayNr_Hack01: Error^^!
    echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
    echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
    exit /b 1
  )  1>&2
  if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  
  :FncDateToWeekdayNr_Hack01_YearLoop              &::negative Jahreszahl in eine gültige positive Zahl umwandeln...
    if %_MyYear% LSS 1 set /a _MyYear"+=4000000"   &::...alle 400 J. wiederh. sich die WoTage (*10000 ist schneller)  
   if %_MyYear% LSS 1 goto :FncDateToWeekdayNr_Hack01_YearLoop &::LSS 1 (statt 0) weil Jahr im JanOrFeb sonst -1
   
  ::Im Folgenden gilt es die bereits verstrichenen Tage des Jahres im März-bis-Februar-Jahresmodell zu berechnen.
    if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 ) &::Jan or Feb = 1, sonst 0
    ::Algorithmus frei nach http://www.commandline.co.uk/lib/treeview/index.php, Autor: Ritchie Lawrence
    set /a _MonthsFactor"=(12*_bJanOrFeb)+(_MyMonth-3)"                &::im Mär=0, Apr=1 ... Feb=11  
    set /a _ElapsedDaysUntilMyMonths"=(153*_MonthsFactor+2)/5"         &::im Mär=0, Apr=31 ... Feb=337  
    set /a _ElapsedDaysOfMyYear"=_ElapsedDaysUntilMyMonths+_MyDay"     &::+ verstrichene Tage des akt. Monats  
  ::Nun gilt es die Tage der vergangenen Jahre bis zum rechnerischen Jahr 0000 zurückzuberechenen.
    set /a _MyYear"-=_bJanOrFeb"                                       &::Jan und Feb liegen hier im verg. Jahr  
    set /a _ElapsedDaysUntilMyYear"=_MyYear*365 + (_MyYear/4 - _MyYear/100 + _MyYear/400)"  
  ::Wochentag=(verstrichene Tage + 1 Tag /*damit der Ursprungstag der Berechnung ein Montag ist*/) mod 7 + 1
    set /a _Weekday"=(_ElapsedDaysUntilMyYear+_ElapsedDaysOfMyYear + 1)%%7 + 1"  
  set %4=%_Weekday%
 exit /b 0

:FncDateToWeekdayNr_Hack_10    {{comment_single_line_remark:54}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnWeekdayNr>
::Example:    call :FncDateToWeekdayNr 5555 05 05 _DayOfWeekNr
::############## Berechnung des Wochentages vom dd.mm des Jahres -2147483648 bis 2147483641 ###################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
::Algorithmus frei nach http://de.wikipedia.org/w/index.php?title=Wochentagsberechnung&oldid=75828222
  set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3

  if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
    echo FncDateToWeekdayNr_Hack10: Error^^!
    echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
    echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
    exit /b 1
  )  1>&2
  if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  
  :FncDateToWeekdayNr_Hack10_YearLoop              &::negative Jahreszahl in eine gültige positive Zahl umwandeln...
    if %_MyYear% LSS 1 set /a _MyYear"+=4000000"   &::...alle 400 J. wiederh. sich die WoTage (*10000 ist schneller)  
   if %_MyYear% LSS 1 goto :FncDateToWeekdayNr_Hack10_YearLoop &::LSS 1 (statt 0) weil Jahr im JanOrFeb sonst -1

  set /a _MyDayID"=_MyDay%%7"  &::Tageskennziffer ermitteln  
  for /f "tokens=%_MyMonth%" %%a in ("0 3 3 6 1 4 6 2 5 0 3 5") do set _MyMonthID=%%a  
  
  if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 )
  set /a _MyYear"-=_bJanOrFeb"           &::Im Jan or Feb Schaltjahr nur bis zum verganenen Jahr berechnen  
  set /a _MyLeapYearID"=(_MyYear/4 - _MyYear/100 + _MyYear/400)%%7"    &::Schaltjahreskennziffer ermitteln  

  set /a _Weekday"=(_MyDayID + _MyMonthID + _MyYear+_bJanOrFeb + _MyLeapYearID -2)%%7 + 1" &::Wochentag berechnen  
  set %4=%_Weekday%
 exit /b 0

:FncDateToWeekdayNr_Hack_11    {{comment_single_line_remark:69}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnWeekdayNr>
::Example:    call :FncDateToWeekdayNr 5555 05 05 _DayOfWeekNr
::############## Berechnung des Wochentages vom dd.mm des Jahres -2147483648 bis 1728356768 ###################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
  set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3

  if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
    echo FncDateToWeekdayNr_Hack10: Error^^!
    echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
    echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
    exit /b 1
  )  1>&2
  if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  
  :FncDateToWeekdayNr_Hack11_YearLoop              &::negative Jahreszahl in eine gültige positive Zahl umwandeln...
    if %_MyYear% LSS 1 set /a _MyYear"+=4000000"   &::...alle 400 J. wiederh. sich die WoTage (*10000 ist schneller)  
   if %_MyYear% LSS 1 goto :FncDateToWeekdayNr_Hack11_YearLoop &::LSS 1 (statt 0) weil Jahr im JanOrFeb sonst -1

  ::Verstrichene Monatstage des Jahres mit einem Algorithmus eines März-bis-Februar-Jahresmodells berechnen...
    if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 ) &::Jan or Feb = 1, sonst 0
    ::Algorithmus frei nach http://www.commandline.co.uk/lib/treeview/index.php, Autor: Ritchie Lawrence
    set /a _MonthsFactor"=(12*_bJanOrFeb)+(_MyMonth-3)"                &::im Mär=0, Apr=1  ... Jan=10,  Feb=11  
    set /a _ElapsedDaysUntilMyMonths"=(153*_MonthsFactor+2)/5"         &::im Mär=0, Apr=31 ... Jan=306, Feb=337  
  
  set /a _ElapsedDaysUntilMyMonths"+=59 - 365*_bJanOrFeb"   &::zurückrechnen in das gängige Jahresmodell  
  :: ab März+=59, die Tage Jan+Feb<--'  '-->nur im Jan or Feb: - (59 + 306_MärzBisJanTage_des_März-bis-Feb-Modells) 
  
  set /a _MyYear"-=_bJanOrFeb"                                  &::im Jan/Feb Schaltjahr nur bis Jahr-1 berechnen  
  set /a _MyLeapYears"=(_MyYear/4 - _MyYear/100 + _MyYear/400)" &::Schaltjahre ermitteln  
  
  ::Das rechnerische Jahr 0 beginnt an einem Samstag. Jedes darauf folgende Jahr erhöht den Tag des Jahresbeginns
  ::um 1 Tag. Jedes Schaltjahr erhöht ihn um 1 weiteren Tag. Daher: (Tage+Monatstage + Jahre + Schaltjahre) mod 7
  ::ergibt 0=Sa, 1=So, 2=Mo, etc. Dank -2 steht die 0 für Mo, 1=Di, etc. +1 macht aus 0bis6 ein 1bis7. Fertig.
    set /a _Weekday"=(_MyDay+_ElapsedDaysUntilMyMonths + _MyYear+_bJanOrFeb + _MyLeapYears -2)%%7 + 1"  
  set %4=%_Weekday%
 exit /b 0
 
:FncJulianDayToWeekdayNr
::Parameters: <JulianDayNr> <VarNameToReturnWeekdayNr>
::#############################################################################################################
  setlocal EnableDelayedExpansion
   set _JD=%~1
   set /a _WDNr"=_JD%%7+1"  
   if %_WDNr% LSS 1 set /a _WDNr"+=7" &::für Tage vor dem ersten JulianDay  
  endlocal & set "%~2=%_WDNr%"  
 exit /b 0

:FncDateToJulianDay_Hack_00    {{comment_single_line_remark:94}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnJulianDayNr>
::Example:    call :FncDateToJulianDay 5555 05 05 _JulianDay
::#############################################################################################################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
::Algorithmus frei nach http://docs.kde.org/stable/de/kdeedu/kstars/ai-julianday.html; hier umgesetzt auf batch
  set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3

  if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
    echo FncDateToJulianDay_Hack00: Error^^!
    echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
    echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
    exit /b 1
  )  1>&2
  if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  

  ::das Datum auf den Julianischen Tag umrechnen:
    set /a _JD"=_MyDay-32075 + 1461*(_MyYear+4800 + (_MyMonth-14)/12)/4"  
    set /a _JD"+=367*(_MyMonth-2 - (_MyMonth-14)/12*12)/12"  
    set /a _JD"-=3*((_MyYear + 4900 + (_MyMonth - 14)/12)/100)/4"  
  set /a %~4"=%_JD%" &::Hinweis: JulianDay 0 == 1. Jan. 4713 v.u.Z. julianisch == 24. Nov. 4714 v.u.Z. greogorianisch  
 exit /b 0

:FncDateToJulianDay_Hack_01  {{comment_single_line_remark:94}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnJulianDayNr>
::Example:    call :FncDateToJulianDay 5555 05 05 _JulianDay
::#############################################################################################################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
::Algorithmus frei nach http://www.commandline.co.uk/lib/treeview/index.php, Autor: Ritchie Lawrence
  set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3

  if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
    echo FncDateToJulianDay_Hack01: Error^^!
    echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
    echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
    exit /b 1
  )  1>&2
  if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  

  ::Im Folgenden gilt es die bereits verstrichenen Tage des Jahres im März-bis-Februar-Jahresmodell zu berechnen.
    if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 ) &::Jan or Feb = 1, sonst 0
    set /a _MonthsFactor"=(12*_bJanOrFeb)+(_MyMonth-3)"                &::im Mär=0, Apr=1 ... Feb=11  
    set /a _ElapsedDaysUntilMyMonths"=(153*_MonthsFactor+2)/5"         &::im Mär=0, Apr=31 ... Feb=337  
    set /a _ElapsedDaysOfMyYear"=_ElapsedDaysUntilMyMonths+_MyDay"     &::+ verstrichene Tage des akt. Monats  
  ::Nun gilt es die Tage der vergangenen Jahre bis zum Jahr 0000 zurückzuberechenen.
    set /a _MyYear"-=_bJanOrFeb"                                       &::Jan und Feb liegen hier im verg. Jahr  
    if %_MyYear% LSS 0 set /a _ElapsedDaysOfMyYear"-=1"  
    set /a _ElapsedDaysUntilMyYear"=_MyYear*365 + (_MyYear/4 - _MyYear/100 + _MyYear/400)"  
  set /a _JD"=(_ElapsedDaysUntilMyYear+_ElapsedDaysOfMyYear+1721119)" &::+Tage vom 01. März 0000 bis JulianDay 0  
  set /a %~4"=%_JD%" &::Hinweis: JulianDay 0 == 1. Jan. 4713 v.u.Z. julianisch == 24. Nov. 4714 v.u.Z. greogorianisch  
 exit /b 0

:FncDateToJulianDay_Hack_10  {{comment_single_line_remark:121}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnJulianDayNr>
::Example:    call :FncDateToJulianDay 5555 05 05 _JulianDay
::#############################################################################################################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
::Algorithmus frei nach http://de.wikipedia.org/w/index.php?title=Julianisches_Datum&oldid=76256118#Berechnung_aus_dem_Kalenderdatum
  setlocal EnableDelayedExpansion
   set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3

   if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
     echo FncDateToJulianDay_Hack01: Error^^!
     echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
     echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
     exit /b 1
   )  1>&2
   if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  

   if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 )
   set /a _Y"=_MyYear-_bJanOrFeb"  
   set /a _M"=_MyMonth + (12*_bJanOrFeb) + 1"  
   set /a _JD"=365*(_Y+4716) + (_Y+4716)/4 + 30*_M + 6001*_M/10000 - 1524 + _MyDay + 2 - _Y/100 + _Y/400"  
  endlocal &set "%~4=%_JD%" &::Hinweis: JulianDay 0 == 1. Jan. 4713 v.u.Z. julianisch == 24. Nov. 4714 v.u.Z. greogorianisch  
 exit /b 0

:FncDateToJulianDay_Hack_11  {{comment_single_line_remark:130}}
::Parameters: <Year> <Month> <Day> <VarNameToReturnJulianDayNr>
::Example:    call :FncDateToJulianDay 5555 05 05 _JulianDay
::#############################################################################################################
::Nicht fuer den produktiven Einsatz gedacht und geeignet; nur zum Testen.
::Algorithmus frei nach http://de.wikipedia.org/w/index.php?title=Julianisches_Datum&oldid=76256118#Berechnung_aus_dem_Kalenderdatum
  setlocal EnableDelayedExpansion
   set _MyYear=%1&set _MyMonth=%2&set _MyDay=%3

   if %_MyYear% EQU 0 ( ::Jahr 0000 wurde angegeben; ungültige Jahreszahl...
     echo FncDateToJulianDay_Hack01: Error^^!
     echo On 31.12.0001 before Christ ^(BC^) immediately follows the 01.01.0001 AD ^(CE^).
     echo The year 0000 does not exist. Use -0001 do you mean the year 1 before Christ.
     exit /b 1
   )  1>&2
   if %_MyYear% LSS 0 set /a _MyYear"+=1"           &::Das Jahr -1 liegt rechnerisch im Jahr 0, -2 im Jahr -1, etc.  

   if %_MyMonth% LEQ 2 ( set _bJanOrFeb=1 ) else ( set _bJanOrFeb=0 )
   set /a _Y"=_MyYear-_bJanOrFeb"  
   set /a _M"=_MyMonth + (12*_bJanOrFeb) + 1"  
  
   set /a        _MyCalendar"=_MyYear*100 + _MyMonth*10 + _MyDay"  
   set /a _GregorianCalendar"=   1582*100 +       10*10 +     15"  
   set /a    _JulianCalendar"=   1582*100 +       10*10 +      4"  
   if %_MyCalendar% GEQ %_GregorianCalendar% ( ::ab 15.10.1582 Schaltjahresberechnung nach dem Gregorian. Kal.
     echo         Berechnung nach dem Gregorianischen Kalender...
     set /a _JD"=365*(_Y+4716) + (_Y+4716)/4 + 30*_M + 6001*_M/10000 - 1524 + _MyDay + 2 - _Y/100 + _Y/400"  
   )
   if %_MyCalendar% LSS %_GregorianCalendar% if %_MyCalendar% GTR %_JulianCalendar% (
     echo         FncDateToJulianDay_Hack_11: Error^^!
     echo         Historically the days between 05-14 in October 1582 does not exist.
     exit /b 1
   ) 1>&2
   if %_MyCalendar% LEQ %_JulianCalendar% ( ::bis 04.10.1582 Schaltjahresberechnung nach dem Julian. Kalender
     echo         Berechnung nach dem Julianischen Kalender...
     set /a _JD"=365*(_Y+4716) + (_Y+4716)/4 + 30*_M + 6001*_M/10000 + _MyDay - 1524"  
   )
  endlocal &set "%~4=%_JD%"  
 exit /b 0
 
:DateToDOW %yy% %mm% %dd% dow
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: By:   Ritchie Lawrence, 2003-04-29. Version 1.1
:: Func: Creates a day of week number from a calendar date, where 1 = Mon
::       and 7 = Sun. For NT4/2000/XP/2003.
:: Args: %1 year component to be converted, 2 or 4 digits (by val)
::       %2 month component to be converted, leading zero ok (by val)
::       %3 day of month to be converted, leading zero ok (by val)
::       %4 var to receive day of week number, 1 to 7 (by ref)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  set yy=%1&set mm=%2&set dd=%3
  ::if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  set /a dd=100%dd%%%100,mm=100%mm%%%100
  set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
  set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1
  set %4=%dow%
 exit /b 0
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::   

c:\>MyBatch.cmd 05.05.5555
-------------------------------
  Ausgabe:
------------------------------------------------------------------------------
#     Wochentagsberechnung stur nach dem Gregorianischen Kalendersystem:     #
------------------------------------------------------------------------------
Der gesuchte Wochentag ist ein: Donnerstag  (laut DateToDOW)
Der gesuchte Wochentag ist ein: Donnerstag  (laut FncDateToWeekdayNr_Hack_00)
Der gesuchte Wochentag ist ein: Donnerstag  (laut FncDateToWeekdayNr_Hack_01)
Der gesuchte Wochentag ist ein: Donnerstag  (laut FncDateToWeekdayNr_Hack_10)
Der gesuchte Wochentag ist ein: Donnerstag  (laut FncDateToWeekdayNr_Hack_11)

------------------------------------------------------------------------------
# Berechnung des Julianischen Tages stur nach dem Gregorian. Kalendersystem: #
------------------------------------------------------------------------------
Umrechnung Datum nach JulianDay: 3750106  (laut FncDateToJulianDay_Hack_00)
Umrechnung Datum nach JulianDay: 3750106  (laut FncDateToJulianDay_Hack_01)
Umrechnung Datum nach JulianDay: 3750106  (laut FncDateToJulianDay_Hack_10)

        Berechneter Wochentag aus JulianDay 3750106:       Donnerstag

------------------------------------------------------------------------------
# Julian Day bis 04.10.1582 nach dem Julianischen, dann Gregorian. Kalender: #
------------------------------------------------------------------------------
        Berechnung nach dem Gregorianischen Kalender...

Umrechnung Datum nach JulianDay: 3750106  (laut FncDateToJulianDay_Hack_11)

        Berechneter Wochentag aus JulianDay 3750106:       Donnerstag

Original-Code:
  set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
  set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1
Dieser Code nur anders formatiert:
  set /a z=14-mm, z/=12, m"=(12*z) + (mm-3)", dow"=(153*m + 2)/5"  
  set /a y=yy-z + 4800, dow"=(dow + dd + y*365 + (y/4 - y/100 + y/400) -2472630)%%7 + 1"  

Gjeldende dato er: 04.03.2011
Skriv ny dato: (dd.mm.åå)
---
04.03.2011

     FOR /F "tokens=2-4 delims=/-,() skip=1" %%a in ('echo ^|date') do (

Geben Sie das neue Datum ein: (TT-MM-JJ) ECHO ist eingeschaltet (ON).
Eingegebenes Datum kann nicht übernommen werden.
Geben Sie das neue Datum ein: (TT-MM-JJ)

     FOR /F "tokens=2-4 delims=./-,() skip=1" %%a in ('echo(^|date') do (  

FOR /F "delims=DTMYJ-dtmyj" %%i in ("%DateOrder%") do set "Other=%%i"&if not defined JJ call set "JJ=%%%%i%%"  

For %%i in (INDate INTime %Other% %AllDateTimeVars%) do @if defined %%i set %%i|find /i "%%i="  

For %%i in (vbssnippet INTime INDate %Other% Other) Do Set "%%i="  

date^<nul

FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"   

REM Datumsformat “Sa 01.10.2005“
If "%indate:~5,1%" == ":" FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~5,1%" == "/" FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~5,1%" == "." FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~5,1%" == "-" FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~5,1%" == "," FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
REM Datumsformat “Fri 10/11/2013"  
If "%indate:~6,1%" == ":" FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~6,1%" == "/" FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~6,1%" == "." FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~6,1%" == "-" FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~6,1%" == "," FOR /F "tokens=2" %%i in ("%INDate%") do Set "INDate=%%i"  
REM Datumsformat “2013-10-10 ???“ (??? sind 3 chinesische Zeichen)
If "%indate:~4,1%" == ":" FOR /F "tokens=1" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~4,1%" == "/" FOR /F "tokens=1" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~4,1%" == "." FOR /F "tokens=1" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~4,1%" == "-" FOR /F "tokens=1" %%i in ("%INDate%") do Set "INDate=%%i"  
If "%indate:~4,1%" == "," FOR /F "tokens=1" %%i in ("%INDate%") do Set "INDate=%%i"