Textfelder aus Textfile jeweils einzeln in einen Datensatz einlesen

Liebe Administrator-Gemeinde,

ich muss aus einer Edifact-Datei (Textfile) Daten in eine Access-Tabelle importieren.

Beispiel des Aufbaus der Edifact-Datei:
'ABC:123'DEF:456'GHI789'JKL125lk'MNO+:adf45'PIA+5+F50:SA:108:91'PIA+5+F50:SA:108:92'IMD+E++:108' .........
...............'ABC:123'DEF:789'GHI345'JKL204lk'MNO+:cdk76'.....................................................................................................

Die einzelnen Datenfelder sind also durch ein Hochkomma (') getrennt und werden ohne Zwischenraum und ohne Zeilenumbruch aneinandergefügt.
Die Dateien enthalten weit über 10.000 Zeilen.
Um diese Daten einigermaßen lesbar zu machen, sollen die Datenfelder in eine Access-Tabelle (tabImport) derart importiert werden, dass die einzelnenDatenfelder in einer einzigen Spalte jeweils als neuer Datensatz erscheinen.

Also So: ID Spalte
1 'ABC:123
2 'DEF:456
3 'GHI789
4 'JKL125lk
5 ............
6 .............

Hab das Problem schon auf verschiedene Weise zu lösen versucht, bin aber noch auf keine brauchbare Lösung gestoßen.
Die Misere liegt darin, dass Access beim Textimport zwar automatisch das Hochkomma(') als Feldtrennzeichen erkennt, ich aber bisher noch keine Funktion gefunden habe, die dieses Feldtrennzeichen als Zeichen für einen neuen Datensatz interpretiert.
Ersatzweise könnte man die Quelldatei vielleicht bereits vor dem Einlesen entsprechend aufbereiten (Für jedes Feld eine neue Zeile), dann klappt nämlich der Import in Access einwandfrei.

Vielleicht hat von Euch jemand eine passende Lösung parat. Ich bin für jede Anregung dankbar. Für eure Mühe bedanke ich mich im Voraus!

Const ForReading = 1
Const ForWriting = 2


If WScript.Arguments.Count > 0 Then
  Set objFSO = CreateObject("Scripting.FileSystemObject")  

  'Dateipfad in die Bestandteile Pfad, Dateiname und -erweiterung aufteilen  
  strFilePath = objFSO.GetParentFolderName(WScript.Arguments(0))
  strFileName = objFSO.GetBaseName(WScript.Arguments(0))
  strFileExt  = objFSO.GetExtensionName(WScript.Arguments(0))

  'Eingabedaei zum lesen öffnen  
  Set objInFile = objFSO.OpenTextFile(WScript.Arguments(0), ForReading, False)

  'Ausgabedatei zum schreiben öffnen  
  'Den Dateinamen dabei um "_Neu" ergänzen  
  Set objOutFile = objFSO.OpenTextFile(objFSO.BuildPath(strFilePath, strFileName & "_Neu" & "." & strFileExt), ForWriting, True)  

  'Header überlesen  
  Do While (Not objInFile.AtEndOfStream) And (objInFile.Read(1) <> "'")  
  Loop

  'Eingabedatei zeichenweise einlesen  
  'Ausgabedatei zeichenweise schreiben  
  'Wenn ein Hochkomma gelesen wurde, einen Zeilenumbruch schreiben  
  While Not objInFile.AtEndOfStream
    strChar = objInFile.Read(1)

    If strChar <> "'" Then  
      objOutFile.Write strChar
    Else
      objOutFile.Write vbCRLF
    End If
  Wend

  'Letzte Zeile der Ausgabedatei mit einem Zeilenumbruch abschließen  
  objOutFile.Write vbCRLF

  objOutFile.Close
  objInFile.Close
End If