Batch um mehrere IP-Adressen via Ping auf Erreichbarkeit zu prüfen

Hallo liebe Administratoren Gemeinde.

Ich muss ganz viele IP-Adressen auf Erreichbarkeit prüfen und protokollieren. Ich darf keine Tools benutzen, also benutze ich eine batch.
Die einfachste Methode ist ein zyklischer Ping der im Loop über die Liste der IP-Adressen geht. Dazu gibt es hier viele nützliche Beiträge, leider komme ich mit keinem wirklich weiter (oder ich finde nicht den richtigen...). Die IP Adressen befinden sich in einer Datei namens ip.list und sehen so aus:

10.100.8.10
10.100.8.11
10.100.8.12
...

Ich habe hier im Forum ein super Skript gefunden um EINE IP-Adresse zu prüfen. Das klappt auch wunderbar wenn ich eine IP als fester Parameter in die batch eintrage.

set "IP=10.100.8.10"
:start
set "Erfolg=NEIN"
set "Zeit="
for /f "tokens=7 delims==< " %%i in ('ping -n 1 %IP%^|findstr "TTL"') do set "Zeit= - %%i" && set "Erfolg=JA"
goto start

Das Ergebnis in der result.log sieht so aus:

10.100.8.10 - 27/04/2016- 8:28:05.73 - JA - 35ms
10.100.8.10 - 27/04/2016- 8:28:05.87 - JA - 33ms
10.100.8.10 - 27/04/2016- 8:28:06.01 - JA - 33ms

Perfekt, genau wie ich es haben will. Nun muss ich nichts weiter tun, als die IP-Adresse aus der ip.list auslesen und der FOR-Schleife übergeben.
Dazu benutze ich eine weitere FOR-Schleife:

:start
FOR /f %%f IN (ip.list) DO (
set "Erfolg=NEIN"
set "Zeit="
for /f "tokens=7 delims==< " %%i in ('ping -n 1 %%f^|findstr "TTL"') do set "Zeit= - %%i" && set "Erfolg=JA"
)
goto start

Ganz schlicht. Leider funktioniert das nicht. Das Ergebnis in der result.log sieht so aus:

10.100.8.10 - 27/04/2016- 8:34:26.15 -
10.100.8.11 - 27/04/2016- 8:34:26.15 -
10.100.8.12 - 27/04/2016- 8:34:26.15 -
10.100.8.13 - 27/04/2016- 8:34:26.15 -

Wie man sieht, werden die IP-Adressen richtig übergeben, aber die Parameter %Erfolg% und %Zeit% gehen "verloren", oder werden einfach nicht gesetzt... Versuche seit zwei Tagen das Problem zu lösen, mit Schreibweise in einer Zeile, Klammern an verschiedenen Stellen, mit TABs arbeiten usw. Hab hier auch einige verschachtelte scripts gefunden und folgendes versucht:

:start
FOR /f %%f IN (ip.list) DO (
set "Erfolg=NEIN"
set "Zeit="
setlocal enabledelayedexpansion
for /f "tokens=7 delims==< " %%i in ('ping -n 1 %%f^|findstr "TTL"') do set "Zeit= - %%i" && set "Erfolg=JA"
endlocal
)
goto start

Wobei ich sagen muss, dass ich das enabledelayedexpansion und endlocal nicht verstehe. Wie auch immer, das Ergebnis ist das gleiche...
Kann mir jemand sagen, was ich falsch mache?

Vielen Dank im Voraus.

Gruß,
GalinDiesel

@echo off
:start
FOR /f %%f IN (ip.list) DO (
set "Erfolg=NEIN"  
set "Zeit="  
for /f "tokens=7 delims==< " %%i in ('ping -n 1 %%f^|findstr "TTL"') do set "Zeit= - %%i" && set "Erfolg=JA"  
>>result.log echo %%f - %date%-%time% - %Erfolg%%Zeit%
)
goto start

1xx.xx.xx.xx8 - 27.04.2016-10:06:54,65 - JA - 1ms
1xx.xx.xx.xx0 - 27.04.2016-10:06:54,65 - JA - 1ms
1xx.xx.xx.xx1 - 27.04.2016-10:06:54,65 - JA - 1ms
1xx.xx.xx.xx8 - 27.04.2016-10:06:54,72 - JA - 1ms
1xx.xx.xx.xx0 - 27.04.2016-10:06:54,72 - JA - 1ms

1xx.xx.xx.xx8 - 27.04.2016-10:06:54,38 - 
1xx.xx.xx.xx0 - 27.04.2016-10:06:54,38 - 
1xx.xx.xx.xx1 - 27.04.2016-10:06:54,38 - 

@echo off
setlocal enabledelayedexpansion

:start
FOR /f %%f IN (ip.list) DO (
set "Erfolg=NEIN"  
set "Zeit="  
for /f "tokens=7 delims==< " %%i in ('ping -n 1 %%f^|findstr "TTL"') do (  
set "Zeit= - %%i"  
set "Erfolg=JA"  
)
>>result.log echo %%f - %date%-%time% - !Erfolg!!Zeit!
)
goto start

setlocal enabledelayedexpansion