Sverweis mit mehreren Ergebnissen

Ich habe eine Excel-Tabelle.
Diese Tabelle hat 2 Spalten.

In der ersten finden sich verschiedene Namen, in der zweiten bspw. punktzahlen. Die Namen können öfters mit verschiedenen Punktzahlen vorkommen.

Spalte A ---------- Spalte B

Klaus ------------- 15
Peter -------------- 20
Rainer ------------ 5
Klaus ------------- 30
Holger ------------ 23

in einer zweiten tabelle findet sich nur der name(spalte d) und es soll die gesamtpunktzahl(spalte e) mittels sverweis ermittelt werden

Spalte D ----------- Spalte E

Klaus ------------- 45
Peter -------------- 20
Rainer ------------ 5
Holger ------------ 23

Es soll also die Spalte D in Spalte A gesucht werden und die Ergebnisse aus Spalte B addiert und in Spalte E eingefügt werden.

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 152416

Url: https://administrator.de/forum/sverweis-mit-mehreren-ergebnissen-152416.html

Ausgedruckt am: 23.12.2024 um 07:12 Uhr

7 Kommentare

Neuester Kommentar

Hallo fcmfanswr!

"SVERWEIS()" ist dafür das falsche Werkzeug - verwende "SUMMEWENN()" ...

Grüße
bastla

Hallo fcmfanswr,

folgender Vorschlag:

        Spalte A
Zeile 1 Klaus
      2 Peter
      3 Rainer
      4 Klaus
      5 Holger

        Spalte B
Zeile 1 15
      2 20
      3 5
      4 30
      5 23

        Spalte D
Zeile 1 =A1
      2 =WENN(ZÄHLENWENN(D$1:D1;"="&A2)=0;A2;"")
      :
      5 =WENN(ZÄHLENWENN(D$1:D4;"="&A5)=0;A5;"")

        Spalte E
Zeile 1 =WENN(NICHT(D1="");SUMMEWENN(A$1:A$5;"="&A1;B$1:B$5);"")
      :
      5 =WENN(NICHT(D5="");SUMMEWENN(A$1:A$5;"="&A5;B$1:B$5);"")

Ausgabe:

        Spalte D
Zeile 1 Klaus
      2 Peter
      3 Rainer
      4
      5 Holger

        Spalte E
Zeile 1 45
      2 20
      3 5
      4
      5 23

Für doppelt vorkommende Namen wird eine Leerzeile erzeugt.

Gruß
Friemler

Super, vielen Dank.

Jetzt kommt noch eine Problematik hinzu.
Es kommt eine weitere Spalte hinzu, inder zu jedem namen noch ein buchstabe steht.

Spalte A

Zeile 1 Klaus

2 Peter

3 Rainer

4 Klaus

5 Holger

Spalte B

Zeile 1 15

2 20

3 5

4 30

5 23

Spalte C

Zeile 1 a

2 b

3 c

4 b

5 a

Ich möchte nun die möglichkeit haben die selektion noch nach 1 oder 2 kriterien aus spalte c zu beschränken. heißt also, wenn ich "a" eingebe, dann sollen immer nur die namen berücksichtigung finden bei dehen in spalte C ein "a" steht und nur dessen zahlen in spalte e errechnet werden. wenn ich zwei kriterien eingeben, also z.b. "a" und "b" dann sollen allen namen mit a oder b berücksichtigt werden.

die eingabe meiner kriterien erfolgt in eine beliebige zelle, sagen wir H1 und H2.

Das ist alles super kompley, aber ich hoffe ihr versteht, was ich meine und könnt mir helfen!?

Hallo fomfanswr!

Ohne "Behübschung" könnte die Formel für E1 (für D1 kannst Du die bisherige Formel beibehalten) so aussehen:

=SUMME((D1=$A$1:$A$5)*$B$1:$B$5*VORZEICHEN(($H$1=$C$1:$C$5)+($H$2=$C$1:$C$5)))

Bei der Ersteingabe, aber auch bei jeder Änderung dieser Formel ist (da es sich um eine "Array"-Formel handelt) zum Abschluss die Tastenkombination Strg + Umsch + Enter zu verwenden - in der Bearbeitungsleiste wird diese Formel dann (zur Kennzeichnung) innerhalb von geschwungenen Klammern angezeigt.

Kurze Erklärung: Jeder Klammerausdruck innerhalb der Summenformel wird ausgewertet und liefert entweder 1 oder 0 - damit dies bei irrtümlicher Eingabe zweier gleicher Werte in H1 und H2 (würde dann ja 2 ergeben) auch noch zutrifft, wird das Ergebnis dieser Überprüfung mithilfe der "VORZEICHEN()"-Funktion auf 1 oder 0 reduziert. Die Multiplikation (da UND-Verknüpfung) dieser Prüf-Ergebnisse miteinander und mit dem jeweiligen Wert aus der Spalte B ergibt entweder diesen Wert oder 0, sodass in der Summe nur die Werte jener Zeilen enthalten sind, in welchen der Name aus Spalte D und eines der beiden Kriterien aus H1 und H2 vorkommen.

Grüße
bastla

Moin fcmfanswr,

ergänzend zu bastlas Matrixkrams hier eine Lösung mit der VERGLEICH()-Funktion, die auch bei mir gemäß deiner Vorgabe in den Feldern $H$1 und $H$2 zwei Zusatz-Kriterien berücksichtigt.

Ebenfalls vorgesehen für Zeile E1:E5--> die Spalte D kann so bleiben.

=WENN(NICHT((D1="")+ISTNV(VERGLEICH(C1;$H$1:$H$2;0)));SUMMEWENN(A$1:A$5;"="&A1;B$1:B$5);"")

Sieht auch relativ unwartbar aus - Einziger kleiner Vorteil ist, das bei der VERGLEICH-Funktion einfach aus jetzt 2 Kriterien (H1:H2) auch 3 (H1:H3) oder 4 .... gemacht werden könnten, falls mal nach "a" oder "b" oder "c" gesucht werden soll.

Grüße
Biber

@ bastla

Vielen Dank, diese Lösung ist perfekt. Vielen Dank auch für die nette Erklärung. und auch hier ist es ja möglich weitere Kriterien hinzuzufügen.

Ich bin immer wieder erstaunt, wieviel man mit den Formeln lösen kann ohne ein Macro zu programmieren.
Nur muss ich auch gestehen, das es mir immer schwer fällt die Formeln nachzuvollziehen und ich frage mich jedes mal, wie ihr darauf kommt solche Formeln zu bauen!?

Viele Grüße

@ Biber

Vielen Dank auch für deine Lösung.
Da bastla's Lösung funktioniert habe ich mir deine nur kurz angeschaut und wenn ich es richtig gesehen habe funktioniert diese nur wenn alle kriterien gefüllt sind, ist h1 nicht gefüllt aber h2, dann kommt kein ergebnis, oder?

Interessant zu sehen, dass es für dieses Problem sogar mehrere Lösungsformeln gibt.

Viele Grüße

Moin fcmfanswr,

Zitat von @fcmfanswr:

... und ich frage mich jedes mal, wie ihr darauf kommt solche Formeln zu bauen!?

Hat etwas mit der Absetzung von Medikamenten ohne ärztliche Erlaubnis zu tun...

Da bastla's Lösung funktioniert habe ich mir deine nur kurz angeschaut und wenn ich es richtig gesehen habe funktioniert
diese nur wenn alle kriterien gefüllt sind, ist h1 nicht gefüllt aber h2, dann kommt kein ergebnis, oder?

Ja, stimmt schon... ich hatte gestern nicht mehr so viel Lust zum Erläutern.
Aber ich war ja auch erst Stunden nach bastla auf dem Plan. *gg

Also: die Felder dürfen nicht leer sein, das war mir gestern auch bewusst.
Damit würde ich allerdings auch klarkommen, wenn jeweils in den (theoretisch nutzbaren) Kritienfeldern bei allen nicht genutzten Kriterien ein Text "--" oder "-kein Kriterium-" oder "@" steht.

Interessant zu sehen, dass es für dieses Problem sogar mehrere Lösungsformeln gibt.

Öfter allerdings ist es umgekehrt - bei einer Lösungsformel existieren mehrere Probleme..