Vorbereiten eines Schulungsraumes mittels Batch Dateien

REM Hier werden Variablen für die Umlaute definiert, damit Sie nachher im Text richtig angezeigt werden (ANSI/ASCI-Problem)
chcp 1252>nul
set ue=ü
set ae=ä
set oe=ö
set Uue=Ü
set Aae=Ä
set Ooe=Ö
set ss=ß
chcp 850>nul

REM Hier wird die Farbe der Fenster bestimmt
COLOR 0E

REM Und nun noch vor dem jeweiligen  "Programmstart" sauber putzen...  
CLS

Computernamen=C:\Schulungsraum\Computernamen_Schulungsraum.txt
Mac-Adressen=C:\Schulungsraum\Mac-Adressen_Schulungsraum.txt
DatenFuerSchueler=C:\Schulungsraum\Daten_fuer_Schueler
WOL=C:\Schulungsraum\woL.exe

@ECHO OFF & SETLOCAL
REM hier erfolgt erstmal die Verarbeitung der allgemeinen Einstellungen 
call C:\Schulungsraum\Allgemeine_Einstellungen.bat

REM Variablen einlesen
for /f %%i in (C:\Schulungsraum\variablen.ini) do set %%i

:DoAction
REM Jetzt geht's los - für jeden Eintrag in der Liste der Computernamen ...  
for /f %%i in (%Computernamen%) do (
cls
@echo -------------------------------------------------------------------
@echo Computer werden angepingt...
@echo -------------------------------------------------------------------
REM ...wird der jeweilige PC genau einmal angepingt und 50 ms auf eine Antwort gewartet
ping %%i -n 1 -w 50
@echo -------------------------------------------------------------------
@echo                       Abbruch mit Strg + C
@echo -------------------------------------------------------------------
REM Der nachfolgende Ping auf localhost bewirkt lediglich, dass die Antwort des Rechners noch eine Weile stehen bleibt 
ping localhost -n 2 >nul
)
@echo off 
REM Und hiermit geht's zurück zum Anfang...  
goto DoAction

REM Hiermit werden die Schulungsrechner heruntergefahren

@ECHO OFF & SETLOCAL 
REM hier erfolgt wieder zunächst die Verarbeitung der allgemeinen Einstellungen 
call C:\Schulungsraum\Allgemeine_Einstellungen.bat

REM Variablen einlesen
for /f %%i in (C:\Schulungsraum\variablen.ini) do set %%i

:DoAction
@echo.
@echo ---------------------------------------------------------
@echo Hierdurch werden alle Schulungsrechner heruntergefahren 
@echo und ausgeschaltet.
@echo ---------------------------------------------------------
REM ZUr Sicherheit nochmal eine Nachfrage, ob man wirklich alle PCs herunterfahren will
@echo M%oe%chten Sie ALLE Schulungsrechner herunterfahren?
set /p JaOderNein=Ungesicherte Daten k%oe%nnen verloren gehen (J/N):
if /i '%JaOderNein:~0,1%' == 'j' goto :Shutdown  
REM Wird nein (bzw. nicht ja) eingegeben, wird die Verarbeitung der Batch abgebrochen
@echo ---------------------------------------------------------
@echo  Schulungsrechner werden nicht heruntergefahren, beende
@echo ---------------------------------------------------------
REM Und wieder zum Lesen das Fenster ein bischen offen gelassen
ping localhost -n 3 >nul
exit

:Shutdown
@echo.
@echo ---------------------------------------------------------
@echo        Schulungsrechner werden heruntergefahren
@echo ---------------------------------------------------------
echo on
REM Wird "Ja" gewählt, wird der Rechner mit einem entsprechenden Hinweis an den davor Sitzenden heruntergefahren  
for /f %%i in (%Computernamen%) do shutdown -s -t 30 -c "Der Computer wird vom Seminarleiter heruntergefahren" -f -m \\%%i  
ping localhost -n 3 >nul

REM Hiermit werden die Schulungsrechner gestartet

@ECHO OFF & SETLOCAL 
REM Und wieder... 
call C:\Schulungsraum\Allgemeine_Einstellungen.bat

REM Variablen einlesen
for /f %%i in (C:\Schulungsraum\variablen.ini) do set %%i

:DoAction
@echo ----------------------------------------------------------------
@echo               Schulungsrechner werden gestartet
@echo ----------------------------------------------------------------
REM Hier wird in einer Schleife jede Mac-Adresse aus der Datei Mac-Adressen_Schulungsraum.txt ausgelesen und der Rechner mit Wake-on-LAN gestartet
for /f %%i in (%Mac-Adressen%) do %wol% %%i
@echo.
@echo ----------------------------------------------------------------
@echo                  Startbefehl wurden gesendet
@echo ----------------------------------------------------------------
REM Und wieder zur besseren Lesbarkeit:
ping localhost >nul

@ECHO OFF & SETLOCAL 
REM Und auch hier zum Schluss nochmal die allgemeinen Einstelungen laden:
call C:\Schulungsraum\Allgemeine_Einstellungen.bat

REM Variablen einlesen
for /f %%i in (C:\Schulungsraum\variablen.ini) do set %%i

:DoAction
@echo -----------------------------------------------------------------
@echo Hiermit werden Alle Dateien aus dem Verzeichnis 
@echo %DatenFuerSchueler% 
@echo auf die Schulungsrechner kopiert. Eventuell vorhandene Dateien
@echo werden dabei %ue%berschrieben
@echo -----------------------------------------------------------------
@echo.

REM Man kann mit diesem Script die Schüler-Verzeichnisse auch gleich wieder sauber machen, deshalb hier die Abfrage, ob kopiert oder gelöscht werden soll
set /p WasWillstDuTun=M%oe%chten Sie neue Dateien (k)opieren oder alte Daten (l)%oe%schen?
if '%WasWillstDuTun%' == 'k' goto Kopieren  
if '%WasWillstDuTun%' == 'l' goto Loeschen  
exit

:Kopieren
@echo -----------------------------------------------------------------
@echo Daten von %DatenFuerSchueler% werden kopiert
@echo -----------------------------------------------------------------
REM Beim Kopieren wird eine Schleife ausgeführt die auf jeden in der Datei Computernamen_Schulungsraum.txt stehenden Rechner Die Dateien vom Referenten-PC kopiert
for /f %%i in (%Computernamen%) do xcopy "%DatenFuerSchueler%\*.*" "\\%%i\c$\Schulungsdaten\" /y  
@echo -----------------------------------------------------------------
@echo Daten wurden auf alle eingeschalteten Schulungsrechner kopiert
@echo -----------------------------------------------------------------
pause
exit

:Loeschen
@echo -----------------------------------------------------------------
@echo Daten der Schulungsrechner werden gel%oe%scht
@echo -----------------------------------------------------------------
REM Beim löschen wird die Schleife auf jedem in der Datei stehendem PC die Dateien im Verzeichnis löschen
for /f %%i in (%Computernamen%) do del \\%%i\c$\Schulungsdaten\*.* /s /q
@echo -----------------------------------------------------------------
@echo Daten wurden auf alle eingeschalteten Schulungsrechnern gel%oe%scht
@echo -----------------------------------------------------------------
ping localhost -n 5 >nul
exit