Batch einzelne zeilen aus einer txt.datei in jeweils verschiedene variablen schreiben

Guten Tag,
Ich sitze grad an einem Projekt von mir (Eine bat zum verschlüsseln und entschlüsseln von Buchstaben)
Mein Problem ist das ich nicht weiß wie man einzelne Zeilen aus einer txt Datei auslesen kann.
:Datei
@echo off
title Data encriptor made by MR for %name%
set Dataname=
set /p Dataname= Put the name of your locked txt here:
title Data encriptor made by MR for %name% Data: Name %Dataname%
set Zeile=
set /p Zeile= Hier Zeile eingeben:
1. %Zeile % soll aus %Dataname% ausgelesen werden.
2. dann soll das was in der Zeile steht in eine Variable gepackt werden
set InhaltZeile1=
set /p InhaltZeile1=: %Zeile1%
Da ich dazu nichts mir verständliches gefunden habe frage ich euch.
Wenn du die ganze bat sehen möchtest einfach antworten!
Danke im voraus bin noch neu.


LG von Manuel
ich hoffe auf schnelle Antwort

@echo off &setlocal
set "txtfile=test.txt"  

for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%txtfile%"') do (  
  echo Zeile %%i: %%j
)
pause

@echo off &setlocal
set "txtfile=test.txt"  

for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%txtfile%"') do (  
  set /a "n=%%i"  
  set "line[%%i]=%%j"  
)

echo Es wurden %n% Zeilen gelesen
echo Zeile 1 ist: %line[1]%
echo(
echo Alle gelesenen Zeilen:
setlocal EnableDelayedExpansion
for /l %%i in (1 1 %n%) do (
  echo !line[%%i]!
)
pause