6
Verschieben von Verzeichnisbäumen mit MOVE.exe unter Angabe von mehreren Dateimasken
Der MOVE-Befehl kann nur Dateien aus einem Verzeichnis, ohne die Dateien in den Unterverzeichnissen, verschieben. Außerdem wäre es evtl. noch nützlich, mehrere Dateimasken angeben zu können, um zu bestimmen, welche Dateien verschoben werden.
Hier ein kleiner Batch, der all das erfüllt.
Den Code als rmove.bat speichern, andere Namen sind auch möglich. Der Aufruf sieht dann so aus:
rmove <Quellverzeichnis> <Zielverzeichnis> <Dateimaske1> [<Dateimaske2> ... <DateimaskeX>]
Das Zielverzeichnis muss bereits existieren. Sollte einer der Parameter Leerzeichen enthalten, muss er in Anführungszeichen eingeschlossen werden.
Der Code ruft sich selbst rekursiv auf und erstellt dabei im Zielverzeichnis alle (Unter-)Verzeichnisse aus dem Quellverzeichnis, die Dateien enthalten, auf die die Dateimaske passt.
Ein kleiner Wermutstropfen bleibt: Die Verzeichnisstruktur im Quellverzeichnis bleibt bestehen, auch wenn man *.* als Dateimaske verwendet.
[Edit]
Bzgl. Wermutstropfen: Die Möglichkeit, nach dem Verschieben leere Verzeichnisse zu löschen, ist jetzt eingebaut, laut Posting von Biber (s.u.) jedoch auch gefährlich.
[Edit]
Code wurde nochmal geändert, bei einem Wurzelverzeichnis als Quell- oder Zielverzeichnis hätte es Fehlfunktionen gegeben.
[Edit]
Code wurde zur Geschwindigkeitssteigerung nochmal geändert. Wer den Batch benutzen will, sollte am besten auch die Kommentare entfernen, läuft dann auch schneller.
[Edit]
Code wurde nochmals geändert, damit z.B. & als Teil von Datei-/Verzeichnisnamen kein Problem mehr macht.
Gruß
Friemler
@echo off
setlocal
set "prgname=%~0"
set "src=%~1"
set "dest=%~2"
:: evtl. Backslash als letztes Zeichen von src und dest entfernen
if "%src:~-1%"=="\" (
set "src=%src:~0,-1%"
)
if "%dest:~-1%"=="\" (
set "dest=%dest:~0,-1%"
)
:: Die ersten zwei Parameter aus der Parameterliste entfernen
:: Dank an Biber/Bastla/LotPings, von einem habe ich den Trick
set "allparam=%*"
call set "allparam=%%allparam:%1 =%%"
call set "allparam=%%allparam:%2 =%%"
shift
shift
:: Der Call-Befehl wird nur ausgeführt, wenn im
:: Quellverzeichnis Unterverzeichnisse enthalten sind
for /f "delims=" %%p in ('dir "%src%\" /b /-p /a:d 2^>NUL') do (
call "%prgname%" "%src%\%%p" "%dest%\%%p" %allparam%
)
:: Wenn dest ein Wurzelverzeichnis ist, Backslash wieder anhängen
if "%dest:~-1%"==":" (
set "dest=%dest%\"
)
:: Im Quellverzeichnis nach Dateien suchen auf die die Maske passt.
:: Wenn gefunden, Verzeichnis im Ziel anlegen und Dateien verschieben
:loop
set "filesfound=0"
:: Alternative (ohne for-Schleife und filesfound):
:: if exist "%src%\%~1" (
:: md "%dest%" > NUL 2>&1
:: move "%src%\%~1" "%dest%"
:: )
:: erzeugt jedoch eine Fehlermeldung in Verzeichnissen,
:: die nur Unterverzeichnisse und keine Dateien enthalten.
:: Der Code funktioniert trotzdem und ist schneller, aber
:: die Fehlermeldung ist nicht schön.
for /f "delims=" %%f in ('dir "%src%\%~1" /b /-p /a:-d 2^>NUL') do (
set "filesfound=1"
goto break_for
)
:break_for
if "%filesfound%"=="1" (
md "%dest%" > NUL 2>&1
move "%src%\%~1" "%dest%"
)
shift
if not "%~1"== "" goto loop
:: Wenn Quellverzeichnis kein Wurzelverzeichnis ist und
:: keine Dateien oder Verzeichnisse enthält, löschen
if not "%src:~-1%"==":" (
rd "%src%" 2>NUL
)
endlocalDen Code als rmove.bat speichern, andere Namen sind auch möglich. Der Aufruf sieht dann so aus:
rmove <Quellverzeichnis> <Zielverzeichnis> <Dateimaske1> [<Dateimaske2> ... <DateimaskeX>]
Das Zielverzeichnis muss bereits existieren. Sollte einer der Parameter Leerzeichen enthalten, muss er in Anführungszeichen eingeschlossen werden.
Der Code ruft sich selbst rekursiv auf und erstellt dabei im Zielverzeichnis alle (Unter-)Verzeichnisse aus dem Quellverzeichnis, die Dateien enthalten, auf die die Dateimaske passt.
Ein kleiner Wermutstropfen bleibt: Die Verzeichnisstruktur im Quellverzeichnis bleibt bestehen, auch wenn man *.* als Dateimaske verwendet.
[Edit]
Bzgl. Wermutstropfen: Die Möglichkeit, nach dem Verschieben leere Verzeichnisse zu löschen, ist jetzt eingebaut, laut Posting von Biber (s.u.) jedoch auch gefährlich.
[Edit]
Code wurde nochmal geändert, bei einem Wurzelverzeichnis als Quell- oder Zielverzeichnis hätte es Fehlfunktionen gegeben.
[Edit]
Code wurde zur Geschwindigkeitssteigerung nochmal geändert. Wer den Batch benutzen will, sollte am besten auch die Kommentare entfernen, läuft dann auch schneller.
[Edit]
Code wurde nochmals geändert, damit z.B. & als Teil von Datei-/Verzeichnisnamen kein Problem mehr macht.
Gruß
Friemler
Share on Facebook
Share on Twitter
Share on Reddit
Share on LinkedinPlease also mark the comments that contributed to the solution of the article
Content-Key: 147070
Url: https://administrator.de/contentid/147070
Printed on: April 24, 2024 at 17:04 o'clock
6 Comments
Latest comment
Moin Friemler,
zu deinem kleinen Wermutstropfen:
Wenn du tatsächlich jemals alle Dateien (also *.*) verschieben wolltest, dann reicht doch ein einfaches MOVE auf das Wurzelverzeichnis.
Ohne irgendein rekursives Geeiere.
Wie du an der letzten Zeile siehst, ist die Struktur "D:\otherwork" wieder vollkommen entsorgt.
In allen anderen Fällen, also wenn ich etwas mit Wildcards verschiebe, z.B. nur *.PDFs...
--> da möchte ich gar nicht, das automatisch irgendwelche Verzeichnisse gelöscht werden, nur weil die grad leer sind.
Vielleicht zeigen auf genau diesen Pfad drei andere Applikationen und bringen mir sonst beim nächsten Start einen Fehler, wenn das Verzeichnis fehlt?
Grüße
Biber
zu deinem kleinen Wermutstropfen:
Wenn du tatsächlich jemals alle Dateien (also *.*) verschieben wolltest, dann reicht doch ein einfaches MOVE auf das Wurzelverzeichnis.
Ohne irgendein rekursives Geeiere.
>dir \work /s /b
D:\work\app
D:\work\dev
D:\work\Dougknox.vbs
D:\work\SQlLoad
D:\work\SQlLoad\S_SLT_MFD_ARTTEXTE.ctl
D:\work\SQlLoad\S_SLT_MFD_ARTTEXTE.xls
(=18:34:43 D:\temp=)
>move d:\work d:\otherwork
1 Datei(en) verschoben.
(=18:35:38 D:\temp=)
>dir \otherwork /s /b
D:\otherwork\app
D:\otherwork\dev
D:\otherwork\Dougknox.vbs
D:\otherwork\SQlLoad
D:\otherwork\SQlLoad\
D:\otherwork\SQlLoad\S_SLT_MFD_ARTTEXTE.ctl
D:\otherwork\SQlLoad\S_SLT_MFD_ARTTEXTE.xls
(=18:35:43 D:\temp=)
>move d:\otherwork d:\work
1 Datei(en) verschoben.
(=18:35:49 D:\temp=)
>dir \otherwork /b /s
Datei nicht gefunden
In allen anderen Fällen, also wenn ich etwas mit Wildcards verschiebe, z.B. nur *.PDFs...
--> da möchte ich gar nicht, das automatisch irgendwelche Verzeichnisse gelöscht werden, nur weil die grad leer sind.
Vielleicht zeigen auf genau diesen Pfad drei andere Applikationen und bringen mir sonst beim nächsten Start einen Fehler, wenn das Verzeichnis fehlt?
Grüße
Biber
Hallo Biber,
der Befehl
bewirkt lediglich, daß work in otherwork umbenannt wird, deswegen auch die Meldung "1 Datei(en) verschoben."
Zu Deinem anderen Einwand: OK, muß ich Dir recht geben.
Davon abgesehen habe ich noch einen Fehler im Code entdeckt, werde das bald korrigieren, allerdings wird der Code dadurch aufwändiger.
[Edit]
Code wurde geändert
Gruß
Friemler
der Befehl
move d:\work d:\otherwork
bewirkt lediglich, daß work in otherwork umbenannt wird, deswegen auch die Meldung "1 Datei(en) verschoben."
Zu Deinem anderen Einwand: OK, muß ich Dir recht geben.
Davon abgesehen habe ich noch einen Fehler im Code entdeckt, werde das bald korrigieren, allerdings wird der Code dadurch aufwändiger.
[Edit]
Code wurde geändert
Gruß
Friemler
Hallo Friemler!
Grüße
bastla
:: Der Code funktioniert trotzdem und ist schneller, aber
:: die Fehlermeldung ist nicht schön.
... und da hilft kein ":: die Fehlermeldung ist nicht schön.
2>nul"?Grüße
bastla
Hi bastla,
klar hilft das, aber dann sieht man garkeine Fehlermeldungen mehr.
Gruß
Friemler
klar hilft das, aber dann sieht man garkeine Fehlermeldungen mehr.
Gruß
Friemler
Moin,
Naja -wer schreibt, dass es device null sein soll?
oder so ähnlich
Gruß
Zitat von @bastla:
Hallo Friemler!
> :: Der Code funktioniert trotzdem und ist schneller, aber
> :: die Fehlermeldung ist nicht schön.
... und da hilft kein "
Grüße
bastla
Zitat von @Friemler:
Hi bastla,
klar hilft das, aber dann sieht man garkeine Fehlermeldungen mehr.
Hallo Friemler!
> :: Der Code funktioniert trotzdem und ist schneller, aber
> :: die Fehlermeldung ist nicht schön.
... und da hilft kein "
2>nul"?Grüße
bastla
Zitat von @Friemler:
Hi bastla,
klar hilft das, aber dann sieht man garkeine Fehlermeldungen mehr.
Naja -wer schreibt, dass es device null sein soll?
if exist c:\error.txt del c:\error.txt
keinbefehl>nul 2>>c:\error.txt
if exist c:\error.txt goto error
:code
goto end
:error
type error.txt
:endGruß
Hallo TimoBeil,
die Fehler in einer Datei zu protokollieren ist ja nicht schlecht gedacht. Aber schau dir mal folgendes Protokoll verschiedener MOVE-Befehle an, die alle einen Fehler verursachen. Unnötige Informationen (z.B. den Kommandoprompt) habe ich entfernt.
Zunächst mal die Verzeichnisstruktur:
dir c:\
Verzeichnis von c:\
19.07.2010 18:21 <DIR> test1
19.07.2010 18:16 <DIR> test2
dir c:\test1 /s /b
c:\test1\test11
c:\test1\test12
dir c:\test2 /s /b
c:\test2\test21
c:\test2\test22
Jetzt die Befehle, die Stellen, die einen Fehler verursachen, habe ich fett hervorgehoben:
a)
move c:\test1\test11\*.* c:\test2\test21 <--- hier ist es *.*, sieht man schlecht
Die Syntax für den Dateinamen, Verzeichnisnamen oder die Datenträgerbezeichnung
ist falsch.
b)
move c:\test1\test11\*.txt c:\test2\test21
Dateiname existiert bereits, oder die Datei
konnte nicht gefunden werden.
c)
move c:\test1\test11\xyz.* c:\test2\test21
Dateiname existiert bereits, oder die Datei
konnte nicht gefunden werden.
d)
move c:\test1\test1\*.* c:\test2\test21
Das System kann die angegebene Datei nicht finden.
e)
move c:\test\test11\*.* c:\test2\test21
Das System kann den angegebenen Pfad nicht finden.
f)
move c:\test1\test11\*.* c:\test2\test2
Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess
verwendet wird.
0 Datei(en) verschoben.
g)
move c:\test1\test11\*.* c:\test\test21
Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess
verwendet wird.
0 Datei(en) verschoben.
h)
move z:\test1\test11\*.* c:\test2\test21
Das System kann das angegebene Laufwerk nicht finden.
i)
move c:\test1\test11\*.* z:\test2\test21
Das System kann das angegebene Laufwerk nicht finden.
Von 9 Fehlermeldungen sind 4 (nämlich a, d, f und g) komplett irreführend und 2 (nämlich b und c) doppeldeutig und zumindest teilweise verwirrend (Dateiname existiert bereits, oder...). Am besten ist es also, wenn der MOVE-Befehl ganz ohne Fehlermeldung ausgeführt wird, dann weiß man wenigstens, daß alles funktioniert hat.
Wenn man meinen Batch ausführt, Laufwerke und Pfade richtig angegeben sind, Parameter, die Leerzeichen enthalten, in Anführungszeichen eingeschlossen sind und zwischen zwei Parametern nicht mehr als ein Leerzeichen vorkommt (man hat also alles richtig gemacht), können je nach Dateimaske die Fehlermeldungen a -c auftreten. Genau die gehören aber zu obigen Kandidaten.
Ich werde statt dessen noch ein goto in die zweite FOR-Schleife einbauen, damit die nur einmal ausgeführt wird. Das dürfte, gerade bei langen Verzeichnissen, auch einen Geschwindigkeitszuwachs bringen.
[Edit]
Wer den Batch benutzen will, sollte am besten auch die Kommentare entfernen, läuft dann auch schneller.
Gruß
Friemler
die Fehler in einer Datei zu protokollieren ist ja nicht schlecht gedacht. Aber schau dir mal folgendes Protokoll verschiedener MOVE-Befehle an, die alle einen Fehler verursachen. Unnötige Informationen (z.B. den Kommandoprompt) habe ich entfernt.
Zunächst mal die Verzeichnisstruktur:
dir c:\
Verzeichnis von c:\
19.07.2010 18:21 <DIR> test1
19.07.2010 18:16 <DIR> test2
dir c:\test1 /s /b
c:\test1\test11
c:\test1\test12
dir c:\test2 /s /b
c:\test2\test21
c:\test2\test22
Jetzt die Befehle, die Stellen, die einen Fehler verursachen, habe ich fett hervorgehoben:
a)
move c:\test1\test11\*.* c:\test2\test21 <--- hier ist es *.*, sieht man schlecht
Die Syntax für den Dateinamen, Verzeichnisnamen oder die Datenträgerbezeichnung
ist falsch.
b)
move c:\test1\test11\*.txt c:\test2\test21
Dateiname existiert bereits, oder die Datei
konnte nicht gefunden werden.
c)
move c:\test1\test11\xyz.* c:\test2\test21
Dateiname existiert bereits, oder die Datei
konnte nicht gefunden werden.
d)
move c:\test1\test1\*.* c:\test2\test21
Das System kann die angegebene Datei nicht finden.
e)
move c:\test\test11\*.* c:\test2\test21
Das System kann den angegebenen Pfad nicht finden.
f)
move c:\test1\test11\*.* c:\test2\test2
Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess
verwendet wird.
0 Datei(en) verschoben.
g)
move c:\test1\test11\*.* c:\test\test21
Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess
verwendet wird.
0 Datei(en) verschoben.
h)
move z:\test1\test11\*.* c:\test2\test21
Das System kann das angegebene Laufwerk nicht finden.
i)
move c:\test1\test11\*.* z:\test2\test21
Das System kann das angegebene Laufwerk nicht finden.
Von 9 Fehlermeldungen sind 4 (nämlich a, d, f und g) komplett irreführend und 2 (nämlich b und c) doppeldeutig und zumindest teilweise verwirrend (Dateiname existiert bereits, oder...). Am besten ist es also, wenn der MOVE-Befehl ganz ohne Fehlermeldung ausgeführt wird, dann weiß man wenigstens, daß alles funktioniert hat.
Wenn man meinen Batch ausführt, Laufwerke und Pfade richtig angegeben sind, Parameter, die Leerzeichen enthalten, in Anführungszeichen eingeschlossen sind und zwischen zwei Parametern nicht mehr als ein Leerzeichen vorkommt (man hat also alles richtig gemacht), können je nach Dateimaske die Fehlermeldungen a -c auftreten. Genau die gehören aber zu obigen Kandidaten.
Ich werde statt dessen noch ein goto in die zweite FOR-Schleife einbauen, damit die nur einmal ausgeführt wird. Das dürfte, gerade bei langen Verzeichnissen, auch einen Geschwindigkeitszuwachs bringen.
[Edit]
Wer den Batch benutzen will, sollte am besten auch die Kommentare entfernen, läuft dann auch schneller.
Gruß
Friemler
