Outlook Besprechung - Skript zum Einfügen von Standarddaten

ActiveInspector.CurrentItem.Start

ActiveInspector.CurrentItem.Location

Sub InsertStandardAppointmentBody()
    ' Variablen  
    Dim cInspector As Inspector, regex As Object, strClientName As String, strMessageType As String, strDate As String
    ' Objekte initialisieren  
    Set regex = CreateObject("vbscript.regexp")  
    regex.IgnoreCase = True
    ' aktiven Inspector finden  
    Set cInspector = Application.ActiveInspector
    If cInspector Is Nothing Then
       MsgBox "Kein Element offen!", vbExclamation  
       Exit Sub
    End If
    ' mit aktivem Element im Inspector arbeiten  
    With cInspector.CurrentItem
        ' elemente aus dem Subject mit Regex extrahieren  
        regex.pattern = "([^\s]+) für (.*)$"  
        ' regex pattern anwenden  
        Set match = regex.Execute(.subject)
        ' Fallback für Nutzername und Messagetype  
        strClientName = "User"  
        strMessageType = "Gespräch"  
        ' Wenn Regex-Match erfolgreich war  
        If match.Count > 0 Then
            ' Submatch 2 aus dem Regex dem Namen zuweisen  
            strClientName = match(0).submatches(1)
            ' Submatch 1 aus dem Regex dem Typen der Nachricht zuweisen  
            strMessageType = match(0).submatches(0) & "gespräch"  
        End If
        ' Standard-Datum formatieren  
        strDate = Format(.Start, "dddd, \d\e\n dd. mmmm \u\m hh:nn \U\h\r")  
        ' wenn das Datum heute ist formatiere das Datum um  
        If DateValue(.Start) = Date Then
            strDate = "heute um " & Format(.Start, "hh:nn")  
        End If
        ' Fülle den Inhalt des Bodies aus  
        .Body = "Hallo " & strClientName & "." & vbNewLine & vbNewLine & _  
                "hiermit erhalten sie die Einladung zu einem Zoom-Meeting für ein " & strMessageType & " mit Max Mustermann." & vbNewLine & vbNewLine & _  
                "Das Gespräch findet " & strDate & " statt." & vbNewLine & _  
                .Location & vbNewLine & vbNewLine & _
                "Herr Mustermann freut sich auf das gemeinsame Gespräch." & vbNewLine & vbNewLine & _  
                "Mit besten Grüßen"  
    End With
End Sub