Batch Schleife, welche die Prozesse prüft

Guten Tag,

ich komme nicht ganz mit for schleifen in batches klar und möchte folgendes, was bereits funktioniert aber sehr simpel gehalten ist in eine for schliefe basteln:

:prozesspruefung
																															echo Installationsprozess
																															tasklist | find /i "setup.exe">nul && goto prozesspruefung  
																															echo Installation zu Ende

also ich möchte prüfen ob ein prozess noch läuft und in dem fall nichts machen oder nur ausgeben, dass der prozess noch läuft, sobald dieser fertig ist, soll es in der bat weitergehen.

danke für die hilfe!

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 216576

Url: https://administrator.de/forum/batch-schleife-welche-die-prozesse-prueft-216576.html

Ausgedruckt am: 11.04.2025 um 17:04 Uhr

5 Kommentare

Neuester Kommentar

Hallo ChrisDynamite,

was funktioniert an deiner Lösung nicht / was stört dich?

Um es vorab zu sagen: Du kannst diese Prüfung nicht per Endlos-FOR /L-Schleife in Batch durchführen, da diese nicht abbrechbar sein würde.

Grüße
rubberman

Hi,

Das wäre doch abbrechbar, oder? Wenn in einer der "Möglichkeiten" exit steht ? Oder gibt´s kein exit in der Batch ?

Grüße
Exze

Hallo Exzellius.

Tatsächlich ist ein EXIT die einzige Möglichkeit aus einer solchen Schleife herauszukommen. Ist aber denke ich nicht anwendbar, da der cmd.exe Prozess damit terminiert wird. Ich gehe davon aus dass nach der Schleife aber noch was folgen soll, sonst wäre die ganze Aktion reichlich sinnlos.

Grüße
rubberman

Guten Tag,

vielen Dank für die Hilfe. Ich habe jetzt meine Variante siehe oben benutzt auch wenn ich kein GOTO Freund bin. Es scheint aber wirklich so zu sein, als dass Batch nur Zählschleifen hergibt.

Der Hintergrund warum ich das mache:

ich installiere per Batch Programme per Startscript auf Computer. Wenn ich eine "normale" Exe habe ist das auch kein Problem. Dumm wirds, wenn eine Exe unterexen oder eine msi danach öffnet.

wenn ich call programmname schreibe wird dann die 1. exe gestartet und diese startet dann eine 2. oder eine msi und mein skript läuft weiter auch wenn die installation noch nicht fertig ist.

mit der goto schleife oben prüfe ich, ob die exe noch in der tasklist steht und so lange soll die schleife sinnlos rennen, bis sie nicht mehr in der tasklist steht. dann läuft das skript auch dann weiter, wenn die exe vorüber ist.

Hallo ChrisDynamite.

auch wenn ich kein GOTO Freund bin

Kann ich teilweise verstehen. Bestimmte Schleifenvarianten (so etwas wie WHILE) lässt sich aber am einfachsten mit GOTO umsetzen. Zugegeben ist aber der Bau solcher Schleifen auch die einzige Anwendung, für die man GOTO wirklich benötigt (neben GOTO :EOF). Jede andere Anwendung resultiert meistens in Spaghetticode.

Es scheint aber wirklich so zu sein, als dass Batch nur Zählschleifen hergibt.

Nee, so schlimm ist es dann auch wieder nicht

Die Hilfe zu FOR gibt dir da schon ein paar Anwendungsgebiete mehr aus.

Ich gebe dir mal noch eine Möglichkeit auf den Weg, die ohne GOTO auskommt. (Eigentlich wollte ich nicht, weil es den Aufwand nicht wert ist.) Verwendet wird sowohl die oben genannte Endlos-FOR /L-Schleife, als auch das EXIT um diese zu verlassen. Trick: Die Schleife muss in einer weiteren CMD Instanz laufen.

@echo off &setlocal

REM ruft Subroutine :while auf (nach Selbstaufruf in Zeile 12)
if "%~1"==":while" call %~1  

REM Prozess definieren (Notepad als Test)
set "process=notepad.exe"  
REM Prozess asynchron aufrufen
start "" "%process%"  

REM neue CMD-Instanz mit Argument ":while" aufrufen  
cmd /c "%~f0" :while  

echo Notepad wurde geschlossen.

pause
exit /b

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:while
REM Endlosschleife (ist nur per EXIT abbrechbar)
for /l %%# in (0) do (
  REM EXIT wird ausgeführt, wenn der Prozess beendet wurde
  tasklist /fi "imagename eq %process%" | >nul findstr /bic:"%process%" || exit  
  echo Prozess laeuft ...
  REM 1 Sekunde Timeout, um die Prozessorlast zu minimieren
  >nul timeout /t 1 /nobreak
)