Zahlen aus einer .txt-Datei sortieren und erneut abspeichern

Hallo zusammen,

eine Frage an dieses Forum, weil ich so langsam verzweifle. Ich bin blutiger Anfänger und habe alles was ich bisher kann aus diesem Forum gelernt. Dafür mal herzlichen Dank.

Nun habe ich allerdings folgendes problem (bitte nicht steinigen, wenn es für Euch kein Problem darstellt):
Ich möchte eine .txt-Datei auslesen und sortiert eneut abspeichern. Meine .txt-Datei enthält nur Zahlen, die bei meiner Sortiermethode Ziffernweise sortiert werden. Ich möchte aber die komplette Zahl sortiert darstellen.
Bsp.:
Ausgangsdatei (result.txt) mit
150
150
700
90
1
8
7

wird mit meiner Batch so dargestellt/sortiert und in die Datei sort.txt geschrieben:
1
150
150
7
700
8
90

so sollte es nach meinen Vorstellungen eigentlich aussehen:
1
7
8
90
150
150
700


mein Batch sieht folgendermaßen aus:
echo off &setlocal enabledelayedexpansion
set Ziel1=result.txt
for /f "usebackq tokens=1 delims= " %%a in ("%Ziel1%") do sort "%Ziel1%" /O c:\odr\sort.txt


Worin liegt mein Fehler??
Kann mir jemand helfen? Herzlichen Dank schon mal im Voraus.

@echo off & setlocal enabledelayedexpansion
set "Ein=result.txt"  
set "Aus=c:\odr\sort.txt"  

set "Blanks=            "  
set T=%temp%\result.tmp
del %T% 2>nul
for /f "usebackq" %%i in ("%Ein%") do (  
    set "Z=%Blanks%%%i"  
    >>%T% echo !Z:~-12%!
)
sort %T% /O %T%

del "%Aus%" 2>nul  
for /f %%i in (%T%) do >>"%Aus%" echo\%%i  

@echo off &setlocal enabledelayedexpansion
set "Ein=result.txt"  
set "Aus=c:\odr\sort.txt"  

for /f "delims=: tokens=1*" %%i in ('findstr /n . "%Ein%"') do set /a zahl%%i=%%j &set /a n=%%i  
for /l %%i in (1,1,%n%) do (
  for /l %%j in (1,1,%n%) do (
    if !zahl%%i! lss !zahl%%j! (
      set /a temp=!zahl%%i!
      set /a zahl%%i=!zahl%%j!
      set /a zahl%%j=!temp!
    )
  )
)
type nul>"%Aus%"  
for /l %%i in (1,1,%n%) do (
  >>"%Aus%" echo !zahl%%i!  
)

@echo off & setlocal enabledelayedexpansion
set "Ein=result.txt"  
set "Aus=c:\odr\sort.txt"   

set "Blanks=            "  
set T=%temp%\result.tmp
del %T% 2>nul
for /f "delims=: tokens=1*" %%i in ('findstr /n "^" "%Ein%"') do (  
    set "Z=%Blanks%%%j"  
    >>%T% echo\!Z:~-12%!
)
sort %T% /O %T%

del "%Aus%" 2>nul  
for /f "tokens=1* delims=: " %%i in ('findstr /n "^" "%T%"') do >>"%Aus%" echo\%%j