Batch OCR gesucht mit Dateifilterfunktionen

gci 'd:\root' -File -Filter *.pdf -recurse | ?{$_.Basename -match 'A'}  

gci 'd:\root' -File -Filter *.pdf -recurse | ?{$_.Directory.Name -eq '2'}  

Process, Priority,, High
DetectHiddenWindows, On
SetKeyDelay, 30, 10
KeyWait, LButton, L T2
KeyWait, MButton, L T2
KeyWait, RButton, L T2
SetTitleMatchMode 2

;Prüfen, ob ABBYY FineReader Sprint aktiv ist
Process, Exist, sprint.exe, 
if ErrorLevel ; The PID ist vorhanden
	ExitApp, -1

;Prüfen, ob eine zu konvertierende Datei übergeben wurde
if 0 < 1  ; Die linke Seite einer if-Anweisung ohne Ausdruck ist immer der Name einer Variable.
{
    ExitApp, -2
}

; Startet Abbyy Finereader Sprint und übergibt die zu konvertierende Datei
Run, %A_ProgramFiles%\ABBYY FineReader 12 Sprint\sprint.exe %1%

;Warte, bis FineReader Sprint gestartet
WinWait, ABBYY FineReader 12 Sprint, , 5
IfWinExist, ABBYY FineReader 12 Sprint, 
{
	;Warten bis der Seitenimport in Finereader abgeschlossen ist...
	WinWait, Bilder werden geladen -, Verarbeite Seiten..., 5
	IfWinExist, Bilder werden geladen -, Verarbeite Seiten...
	{
		WinWaitClose
	}
	else
	{
		RunWait, taskkill /f /im sprint.exe
		ExitApp, -3 ;Programm beendet da Fehler bei Seitenimport
	}
	If WinExist("ahk_class FineReaderSprint12MainWindowClass")  
	{	
		WinActivate  ; Verwendet das zuletzt gefundene Fenster.
		ControlSend, , {LControl down}s{LControl up} ; Sende Control + S -> Speichern unter
	
		WinWait, Speichern unter, ShellView, 5
		IfWinExist, Speichern unter, ShellView
		{
			WinActivate, Speichern unter
			ControlClick, Button3, Speichern unter ; Sende Click auf 'Speichern'  
			Sleep 300
			;Ggf. Ausgabedatei überschreiben
			WinGetActiveTitle, Titel
			If (Titel = "ABBYY FineReader 12 Sprint")  
			{
				WinActivate
				ControlClick, Button1, ABBYY FineReader 12 Sprint ; Sende Click auf 'OK'  
			}
			;Warten bis Konvertierung abgeschlossen ist...
			WinWait, Seiten werden konvertiert -, Konvertiere zu, 5
			IfWinExist, Seiten werden konvertiert -, Konvertiere zu
			{
				WinWaitClose
			}	
			else
			{
				RunWait, taskkill /f /im sprint.exe
				ExitApp, -4 ;Programm beendet da Fehler 
			}
		}
		else
		{
			RunWait, taskkill /f /im sprint.exe
			ExitApp, -5 ;Programm beendet da Fehler 
		}
	}
	If WinExist("ahk_class FineReaderSprint12MainWindowClass")  
	{		
		WinActivate  ; Verwendet das zuletzt gefundene Fenster.
		ControlSend, , {LControl down}q{LControl up} ; Sende Control + q -> Quit
		ExitApp, 1 ; Skript erfolgreich beendet
	}
}


;Prüfen, ob ABBYY FineReader Sprint läuft
Process, Exist, sprint.exe, 
if ErrorLevel ; The PID ist vorhanden
	Process, WaitClose, sprint.exe, 5  ;Versuche FineReader zu beenden
	
ExitApp, 0 ;FineReader war nicht anteuerbar -> Exit