Textdateien öffnen, Suchmuster finden, dahinter eine Zeile einfügen, abspeichern

@echo off & setlocal
set "Ordner=D:\Test"  
set "Dateien=*.txt"  
set "Suchbegriff=dieser-text-ist-immer-gleich"  
set "Zusatzzeile=DIE NEUE ZEILE"  

set "IL=%temp%\InsertLine.vbs"  
echo Set args = WScript.Arguments:Set fso=CreateObject("Scripting.FileSystemObject")>%IL%  
echo T=fso.OpenTextFile(args(0)).ReadAll:P=InStr(1,T,args(1),vbTextCompare):If P=0 Then WScript.Quit 1 >>%IL%
echo P=InStr(P,T,vbCrLF):If P^<^>0 Then fso.CreateTextFile(args(0)).Write Left(T,P-1)^&vbCrLF^&args(2)^&Mid(T,P)>>%IL%

for %%i in ("%Ordner%\%Dateien%") do cscript //nologo %IL% "%%i" "%Suchbegriff%" "%Zusatzzeile%" || echo Keine Ersetzung in "%%i"  

@echo off & setlocal
set "Ordner=D:\Test"  
set "Dateien=*.ghtml"  
set "Suchbegriff=Message-ID: "  
set "Zusatzzeile=x-ID: "  

if "%Ordner:~-1%"=="\" set "Ordner=%Ordner:~,-1%"  
set "IL=%temp%\InsertLine.vbs"  
echo Set args = WScript.Arguments:Set fso=CreateObject("Scripting.FileSystemObject")>%IL%  
echo T=fso.OpenTextFile(args(0)).ReadAll:P=InStr(1,T,args(1),vbTextCompare):If P=0 Then WScript.Quit 1 >>%IL%
echo P=P+Len(args(1)):P2=InStr(P,T,vbCrLF):If P2^<^>0 Then fso.CreateTextFile(args(0)).Write Left(T,P2-1)^&vbCrLF^&args(2)^&Mid(T,P,P2-P)^&Mid(T,P2) Else WScript.Quit 1 >>%IL%

for /d %%a in ("%Ordner%\*.*") do call :ProcessFolder "%%a"  
goto :eof

:ProcessFolder
for /r %1 %%i in (%Dateien%) do cscript //nologo %IL% "%%i" "%Suchbegriff%" "%Zusatzzeile%" || echo Keine Ersetzung in "%%i"  
goto :eof

@echo off & setlocal
set "Ordner=D:\Test"  
set "Dateien=*.ghtml"  
set "Suchbegriff=Message-ID: "  
set "Zusatzzeile1=x-ID: "  
set "Zusatzzeile2=durch-set-festzulegender-begriff_1: durch-set-festzulegender-begriff_2"  

if "%Ordner:~-1%"=="\" set "Ordner=%Ordner:~,-1%"   
set "IL=%temp%\InsertLine.vbs"  

>%IL%  echo Set args=WScript.Arguments
>>%IL% echo Set fso=CreateObject("Scripting.FileSystemObject")  
>>%IL% echo T = fso.OpenTextFile(args(0)).ReadAll
>>%IL% echo P = InStr(1, T, args(1),vbTextCompare)
>>%IL% echo If P = 0 Then WScript.Quit 1
>>%IL% echo P = P + Len(args(1))
>>%IL% echo P2 = InStr(P, T, vbCrLF)
>>%IL% echo If P2^<^>0 Then
>>%IL% echo     fso.CreateTextFile(args(0)).Write _
>>%IL% echo         Left(T, P2 - 1) ^& vbCrLF _
>>%IL% echo         ^& args(2) _
>>%IL% echo         ^& Mid(T, P, P2-P) ^& vbCrLF _
>>%IL% echo         ^& args(3) _
>>%IL% echo         ^& Mid(T, P2)
>>%IL% echo Else
>>%IL% echo     WScript.Quit 2
>>%IL% echo End If

for /d %%a in ("%Ordner%\*.*") do call :ProcessFolder "%%a"  
goto :eof

:ProcessFolder
for /r %1 %%i in (%Dateien%) do (
    cscript //nologo %IL% "%%i" "%Suchbegriff%" "%Zusatzzeile1%" "%Zusatzzeile2%"  
    if errorlevel 1 echo Keine Ersetzung in "%%i"  
)
goto :eof