Netzwerkkarte Variable zuweisen

Hallo liebes Forum

Ich versuche nun schon seit einigen Tagen in Batch die Netzwerkkarten automatisch mit einer automatisch zugewiesenen Variable auszugeben, damit ich nicht den ganzen Namen eingeben muss. Das ganze habe ich mir etwa folgendermassen vorgestellt:

Die Netzwerkkarten werden gescannt und ihnen wird eine Variable mit z.B. 1 und der Nächsten dann 2 zugewiesen. dann kann man die Karte mit der Zahl 1 auswählen.
In Batch stelle ich mir es etwa so vor

Variable...................................................Netzwerkkartenname
1...............................................................Netzwerkkarte-x
2...............................................................Netzwerkkarte-y
3...............................................................Netzwerkkarte-z

Ich hoffe auf eine hilfreiche Antwort

-Patrick

@echo off & setlocal enabledelayedexpansion
set /a cnt=1
for /f "tokens=2 delims==" %%a in ('wmic nic where ^(NetEnabled ^= True^) get Description /format:list ^| findstr "Description"') DO @(  
	set "nic!cnt!=%%a"  
	echo [!cnt!] %%a
	set /a cnt+=1
)
echo.
set /p num=Bitte die Karte waehlen:
echo Sie haben folgende Auswahl getroffen: !nic%num%!

@echo off & setlocal enabledelayedexpansion
set /a cnt=1
for /f "tokens=2 delims==" %%a in ('wmic nic where ^(NetEnabled ^= True^) get NetConnectionID /format:list ^| findstr "NetConnectionID"') DO @(  
	set "nic!cnt!=%%a"  
	echo [!cnt!] %%a
	set /a cnt+=1
)
echo.
set /p num=Bitte die Verbindung waehlen:
echo Sie haben folgende Auswahl getroffen: !nic%num%!