unterschiedlichen Netzwerkadaptern immer die selbe IP zuteilen !?

Hallo!!

Habe folgendes Problem und diesbezüglich nichts konkretes im Netz gefunden.

Es geht hierbei um einen Teststand auf dem USB --> Ethernet Adapter geprüft werden sollen.
Der Testaufbau verlangt das der Netzwerkadapter immer die Selbe ip und Subnetmaks zugeteilt bekommt.
das ganze will ich per Batch Datei realisieren.
Mit "netsh" war es mir möglich mein Vorhaben umszusetzten, dachte ich zumindest.
Bis das Problem auftauchte das der Name
der Netzwerkadapter immer um eine Zahl weiter anstieg ( Lan-Verbindung, Lan-Verbindung1, etc. ) und die Batch den Netzwerkadapter nicht mehr fand.
Also fügte ich eine fortlaufende Variable hinzu die Batchüblich die vorgegebenen Werte abklapperte.

REM FOR /L %%i IN (1,1,10) DO @echo %%i
FOR /L %%i IN (1,1,10) DO netsh interface ip set address name="LAN-Verbindung %%i" source=static addr=192.168.0.2 mask=255.255.255.0


Soweit so gut, nur sollen an diesem Teststand um die 500Geräte getestet werden und das am Stück.
Wenn ich nun also von 1- 500 duchlaufen lassen müsste wäre das untragbar zeitaufwendig.
Gibt es eine möglichkeit immer nur dem aktuell aktivem Netzwerkadapter diese fixen Werte zuzuteilen??
Habe auch schon daran gedacht mehrere Batch Dateien anzulegen die jeweils nur einen kleineren Zahlenbereich durchlaufen, was aber keine wirklich schöne lösung für das
Testpersonal darstellt welches dann damit arbeiten müssen.
Wäre für jede Hilfe sehr dankbar!!

' This code configures an IP address, subnet mask and default gateway  
' for the specified connection.  
' ---------------------------------------------------------------  
' From the book "Windows Server Cookbook" by Robbie Allen  
' ISBN: 0-596-00633-0  
' ---------------------------------------------------------------  

' ------ SCRIPT CONFIGURATION ------  
strIP = Array("1.22.2.2")  
strMask = Array("255.255.255.0")  
strGatewayIP = Array("1.2.3.3")  
' ------ END CONFIGURATION ---------  
set objWMI = GetObject("winmgmts:\\.\root\cimv2")  
set colNA = objWMI.ExecQuery("Select * From Win32_NetworkAdapter WHERE NetConnectionID LIKE 'LAN%'")   
for each objNA in colNA
   set colNAConfig = objWMI.ExecQuery("ASSOCIATORS OF {Win32_NetworkAdapter.DeviceID='" & objNA.DeviceID & "'}  WHERE resultClass = win32_NetworkAdapterConfiguration")  
   for each objNAConfig in colNAConfig
      intRC = objNAConfig.EnableStatic(strIP,strMask)
      intRC2 = objNAConfig.SetGateways(strGatewayIP)
      if intRC = 0 and intRC2 = 0 then
         Msgbox "IP address configured for " & strConnection  
      elseif intRC = 1 or intRC2 = 1 then
         Msgbox "You must reboot for the changes to take effect for " & strConnection  
      else
         Msgbox "There was an error configuring IP for " & strconnection & ": " & intRC & " and " & intRC2  
      end if
   next
next