Änderungsdatum einer Datei prüfen und wenn älter als x Mail senden

REM Script zur Überprüfung des Änderungsdatums einer Datei. Ist das Datum
REM älter als Heute -%Lastmodified% wird eine Mail versendet
REM =============================================

REM hier wird der zu prüfende Dateityp (nur Suffix, ohne *.) angegeben
REM ----------------------------------
SET Filetype=bak

REM Hier wird der Speicherort Zieldatei definiert:
REM ----------------------------------
SET Pfad=\\server\freigabe

FOR /f "delims=" %%i in ('dir /b /a-d /od "%Pfad%\*.%Filetype%"') do set "Zieldatei=%Pfad%\%%i"  

REM Hier wird die Dauer in Tagen angegeben, innerhalb der eine Änderung 
REM der neuesten Datei dieses Typs im Verzeichnis stattgefunden haben muss:
REM ----------------------------------
SET LastModified=2


REM Hier werden die E-Mail-Parameter gesetzt:
REM -----------------------------------------
SET Sender=Sender@Mail-Domäne.de
SET Password=passwort
SET SMTPServer=smtp.Mail-Domäne.de
SET Recipient=Empfänger@Mail-Domäne.de




REM =============================================
REM =============================================
REM        AB HIER NICHTS MEHR VERÄNDERN!
REM =============================================
REM =============================================


REM Lösche vorletzte Log-Datei
DEL lastlog.txt

REM Umbenennung letztes Log in vorletztes Log
REN log.txt lastlog.txt

REM Schreibe aktuelles Datum und Uhrzeit in Log >> log.txt
ECHO Aktuelles Datum: >> log.txt
Date /t	>> log.txt
ECHO ------------------ >> log.txt
Echo Aktuelle Uhrzeit: >> log.txt
Time /t >> log.txt

REM Prüfung, ob eine Datei dies definierten Typs dort existiert
IF NOT EXIST %Pfad%\*.%Filetype% GOTO :FILEDOESNOTEXIST

WasFile %Zieldatei% modified after today-%LastModified% >> log.txt
if not errorlevel 1 goto TRUE >> log.txt

:LASTMODIFICATION >> log.txt
ECHO ==================================================================================== >> log.txt
ECHO Datei %Zieldatei% wurde innerhalb der letzten %LastModified% Tage nicht verändert, sende Mail >> log.txt
blat.exe -body "Die Datei %Zieldatei%  wurde innerhalb der letzten %LastModified% Tage nicht veraendert" -ps FOOTER.txt -to %Recipient% -subject "Letzte Aenderung zu lange her" -Server %SMTPServer% -f %Sender% -u %Sender% -pw %Password% >> log.txt  
ECHO ==================================================================================== >> log.txt
EXIT

:TRUE 
ECHO ==================================================================================== >> log.txt
ECHO %Zieldatei% wurde innerhalb der letzten %Lastmodified% Tage geändert >> log.txt
ECHO ==================================================================================== >> log.txt
EXIT

:ERROR
ECHO Datei nicht gefunden
EXIT

:FILEDOESNOTEXIST
ECHO ==================================================================================== >> log.txt
ECHO Eine *.%Filetype%-Datei existiert nicht oder kann nicht aufgerufen werden, sende Mail >> log.txt
blat.exe -body "Eine %Filetype%-Datei existiert nicht oder konnte nicht erreicht werden!" -ps FOOTER.txt -to %Recipient% -subject "Datei nicht existent oder unerreichbar" -Server %SMTPServer% -f %Sender% -u %Sender% -pw %Password% >> log.txt  
ECHO ==================================================================================== >> log.txt
EXIT