Netzlaufwerk nach zu langen Pfaden durchsuchen

@echo off
title Suche nach zu langen Dateipfaden
cd\
set lang=240

cls
echo -------------------------------------------------------------------
echo Netzlaufwerk auswählen
echo -------------------------------------------------------------------
echo.
echo Überprüft die Länge ab %lang% Zeichen
echo.
echo    (1) Laufwerk P
echo    (2) Laufwerk Q
echo    (3) Laufwerk R
echo    (0) Exit
echo.
set /p _choice=Aktion waehlen:

if %_choice%==1 goto Laufwerk_P
if %_choice%==2 goto Laufwerk_Q
if %_choice%==3 goto Laufwerk_R
if %_choice%==0 goto exit


:exit
exit

:Laufwerk_P
set LW=p:
goto Auswertung

:Laufwerk_Q
set LW=q:
goto Auswertung

:Laufwerk_R
set LW=r:
goto Auswertung


:Auswertung
::---------begin ofFindLongPath.bat -------
:: Aufruf FindLongPath [Lw:/Pfad] [Pfadlänge] -- Default Lw:/Pfad=%temp% -- Default Pfadlänge = 50
::@ECHO off & SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEEXTENSIONS
SET usedvars=tmpdatei reportdatei p1 p1masked p2 x YN PAUSE_D ECHO_D 
if Defined DebugMyBatches ((set ECHO_D=@ECHO) & (set PAUSE_D=pause) ) else ( set ECHO_D=REM)
REM call :Debugshow_vars "Am Start der Batchdatei" ...bei Bedarf das REM entfernen  
CALL :paramcheck %1 %2
:: Nicht einfach weiterlesen... hast Du geguckt, was in :paramcheck passiert???
DIR %p1% /aD /b /s >%tmpdatei%
IF exist "%reportdatei%" del "%reportdatei%"   
SET /a p2=%p2%-1
SETLOCAL EnableDelayedExpansion
FOR /F "delims=" %%i in (%tmpdatei%) do (set "x=%%i") && if "!x:~%p2%,10!" GTR "@" @echo %%i >>%reportdatei%  

IF EXIST "%reportdatei%" (  
     ECHO Report wurde gespeichert als %reportdatei%.   
     ECHO - Reportdatei vom %date% -- Alle Verzeichnisse ^>%p2% auf %p1% -->>"%reportdatei%"   
     ECHO - Reportdatei "%reportdatei%" -->>"%reportdatei%"  
     SET /p YN="Auf %p1% wurden Pfade mit Länge größer %p2% gefunden. Anzeigen (J/N?) "  
     IF /i "!YN!"=="J" TYPE "%reportdatei%" |MORE       
) ELSE (
     ECHO Keine Pfade länger als %p2% Zeichen im Pfad %p1% gefunden.
)
ENDLOCAL
CALL :DebugShow_vars
::CALL :cleanup
GOTO :eof
:: -------------------
::::::::::::  ParamCheck ... Hier werden die Parameter %1 und %2 geprüft daraus %p1% und %p2% abgeleitet.
:: Param 1 : Laufwerksbuchstabe oder Verzeichnis; Default %temp%
:::::::::::: Dieser Parameter wird als Substring in den Variablen %tmpdatei% und %reportdatei% verwendet 
:::::::::::: Dafür werden ":" und "\" durch "$" und"_" ersetzt, um einen gültigen Dateinamen zu bilden. 
:::::::::::: dazu Zwischenspeicherung in Variable %p1% und %p1masked% 
:::::::::::: Syntax dazu siehe SET /? und dort.. %PATH:str1=str2%
:: Param 2:: zu prüfende Länge der Verzeichnisse ... Default 50

:ParamCheck
IF (%1)==() (SET p1=%temp%) ELSE (SET p1=%1)
REM nächste Zeile bipede-Variante - siehe unten
IF (%1)==() (SET p1=%LW%) ELSE (SET p1=%1)
IF (%2)==() (SET /a p2=%lang%) ELSE (SET /a p2=%2)
SET p1masked=%p1::=$%
SET p1masked=%p1masked:\=_%
%ECHO_D% p1-^>p1masked ist %p1%-^>%p1masked%; p2 ist %p2%
::SET "tmpdatei=%temp%\%computername%_%p1masked%_All.lst" 
::SET "Reportdatei=%temp%\%computername%_%p1masked%_PfadeGTR%p2%.lst" 
SET "tmpdatei=e:\%computername%_%p1masked%_All.lst"  
SET "Reportdatei=e:\%computername%_%p1masked%_PfadeGTR%p2%.lst"  
CALL :Debugshow_vars "Nach Var-Setzen"  
goto :eof
:: --------------------
:DebugShow_vars
IF DEFINED DebugMyBatches (
SETLOCAL ENABLEDELAYEDEXPANSION
FOR %%i IN (%usedvars%) DO (ECHO [%~1] Variable %%i="!%%i!" )   
ENDLOCAL
PAUSE
)
GOTO :eof
:: -----------------
:cleanup
%ECHO_D% in Subroutine :Cleanup
::IF EXIST "%tmpdatei%" (del "%tmpdatei%") & %ECHO_D% Datei %tmpdatei% wird gelöscht. 
FOR %%i IN (%usedvars% usedvars) DO @IF DEFINED %%i (
  (IF DEFINED DebugMyBatches echo %%i wird freigegeben) & (SET %%i=))

GOTO :eof
::---------End of FindLongPath.bat -------