USB Stick Speicher sperren mit Ausnahme unter Windows 7 64 - baugleiche USB Sticks differenzieren!

@echo off
setlocal EnableDelayedExpansion
title USB-Ueberwachung

:config
set intervall=2
set MeinStick=3E2A2A6D
REM Die Nummer kann so ermittelt werden: wmic logicaldisk where "DriveType=2" get DeviceID, VolumeSerialNumber  
REM Beim Formatieren wird sie neu generiert und muss erneut ausgelesen werden.

:loop
cls
echo(
echo USB-Ueberwachung ist gestartet.

for /f "skip=1 tokens=1,2" %%i in ('2^>nul wmic.exe logicaldisk where "DriveType=2" get DeviceID^, VolumeSerialNumber') do (  
	set letter=%%i
	set volsn=%%j
	REM volsn könnte leer (undefiniert) sein oder nur eine Absatzmarke oder eine Nummer enthalten
	if defined volsn if "!volsn:~1!" EQU "" set volsn=  
	if "!volsn!" NEQ "" (  
		if "!volsn!" NEQ "!MeinStick!" call :auswerfen !letter! !volsn!  
		if "!volsn!" EQU "!MeinStick!" call :nichtauswerfen !letter! !volsn!  
	)
)

:abwarten
if defined intervall timeout %intervall%
if not defined intervall echo %time%
goto loop

:ende
exit /b

:nichtauswerfen
echo(
echo Mein Stick %1 hat die SN %2
echo Der darf bleiben.
goto :eof

:auswerfen
echo(
echo Ein fremder Stick %1 mit der SN %2 wurde erkannt.
echo Er wird jetzt ausgeworfen...
REM **************************************
REM Hier kommt ein externes Tool ist Spiel
REM http://www.freeeject.com/
REM Die Ausgabe des Tool wird mit ">nul 2>&1" unterdrückt.  
>nul 2>&1 FreeEject.exe %i
REM **********************
goto :eof

fsutil fsinfo ntfsinfo LW:

C:\>fsutil fsinfo ntfsinfo h:
NTFS-Volumeseriennummer :          0x01d1dc764faf3870

C:\>fsutil fsinfo volumeinfo h:
Volumeseriennummer : 0x4faf3870

C:\>wmic logicaldisk where "DriveType=2" get DeviceID, VolumeSerialNumber
DeviceID  VolumeSerialNumber
H:        4FAF3870

``(H:)``

@echo off
setlocal EnableDelayedExpansion
title USB-Ueberwachung

:config
set intervall=2
set MeinStick=5C6D4532
set Logfile=C:\Temp\USB.txt

REM Die Nummer für MeinStick kann so ermittelt werden: wmic logicaldisk where "DriveType=2" get DeviceID, VolumeSerialNumber  
REM Beim Formatieren wird sie neu generiert und muss erneut ausgelesen werden.

:pruefung
if defined Logfile echo %date% %time:~0,-3% Die Wechseldatenträgerprüfung wurde ausgelöst.>> %Logfile%
cls
echo(
echo Alle Wechseldatentraeger werden geprueft.

for /f "skip=1 tokens=1,2" %%i in ('2^>nul wmic.exe logicaldisk where "DriveType=2" get DeviceID^, VolumeSerialNumber') do (  
	set letter=%%i
	set volsn=%%j
	REM volsn könnte leer (undefiniert) sein oder nur eine Absatzmarke oder eine Nummer enthalten
	if defined volsn if "!volsn:~1!" EQU "" set volsn=  
	if "!volsn!" NEQ "" (  
		if "!volsn!" NEQ "!MeinStick!" call :auswerfen !letter! !volsn!  
		if "!volsn!" EQU "!MeinStick!" call :nichtauswerfen !letter! !volsn!  
	)
)

:ende
if defined Logfile echo(>> %Logfile%
REM Im Betrieb muss PAUSE auskommentiert werden, damit die Batch sich selbstätig benden kann.
PAUSE
exit /b

:nichtauswerfen
if defined Logfile echo %date% %time:~0,-3% Der zugelassene USB-Stick %2 ist jetzt als Laufwerk %1 bereit.>> %Logfile%
echo(
echo Mein Stick %1 hat die SN %2
echo Der darf bleiben.
goto :eof

:auswerfen
if defined Logfile echo %date% %time:~0,-3% Ein unzulässiger USB-Stick %2 wird jetzt ausgeworfen.>> %Logfile%
echo(
echo Ein fremder Stick %1 mit der SN %2 wurde erkannt.
echo Er wird jetzt ausgeworfen...
REM **************************************
REM Hier kommt ein externes Tool ist Spiel
REM http://www.freeeject.com/
REM Die Ausgabe des Tool wird mit ">nul 2>&1" unterdrückt.  
REM >nul 2>&1 FreeEject.exe %1
>nul 2>&1 FreeEject.exe I:
if errorlevel 2 (
	if defined Logfile echo %date% %time:~0,-3% ERROR: Ein Fehler trat auf beim Versuch den Datentraeger auszuwerfen.>> %Logfile%
	echo Ein Fehler trat auf beim Versuch den Datentraeger auszuwerfen.
)

REM **********************
goto :eof